Q: AppleScript to create thumbnail of selected file with hyperlink to the URL of the file

I do not have any spaces in my metafile declaration because my boot drive is not named Macintosh HD. You will have to replace the reference to metafile as the following to escape the white space in your bootdrive name:

property metafile : (path to desktop as text) & "meta.tex"

property mfile : (metafile's POSIX path)'s quoted form

on write_metadata(fh, aURL, imagePath)

     set imagecnt to (do shell script "[[ -s " & mfile & " ]] && egrep -c includegraphics " & mfile & " || echo \"0\"") as integer

...

end write_metadata

You will need to use this technique for the metafile argument to pandoc too.

do shell script "/usr/local/bin/pandoc -s -f latex -o ~/Desktop/work.docx " & mfile

Well then, it seems OpenOffice Writer and Microsoft Word do not paste html data. As I mentioned earlier, LibreOffice does paste it, though.

Whilst it is possible to amend the script to yield thumbnail image files in any given directory or even put different type(s) of data in the clipboard so that those applications could paste, I'd like to know the following first -

1) Can you paste the resulting data in the clipboard to a TextEdit rich text document correctly? If you can, does copying contents of the TextEdit document and pasting them into OO Writer and/or MS Word document yield desired result?

2) What happens if you open the resulting html file by Safari browser, select all contents, copy and paste them into OO Writer and/or MS Word document? Does it yield desired result?

* Under OS X 10.6.8, I can paste html data into a TextEdit rich text document correctly and copying contents of the TextEdit rich text document puts rtfd data in the clipboard. Also copying contents of Safari window puts rtfd data in the clipboard. If you can paste the rtfd data into OO Writer and/or MS Word document correctly, modifying the script so as to put rtfd data along with html data in the clipboard should solve the problem.

Regards,

H

Here is an update to my original code post that has been tested on OS X 10.11.6 with a boot drive using Macintosh HD. It also incorporates some logic changes in the write_metadata function, that actually now inserts newpage commands into the metafile after every four images. I have tested this successfully with up to 13 files of varying types, and it does not break in any do shell script syntax now.

Code:

-- qlthumb.applescript

-- Prompt user for files and write LaTeX metadata that is transformed into

-- DOCX or ODT documents via third-party pandoc utility

-- Version 1.2

-- VikingOSX, Sept 14, 2016, Apple Support Communities

property default_loc : ((path to desktop) as text) as alias

property qmesg : "Choose file(s) to generate thumbnails"

property metafile : (path to desktop as text) & "meta.tex"

property mfile : POSIX path of metafile

property thumbpath : (path to desktop as text) & "Thumbs:"

property fileCnt : missing value

tell application "Finder"

  if exists file metafile then

  delete file metafile

  end if

  if not (exists folder thumbpath) = true then

  make new folder at (path to desktop as text) with properties {name:"Thumbs"}

  end if

end tell

-- create the empty metafile and return a file handle used to write to it

set fRef to openMetaFile(metafile)

-- initialize with the preamble LaTeX stuff

init_metadata(fRef)

set inPath to (choose file with prompt qmesg default location default_loc with multiple selections allowed without invisibles and showing package contents)

set fileCnt to (count of inPath)

repeat with afile in inPath

  tell application "Finder"

  set ImgPath to ""

  set theURL to (afile's URL) as text

  set theImgName to afile's name & ".png"

  set ImgPath to POSIX path of (thumbpath & theImgName)

  set inFile to (afile's POSIX path)'s quoted form

  end tell

  try

  write_metadata(fRef, theURL, ImgPath)

  -- use the QuickLook manager to generate a 128 pixel icon at 90% scale

  do shell script "/usr/bin/qlmanage -tif 0.9 -s 128 " & inFile & " -o " & POSIX path of thumbpath & " >& /dev/null"

  on error errmsg number errnbr

  my error_handler(errnbr, errmsg)

  set fileCnt to 0

  return

  end try

end repeat

write "\\end{document}" & linefeed to fRef starting at eof

close access fRef

-- do shell script "/usr/local/bin/pandoc -s -f latex -o ~/Desktop/work.odt " & metafile

do shell script "/usr/local/bin/pandoc -s -f latex -o ~/Desktop/work.docx " & mfile

display dialog (fileCnt as text) & " records written. Document produced."

set fileCnt to (0 as integer)

return

on openMetaFile(filePath)

  -- influenced by twtwtw from https://discussions.apple.com/thread/4256380?tstart=0

  try

  set fp to (open for access file filePath with write permission)

  on error errmsg number errnbr

  if errnbr = -49 then

  close access fp

  set fp to (open for access filePath with write permission)

  else

  my error_handler(errnbr, errmsg)

  return false

  end if

  end try

  return fp

end openMetaFile

on init_metadata(fh)

  -- latex preamble

  write "\\documentclass[10pt, twocolumn]{article}" & linefeed to fh starting at eof

  write "\\usepackage{url}" & linefeed to fh starting at eof

  write "\\usepackage{graphicx}" & linefeed to fh starting at eof

  write "\\" & linefeed to fh starting at eof

  write "\\setmainfont{Helvetica}" & linefeed to fh starting at eof

  write "\\begin{document}" & linefeed to fh starting at eof

  return

end init_metadata

on write_metadata(fh, aURL, imagePath)

  -- attempt to control quantity of images on a page

  try

  set imagecnt to (do shell script "grep -c 'includegraphics' " & mfile) as integer

  on error

  -- avoid issue where match above fails and returns "0"

  set imagecnt to 0 as integer

  end try

  -- every four images we introduce a new page

  log imagecnt

  if imagecnt > "0" then

  if ((imagecnt mod 4) as integer) = 0 and imagecnt < fileCnt then

  write "\\newpage" & linefeed to fh starting at eof

  end if

  end if

  -- write data to it

  write "\\url{" & aURL & "}" & linefeed to fh starting at eof

  write "\\\\\\\\" & linefeed to fh starting at eof

  write "\\includegraphics{" & imagePath & "}" & linefeed to fh starting at eof

  write "\\\\\\\\" & linefeed to fh starting at eof

  return

end write_metadata

on error_handler(nbr, msg)

  return display alert "[ " & nbr & " ] " & msg as critical giving up after 10

end error_handler

My pandoc was installed by homebrew package manager into the /usr/local/bin directory as pandoc — hence the path that I used as /usr/local/bin/pandoc. You need to change this to the path where your pandoc executable is located.

Once you do that, then you can generate your Word or ODT document, as all else is complete at that point in the script.

Should the script abort, that will leave you with an open meta.tex file, and you will have to quit the script editor to unlink that file in use bit. Then move meta.tex to the trash, and restart the script.