Q: quicktime uninstall on several clients with several versions
-
Apr 22, 2016 7:54 AMby Nallek,I am in the same situation and the Apple KB on uninstalling QuickTime is pretty useless in an enterprise environment.
Apple should really release a cleanup script that will just look for an uninstall everything QuickTime on a Windows machine. That would be the best solution as they are no longer supporting the product.
-
Apr 27, 2016 8:47 AMby Ibanez1998,I actually created a script with some error checking that employs multiple removal methods, including upgrading to the latest version from a network share to make sure the GUID is accurate. Here is that script:
From a network share, make sure read permissions are set for "Everyone" on the folder that holds the batch file, and read/write for a subfolder in the same location called "UninstallLogs" You can change this in the variables at the top of the script.
This script also assumes you are running Lansweeper to inventory your network. If you are, put LSPUSH.exe in the location of your choice and map to it in the top variables. This will allow the script to execute a scan after running the script to update your reporting.
You can copy and paste the script below and save it in a .BAT file to run it. Alternatively, you can download the entire package containing the .msi installer files I used to update quicktime to this GUID version from my DropBox here: https://www.dropbox.com/sh/tmljvonolmxjdzz/AAAGOlCbfkbTga9u3jRVpBKfa?dl=0
***I'm a professional IT guy, not a hacker. This script is NOT malicious in nature. The intent of this script is to uninstall QuickTime, and it works 9 times out of 10. Sometimes, Quicktime won't uninstall using wmic, and it also won't update from the msi files and therefore QuickTime remains installed. In those cases, find the GUID of the installed version, make a copy of this script and modify it for that GUID. I accept no responsibility if this script hoses your machine or anything like that. Use this simple batch script at your own risk, read through it and make sure it does what you need it to before you press enter.***
QuickTime Uninstall Script REM ******************************************************************************* ************************************************
REM Apple Quicktime Uninstaller. Created by Ed Middlebrooks. Modify variables below.
REM
REM PreRequisites:
REM This document assumes you have a central file server with a software deployment folder, or other folder
REM which can be used to place this script, the installation files, as well as collect logs.
REM I downloaded the latest Quicktime 7 and extracted the .MSI files needed by running QuickTimeInstaller.exe /extract
REM and placed the extracted .MSI files in the "InstallersPath" location. These files have been included for your convenience.
REM The software deployment folder should have at least read permissions for Everyone.
REM
REM ******************************************************************************* ************************************************
REM Set LogLocation to a central directory to collect uninstall log files.
set LogLocation=\\FILESERVERNAME.yourdomain.com\SoftwareDeployment\Quicktime\Uninst allLogs
REM Download the latest Quicktime. Extract the .MSI files needed by running QuickTimeInstaller.exe /extract and place the extracted .MSI files in this location:
set InstallersPath=\\FILESERVERNAME.yourdomain.com\SoftwareDeployment\Quicktime
REM Set the Path to the Lansweeper LSPush.exe file to update the client after uninstall.
set LSPushPath=\\FILESERVERNAME.yourdomain.com\softwaredeployment
REM Set the Lansweeper server LSPush.exe should send the scan results to.
set LansweeperServer=LANSWEEPERSERVER.yourdomain.com
REM *********************************************************************
REM Uninstall code begins here. Do not modify anything below this line.
REM *********************************************************************
:RegQuery
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\QuickTimePlayer.exe"
if NOT %errorlevel%==1 (goto UninstallQuicktime) else (goto End)
REM If 0 returned, there was no error so the product was found. Run the uninstaller here.
:UninstallQuicktime
start wmic product where "name like 'quicktim%%'" call uninstall /nointeractive
REM Sometimes wmic will hang, if no response from wmic after 10 minutes, kill it.
ping -n 600 -w 1 127.0.0.1>nul
taskkill /im WMIC.exe /f
REM Check if Quicktime was successfully uninstalled
:RegQuery2
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\QuickTimePlayer.exe"
if NOT %errorlevel%==1 (goto UninstallQuicktime2) else (goto End)
REM If product could not be uninstalled by wmic, upgrade product to latest version to set the guid to {FF59BD75-466A-4D5A-AD23-AAD87C5FD44C}, then uninstall it.
:UninstallQuicktime2
start /wait msiexec.exe /i %installerspath%\quicktime.msi /quiet DESKTOP_SHORTCUTS=NO
start /wait msiexec.exe /i %installerspath%\applesoftwareupdate.msi /quiet
start /wait msiexec.exe /i %installerspath%\appleapplicationsupport.msi /quiet
start /wait msiexec.exe /x {FF59BD75-466A-4D5A-AD23-AAD87C5FD44C} /qn
REM If 1 or other was returned, the product was not found or another error occurred. Do nothing.
:End
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\QuickTimePlayer.exe"
echo %date% %time% Setup ended with error code %errorlevel%. 0=Quicktime Still Installed, 1=Quicktime Not Found >> %LogLocation%\%computername%.txt
REM Run Lansweeper Update.
start %LSPushPath%\lspush.exe %LansweeperServer%
