Q: Applescript do shell grep

You can try using sed instead of grep to remove the leading whitespace + brackets and anything in between:

set filename to "Filename I need [Remove this bit].indd"

set newfilename to do shell script "echo " & filename & " | sed 's/ \\[.*\\]//' "

Here a resource for sed: http://www.grymoire.com/Unix/Sed.html  and one for grep: http://www.grymoire.com/Unix/Grep.html

and here's a nice regex "cheat sheet": https://www.cheatography.com/davechild/cheat-sheets/regular-expressions/

Oops…

Since you're already using AppleScript, you could also use the following code:

set filename to "Filename I need [Remove this bit].indd"

set P1 to offset of "[" in filename

set P2 to offset of "]" in filename

if (P1 > 2) and (P2 > P1) then set filename to text 1 through (P1 - 2) of filename & text (P2 + 1) through -1 of filename

use framework "Foundation"

set filename to "Filename I need [Remove this bit].indd"

set str to current application's NSString's alloc()'s initWithString:filename

set n to str's stringByReplacingOccurrencesOfString:" [Remove this bit]" withString:""

set newfile to n as text

Result: Filename I need.indd

It is AppleScript/Objective-C.

Basically, I initialize a string object (str) with your filename string. I then call a string replacement method (function) on that string object, and substitute the null string for the specified replacement text. The result is the desired filename.

How do you use wildcards with that? (Only works as posted with: " [Remove this bit]")

I came up with the same sed solution that you did, and you posted first. Here is the NSRegularExpression approach using your pattern (with wildcard).

use framework "Foundation"

set filename to "Filename I need [Remove this bit].indd"

set pattern to "\\s+\\[.*\\]"

set replaceStr to ""

set str to current application's NSString's alloc's initWithString:filename

set regex to current application's NSRegularExpression's regularExpressionWithPattern:pattern options: 0 |error|: (missing value)

set srange to current application's NSMakeRange(0, str's |length|)

set newfile to (regex's stringByReplacingMatchesInString:str options: 0 range:srange withTemplate:replaceStr) as text

Result: "Filename I need.indd"

use framework "Foundation"

set filename to "Filename I need [Remove this bit].indd"

set pattern to "\\s+\\[.*\\]"

set replaceStr to " Plus this new bit"

set str to current application's NSString's alloc's initWithString:filename

set regex to current application's NSRegularExpression's regularExpressionWithPattern:pattern options:0 |error|: (missing value)

set srange to current application's NSMakeRange(0, str's |length|)

set newfile to (regex's stringByReplacingMatchesInString:str options:0 range:srange withTemplate:replaceStr) as text

Result: Filename I need Plus this new bit.indd

Also can be done with sed:

sed 's/ \\[.*\\]//' replaces the string with nothing (//).  to replace with something: (/ Plus this new bit/)

In Applescript:

     set filename to "Filename I need [Remove this bit].indd"

     set newBit to " Plus this new bit"

     set newfilename to do shell script "echo " & filename & " | sed 's/ \\[.*\\]/" & newBit & "/' "

Like this?

set filename to "Filename I need [Remove this bit].indd"

set OldVariable to "Remove this bit"

set newBit to " Plus this new bit"

set newfilename to do shell script "echo " & filename & " | sed 's/ \\[" & OldVariable & "\\]/" & newBit & "/' "

Result:

"Filename I need Plus this new bit.indd"