Folder containing subfolders with parent folder name as prefix?

I agree, this is a bit much for Automator, except that it does simplify Folder Actions, so you should be able to take this script here and put it inside of a *Run AppleScript* action, for a nice Folder Action:

set a to choose folder
set new sublist to {"_RawImages", "_Layouts", "_Completed", "_CorrectedImages"}
tell application "Finder"
set a_name to a's name
repeat with nf in new sublist
make new folder in a with properties {name:(a_name & nf)}
end repeat
end tell

Or, you could just use this whenever you need it.

Casey:

Sorry if my previous post was unclear. Allow me to try again. Actually, after some research, as well as some trial and error, it is clear that this need of your will most likely NOT function within a Watched Folder. The problem is that you are creating new folders, so if place your script or workflow there, every new folder that is created as a result of your script, will trigger the script, and so on and so on. Although that may be cool to watch, you would soon have a drive completely filled with empty folders.

So, let's try a different approach, again within Automator. Another nice thing about Automator is that anything you save as an application automatically also functions as a droplet. For instance, this is a modification of my original script:

on run {input, parameters}
set fol_ders to input
set new sublist to {"_RawImages", "_Layouts", "_Completed", "_CorrectedImages"}
tell application "Finder"
repeat with a in fol_ders
set a_name to a's name
repeat with nf in new sublist
make new folder in a with properties {name:(a_name & nf)}
end repeat
end repeat
end tell
end run

In Automator, simply paste this script into a *Run AppleScript* action, save the workflow as an application, and you can drop as many folders as you wish onto the icon, and all the little subfolders defined in this portion of the script:

set new sublist to {"_RawImages", "_Layouts", "_Completed", "_CorrectedImages"}

will be created in the dropped folder. You can add as many folder labels to this list as you wish, and every time you drop a folder (or group of folders) onto the application icon, all the subfolders will be made.

As for the InDesign templates, you need to volunteer a bit more information about what you specifically want for that, but yes, it is certainly a doable process.

Casey:

I believe this is closer to what you are attempting. I am not proud of the code, nor did I do a good job of using descriptive variables. Anyway, here it is:

on run {input, parameters}
set fol_ders to input
set new sublist to {{"_Sub01", {"_RawImages", "_Layouts", "_Completed"}}, {"_Sub02", {"_something", "_CorrectedImages"}}}
tell application "Finder"
repeat with a in fol_ders
set a_name to a's name
repeat with nf in new sublist
set fold01 to make new folder in a with properties {name:(a_name & (nf's item 1))}
repeat with nnf in (nf's item 2)
set aa_name to fold01's name
make new folder in fold01 with properties {name:(aa_name & nnf)}
end repeat
end repeat
end repeat
end tell
end run

The variable newsublist is now a long list of lists. Each list is a 2-item list of folder names. The first item is the name of a sub-folder for the original folder dropped onto the droplet. The script then repeats through the second item in the list to create sub-folders inside of the first sub-folder.

As long as you are careful about how you construct the lists, this should be nearly there for you.

Hello Casey D,

Try something like the following script.
(Please copy code from this web page, not from subscribed email text, for I espaped some characters for posting.)

I don't know and can't test Automator, so this is plain AppleScript's droplet. Save it as application (bundle) and drag-drop the target root folders onto it.

As you see, you can define your directory structure in the template text given inline, where each non-empty line corresponds to a directory's partial path under the drag-dropped root directory and the '%' in template is to be replaced by the name of the root directory. (Partial path for sub-directory is to be delimited by colon as in HFS path)

---
Not sure but if you need code for Automator, you may perhaps change the open handler in the following script:

on open aa
--(current code omited)
end open

to this sort of run handler:

on run {input, parameters}
set aa to input -- pass input to aa
--(current code omitted)
end run



Hope this may help,
H



--SCRIPT
on open aa
set template to "
%_PDFs
%_Photos
% Photos:%Touchups
% Photos:%Originals
%_Products
% Products:%TriFold
% Products:%ThankYouCard
% Products:%PrayerCard
% Products:%Portrait
% Products:%Memorial
% Products:%DVD
% Products:%8pgMemorialBooklet
%_Theme
"
repeat with a in aa
set a to a's contents
tell application "Finder"
set _isContainer to item a's class is in {folder, disk}
set n to a's name
end tell
if _isContainer then
set t1 to replace("%", n, template)
set rp to a as Unicode text
repeat with p in t1's paragraphs
set p to p's contents
if p is not "" then mkDir(rp & p)
end repeat
end if
end repeat
end open

on mkDir(p)
(*
text p : full path of directory. e.g. "aaa:bbb:ccc" or "aaa:bbb:ccc:"
return alias: alias of (created) directory. e.g. alias "aaa:bbb:ccc:"
*)
try
return p as alias
on error
if p ends with ":" then set p to p's text 1 thru -2
do shell script "mkdir -p " & quoted form of POSIX path of p
return p as alias
end try
end mkDir

on replace(x, y, t)
(*
string x, y : searching string and replacing string respectively
string t : source string
return : modified string such that x is replaced by y in t
*)
local astid, astid0, tt
set astid to a reference to AppleScript's text item delimiters
try
set astid0 to astid's contents
set astid's contents to {x}
set tt to t's text items
set astid's contents to {y}
set t to "" & tt
set astid's contents to astid0
on error errs number errn
set astid's contents to astid0
error errs number errn
end try
return t
end replace
--END OF SCRIPT