Hi Stormnorm, I've got a Sony DCR-SR90E, which is very similar to the DCR-SR100 sold in the states and I've been banging my head on the walls trying to figure out how to import videos into iMovie at a good quality, seeing them in Front Row... All the questions you probably have.
I have found a solution which works perfect for me and I would like to share it with you.
It's not simple and I won't say it is, but it works great!
Let me start by saying this: the format used by Sony for video and sound are completely and utterly incompatible with a Mac. MPEG2 and AC3 both need plug ins and an additional QT plug in ($20) from Apple to work as they are, and then you won't get any sound anyway. That's why the only option you have to import and then edit your dear movies is to convert them first.
iMovie will do that automatically when you connect your camera through USB. If that's not working for you right now, look at the end of this message where I'll tell you how to set it up. However, the conversion done by iMovie is pretty bad because the resulting files are big and cannot be played back in Front Row (if they are 16:9, which I suppose they would be since the SR82 is capable of 16:9). The video is still interlaced and quite nasty to look at and to edit.
The best solution is to do the following 10 easy steps. I'll try to explain each step as much as I can.
1] Create a Folder named HandBrake in your /Application/Utilities folder.
2] Download the free utility HandBrakeCLI from here:
http://handbrake.fr/rotation.php?file=HandBrake-0.9.2-MacOSX.5CLIUB.dmg
3] Copy the HandBrakeCLI program to the HandBrake folder created in step 1.
4] Create a folder in your Home folder called, for instance 'Camera Import'. If you are using Time Machine, make sure to exclude it from the backup!
5] Open the Script Editor situated in /Applications/AppleScript
6] Copy the following code and paste it in a new empty script window:
global pathToHome
on adding folder items to this_folder after receiving added_files
set newFiles to {}
set filesToDelete to {}
tell application "Finder"
repeat with aFile in added_files
if name extension of aFile = "MPG" then
copy aFile to the end of newFiles
else
copy aFile to the end of filesToDelete
end if
end repeat
end tell
if ((count of newFiles) = 0) then
return
end if
waitCopy for newFiles
tell application "Finder"
repeat with aFile in filesToDelete
move aFile to trash
end repeat
end tell
checkFoldersExist()
repeat with aFile in newFiles
convertFiles for aFile
end repeat
display alert "Finished!" message "Your movies have been imported successfully."
end adding folder items to
on checkFoldersExist()
set pathToHome to POSIX path of (path to home folder)
try
do shell script "mkdir -p \"" & pathToHome & "Movies/iMovie Events.localized/Video Import\""
on error errmsg
display dialog errmsg
end try
end checkFoldersExist
on convertFiles for aFile
set aFileContents to aFile's contents
set aFileName to name of (info for aFileContents)
set posixPath to quoted form of POSIX path of aFileContents
set newPath to pathToHome & "Movies/iMovie Events.localized/Video Import/" & aFileName & ".mp4"
do shell script ("/Applications/Utilities/HandBrake/HandBrakeCLI -i " & posixPath & " -o \"" & newPath & "\" -B 128 -R 48 -E AAC -e FFmpeg -f MP4 -p -d -b 3500")
end convertFiles
on waitCopy for theFiles
tell application "Finder"
set wait to true
repeat while wait
set wait to false
set newFiles to {}
repeat with aFile in theFiles
set posixPath to quoted form of POSIX path of aFile
if size of aFile = 0 then
copy aFile to the end of newFiles
set wait to true
else
try
do shell script ("lsof \"" & posixPath & "\"")
set wait to true
copy aFile to the end of newFiles
end try
end if
end repeat
set theFiles to newFiles
end repeat
end tell
end waitCopy
7] Save the script in ~/Library/Scripts/Folder Action Scripts/ directory. '~' denotes your home directory (usually your user name). If the folders 'Scripts' or 'Folder Action Scripts' do not exist, create them first. You can use any name you want, I choose 'Import From Camcorder'. Once the script is saved, you may exit from the Script Editor.
8] Now in the Finder, select your 'Camera Import' folder and right click (or control-click) on it. Navigate to the More->Configure Folder Actions menu item and click on it.
9] Make sure that the 'Enable Folder Actions' check box is checked. Click on the little + sign in the bottom left and select your 'Camera Import' folder. Then click on the second + sign and navigate to your script in '~/Library/Scripts/Folder Actions Scripts'. Select the script and close the configuration window.
10] This step is optional but it's a nice trick: Drag your 'Camera Import' folder to the dock, to the left of the bin. This way, you don't have to look for it every time you want to import movies!
That's it! Here's how it works: when you connect your camera to your mac, you should see a new device called 'NO NAME'. that device is your video camera. You will find all your recorded movies in a folder called MP_ROOT or its sub directories. When you drag your movies to the 'Camera Import' folder on the dock, it starts a conversion process automatically and places the videos in an event called 'Video Import' in iMovie. A small dialog will pop up to inform you that the conversion process is finished. The new files are mp4 files with AAC sound so they will play in Front Row, QT, and will be very quickly imported into iMovie next time you open it. Of course, you have to delete the files in 'Camera Import' after the import (or modify the script to do that for you).
Now just can open iMovie and edit away or open Front Row and watch your dailies on your big screen.
Note: if you still want to use only iMovie but it doesn't import your files, make sure that iPhoto is not set as the default application that opens when you connect a camera (in the Preferences of iPhoto). Also, check that you connect your camera to the Mac and not to a hub since hubs sometimes don't get enough power.
I hope that this message is not too long and that it might be useful. Good luck!
