iTunes - how to create a playlist from a text file list of artists?

The following script should do the trick. The artist names need to be separated by returns and saved into a plain text file.

<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px;
color: #000000;
background-color: #FFEE80;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- make a new iTunes playlist with artist names from a text file

set TheFile to (choose file with prompt "Select a plain text file containing artist names:")
tell application "Finder" to set TheName to (displayed name of TheFile) -- this will be the name of the new playlist
set MyArtists to paragraphs of (read TheFile) -- read artist names (separated by newlines) from the file

tell application "iTunes"
set NewPlaylist to (make new user playlist with properties {name:TheName})
repeat with AnItem in MyArtists -- get all tracks from each artist
set AnItem to (contents of AnItem)
if AnItem is not "" then try -- don't bother with empty names
set MyTracks to (location of file tracks of playlist "Music" whose artist is AnItem)
add MyTracks to NewPlaylist
on error errmess -- oopsie (not found, etc)
log errmess -- just log it
end try
end repeat
end tell
</pre>