Stop Numbers form auto-formatting imported data

(*
Enregistrer le script en tant que Script, Application ou Progiciel : dateTime2duration.xxx
déplacer l'application créée dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Numbers:
Il vous faudra peut-être créer le dossier Numbers et peut-être même le dossier Applications.
 
 Sélectionner les cellules à convertir
 
menu Scripts > Numbers > dateTime2duration
 
Le script insère les durées correspondantes.
 
--=====
 
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
 
+++++++
 
Save the script as a Script, an Application or an Application Bundle: dateTime2duration.xxx
 
Move the newly created application into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
 
 Select cells to convert.
 
menu Scripts > Numbers > dateTime2durationNumbers
 
The script insert the corresponding durations.
 
--=====
 
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
 
--=====
 
Yvan KOENIG (Vallauris FRANCE)
14 mai 2009
*)
--=====
on run
 set {dName, sName, tName, rname, rowNum1, colNum1, rowNum2, colNum2} to my getSelParams()
 set localOffset to (time to GMT)
 tell application "Numbers" to tell document dName to tell sheet sName to tell table tName
 repeat with x from colNum1 to colNum2
 tell column x
 repeat with y from rowNum1 to rowNum2
 try
 set theDate to (value of cell y)
 if class of theDate is date then
 tell (theDate - localOffset)
 set {hh, mm, ss} to {(its hours) as text, its minutes, its seconds}
 end tell
 set value of cell y to hh & "h" & mm & "m" & ss & "s"
 end if -- class…
 end try
 end repeat -- y
 end tell -- column x
 end repeat -- x
 end tell -- Numbers …
end run
--=====
on getSelParams()
 local r_Name, t_Name, s_Name, d_Name, col_Num1, row_Num1, col_Num2, row_Num2
 set {d_Name, s_Name, t_Name, r_Name} to my getSelection()
 
 if r_Name is missing value then
 if my parleAnglais() then
 error "No selected cells"
 else
 error "Il n'y a pas de cellule sélectionnée !"
 end if
 end if
 
 set two_Names to my decoupe(r_Name, ":")
 set {row_Num1, col_Num1} to my decipher(item 1 of two_Names, d_Name, s_Name, t_Name)
 if item 2 of two_Names = item 1 of two_Names then
 set {row_Num2, col_Num2} to {row_Num1, col_Num1}
 else
 set {row_Num2, col_Num2} to my decipher(item 2 of two_Names, d_Name, s_Name, t_Name)
 end if
 return {d_Name, s_Name, t_Name, r_Name, row_Num1, col_Num1, row_Num2, col_Num2}
end getSelParams
--=====
on decipher(n, d, s, t)
 tell application "Numbers" to tell document d to tell sheet s to tell table t to return {address of row of cell n, address of column of cell n}
end decipher
--=====
(*
set { d_Name, s_Name, t_Name, r_Name} to my getSelection()
*)
on getSelection()
 local _, theRange, theTable, theSheet, theDoc, errMsg, errNum
 
 tell application "Numbers" to tell document 1
 repeat with i from 1 to the count of sheets
 tell sheet i
 set x to the count of tables
 if x > 0 then
 repeat with y from 1 to x
 try
 (selection range of table y) as text
 on error errMsg number errNum
 set {_, theRange, _, theTable, _, theSheet, _, theDoc} to my decoupe(errMsg, quote)
 return {theDoc, theSheet, theTable, theRange}
 end try
 end repeat -- y
 end if -- x>0
 end tell -- sheet
 end repeat -- i
 end tell -- document
 return {missing value, missing value, missing value, missing value}
end getSelection
--=====
on decoupe(t, d)
 local l
 set AppleScript's text item delimiters to d
 set l to text items of t
 set AppleScript's text item delimiters to ""
 return l
end decoupe
--=====
on parleAnglais()
 local z
 try
 tell application "Numbers" to set z to localized string "Cancel"
 on error
 set z to "Cancel"
 end try
 return (z is not "Annuler")
end parleAnglais
--=====
--[/SCRIPT]