How to test for custom icon?

There is a Spotlight metadata key kMDItemFSHasCustomIcon that has a value of one for a custom icon, and zero if not. You can use the shell script mdls to get the value of an attribute:
set TheFile to quoted form of POSIX path of (choose file)
do shell script "/usr/bin/mdls -name kMDItemFSHasCustomIcon " & TheFile
display dialog result

It looks like that particular key is only in Leopard. In Tiger, mdls returns a path followed by several dashes if the particular metadata tag doesn't exist.

There also isn't a handy way in AppleScript (even in Leopard) to get the icon of an item - this would require using a scripting language that can access cocoa routines. A script that uses a foundation tool to access the standard system icons is available at macscripter.net - maybe you can modify that.

Hello

You may try GetFileInfo(1) command in Developer Tools to check the attribute bit for custom icon. Something like CODE1.

--CODE1
set p to POSIX path of (choose folder)
do shell script ("/Developer/Tools/GetFileInfo -ac " & quoted form of p)
set hasCustomIcon to result as integer -- 0 or 1
return hasCustomIcon
--END OF CODE1

cf.
http://developer.apple.com/documentation/Darwin/Reference/ManPages/man1/GetFileI nfo.1.html



Or you may check the presence of actual icon file in the target folder. Something like CODE2.

*Note the fact that there is "Icon\r" file does not necessarily mean the enclosing folder has custom icon (at least under OS9/Classic). So CODE2 should NOT be used if your system is configured for both OSX and OS9/Classic (unless additional code is introduced to check whether "Icon\r" file actually contains "icns" resource).

--CODE2 (for OSX-only system)
set d to choose folder
return hasCustomIcon(d) -- true or false

on hasCustomIcon(d)
(*
alias d : folder alias

* CAUTION: "Icon\r" file may exist even when it does not contain custom icon.
(Under OS9/Classic, this file may also contain custom column setting in list view,
which under OSX is stored in ".DS_Store" file.)
*)
set nn to {"Icon" & return, ".VolumeIcon.icns"} -- list of possible icon file names
set dp to d as Unicode text
if dp does not end with ":" then error "Given alias is not directory: " & dp number 9000
repeat with n in nn
try
(dp & n) as alias
return true
on error -- the node does not exist
end try
end repeat
return false
end hasCustomIcon
--END OF CODE2

Hope this may help,
H

Hello Lucifer,

You're quite welcome!

As for the exercise, in order to look into resource fork we need some special tool, for AppleScript has no built-in function for that. One handy way is to use free scripting addition named 'Satimage osax' that is made and distributed by Satimage Software, France.

CODE2A below is a revised version of CODE2. It will check whether "Icon\r" file contains 'icns' resource by using 'list resources' command of Satimage osax, whose dowload links are given in script comment.



--CODE2A
set d to choose folder
return hasCustomIcon(d) -- true or false

on hasCustomIcon(d)
(*
alias d : folder alias

* using 'list resources' command of Satigmage.osax

Install Satimage osax in either of:
/Library/ScriptingAdditions/
~/Library/ScriptingAdditions/

Download links:
http://www.satimage.fr/software/en/downloads/downloadscompanionosaxen.html
http://www.satimage.fr/software/en/downloads/downloadsold_companionosaxen.html
http://www.satimage.fr/software/en/support/soft9.html
*)
set dp to d as Unicode text
if dp does not end with ":" then error "Given alias is not directory: " & dp number 9000
-- check "Icon\r" file
try
(dp & "Icon" & return) as alias
if (list resources "icns" from result) is not {} then return true
on error -- the node does not exist or has no resource fork
end try
-- check ".VolumeIcon.icns" file
try
(dp & ".VolumeIcon.icns") as alias
return true
on error -- the node does not exist
end try
return false
end hasCustomIcon
--END OF CODE2A



Kind regards,
Hiroto