Speed of AppleScript vs. VBA in Excel

Hi,

Thanks for the info. FYI, here's the script. It's designed to parse a file of invoice data, skipping the line item rows and constructing a new sheet containing just the pertinent invoice data and total for each invoice. It provides the correct output, but it's just slow. Any suggestions on improving the code would be much appreciated:

+++++++++++++++++++++++++++++++++++++++
-- Start the timer to time the execution of this script
set start_timer to current date

tell application "Microsoft Excel"

-- Initialize current invoice values
set currentCustNum to ""
set currentCustName to ""
set currentInvoiceNum to ""
set currentInvoiceDate to ""
set currentInvoiceTotal to ""

-- No invoice has been found yet
set firstFoundInvoiceDate to ""
set Done to false

-- Keep track of how many invoices have been processed
set numInvoicesProcessed to 0

-- Find the first occurrence of the row containing the invoice number, date, customer number and customer name
set foundInvoiceDate to (find (range "G:G" of worksheet "Sheet1") what "Date:")

-- Find the first occurrence of the row containing the invoice total
set foundInvoiceTotal to (find (range "B:B" of worksheet "Sheet1") what "INVOICE TOTALS:")

-- Process each invoice
repeat while not Done

set currentRowNum to first row index of foundInvoiceDate

-- Remember the location of the date of the first invoice processed
if numInvoicesProcessed = 0 then

-- Remember the location of the first invoice date found
set firstFoundInvoiceDate to foundInvoiceDate

end if

-- Count the invoice being processed now
set numInvoicesProcessed to numInvoicesProcessed + 1

-- Get the current invoice date
set currentInvoiceDate to value of foundInvoiceDate
set tid to AppleScript's text item delimiters
set AppleScript's text item delimiters to " "
set currentInvoiceDate to (text item 2 of currentInvoiceDate) as text
set AppleScript's text item delimiters to tid
-- display dialog currentInvoiceDate

-- Get the current invoice number
set currentInvoiceNum to value of cell 2 of row currentRowNum
-- display dialog currentInvoiceNum

-- Get the current customer number
set currentCustNum to value of cell 12 of row currentRowNum
set tid to AppleScript's text item delimiters
set AppleScript's text item delimiters to " - "
set currentCustNum to (text item 1 of currentCustNum) as text
set AppleScript's text item delimiters to tid
-- display dialog currentCustNum

-- Get the current customer name
set currentCustName to value of cell 12 of row currentRowNum
set tid to AppleScript's text item delimiters
set AppleScript's text item delimiters to " - "
set currentCustName to (text item 2 of currentCustName) as text
set AppleScript's text item delimiters to tid
-- display dialog currentCustName

-- Look for this invoice's "INVOICE TOTALS:" line
set currentTotalRowNum to first row index of foundInvoiceTotal

set currentInvoiceTotal to string value of cell 20 of row currentTotalRowNum
-- display dialog currentInvoiceTotal

-- Save the current invoice's data fields in the "InvoiceSummaries" sheet
-- activate object worksheet "InvoiceSummaries"
set the value of cell 1 of row numInvoicesProcessed of worksheet 2 to currentInvoiceNum
set the value of cell 2 of row numInvoicesProcessed of worksheet 2 to currentInvoiceDate
set the value of cell 3 of row numInvoicesProcessed of worksheet 2 to currentInvoiceTotal
set the value of cell 4 of row numInvoicesProcessed of worksheet 2 to currentCustNum
set the value of cell 5 of row numInvoicesProcessed of worksheet 2 to currentCustName
-- activate object worksheet "Sheet1"

-- Look for the next invoice to process
set foundInvoiceDate to (find (range "G:G" of worksheet "Sheet1") what "Date:" after foundInvoiceDate)
if foundInvoiceDate = firstFoundInvoiceDate then
set Done to true
else
set foundInvoiceTotal to (find (range "B:B" of worksheet "Sheet1") what "INVOICE TOTALS:" after foundInvoiceTotal)
end if

end repeat

set run_time to (current date) - start_timer

set the value of cell 1 of row (numInvoicesProcessed + 4) of worksheet 2 to (" " & numInvoicesProcessed & " invoices were processed. The elapsed time was " & run_time & " seconds.")
-- display dialog "Processing completed! " & numInvoicesProcessed & " invoices were processed. The elapsed time was " & run_time & " seconds."

end tell
+++++++++++++++++++++++++++++++++++++++