using delimiter "tab"

I want to read a path with "tab" as delimiter, but it won't work.

Sure it will - you're just doing it wrong 🙂

set the_path to read fs as text using delimiter "tab"

Your mistake is that you're quoting "tab". Since it's quoted it is treated as a literal string, so AppleScript is looking for the sequence of characters t-a-b to delimit the text.

Instead you want to use the keyword tab (with no quotes). The keyword identifies the tab character which will properly delimit your text as you expect:

set the_path to read fs as text using delimiter tab

You didn't mention what kind of paths are in your text file (the file needs to be plain text, otherwise the formatting will get in the way), but AppleScript's text item delimiters can break up the text at the specified delimiter (paragraphs are separated by returns, so there is no need to use that unless paragraphs are also used as delimiters). Reading the entire contents and working with the results does make things a little easier, such as not worrying about the end of the file - you also do not need to use *open for access* or close for files that you are just reading.

<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into the AppleScript Editor">
set songFile to "some plain text file with tab sepatated paths"

set theSongs to read file songFile -- get file text
set tempTID to AppleScript's text item delimieters -- save current delimiters
set AppleScript's text item delimiters to tab
set theSongs to text items of theSongs -- convert text to list at the delimiters
set AppleScript's text item delimiters to tempTID -- restore delimiters
log theSongs

repeat with aSong in theSongs
do shell script "afplay " & quoted form of POSIX path of aSong -- Finder path
do shell script "afplay " & quoted form of aSong -- POSIX path
end repeat
</pre>

If there aren't any tabs in there, then you don't need the text item delimiters stuff and can just get the paragraphs:

set theSongs to paragraphs of (read file songFile)

otherwise you can add delimiter characters, for example:

set AppleScript's text item delimiters to {tab, return, linefeed}

Error -39 is end-of-file, although there shouldn't be an error there. What does the text file look like from another application such as TextEdit?

Hello

According to your description, FMP generates a tab-separated-value file, where each field is separated by tab and each record separated by carriage return (CR).
If there's only one field (song path) in each record, the exported text consists of paragraphs each of which corresponds to a song path.

So you may try any of the following codes.
CODE1 is the simplest. AppleScript's paragraph is smart enough to handle all CR, LF, CRLF as delimiters.
CODE2 uses 'using delimiter' parameter of read command.
CODE3 spells out every step to open, read, close in addition to using 'using delimiter' parameter of read command.

--CODE1
set song_file to "HFS:path:to:song_paths.txt"
set pp to paragraphs of (read file song_file) -- System's primary encoding, e.g., Mac-Roman
--set pp to paragraphs of (read file song_file as «class utf8») -- UTF-8
repeat with p in pp
 set p to p's contents
 if (count p's words) > 0 then -- to skip quasi-blank line, just in case
 do shell script "afplay " & quoted form of p
 end if
end repeat
--END OF CODE1

--CODE2
set song_file to "HFS:path:to:song_paths.txt"
set pp to read file song_file using delimiter return -- System's primary encoding, e.g., Mac-Roman
--set pp to read file song_file as «class utf8» using delimiter return -- UTF-8
repeat with p in pp
 set p to p's contents
 if (count p's words) > 0 then -- to skip quasi-blank line, just in case.
 do shell script "afplay " & quoted form of p
 end if
end repeat
--END OF CODE2

--CODE3
set song_file to "HFS:path:to:song_paths.txt"
try
 set fref to open for access file song_file
 set pp to read fref using delimiter return -- System's primary encoding, e.g., Mac-Roman
 --set pp to read fref as «class utf8» using delimiter return -- UTF8
 close access fref
on error errs number errn
 try
 close access file song_file
 end try
 error errs number errn
end try
repeat with p in pp
 set p to p's contents
 if (count p's words) > 0 then -- to skip quasi-blank line, just in case.
 do shell script "afplay " & quoted form of p
 end if
end repeat
--END OF CODE3

*If the text is encoded in UTF-8, read the file as such.
Statement to read the fie as UTF-8 is currently commented out.

*As shown in CODE3, if you open access for a file, you must make sure you close access for it. Failing to close access would result in subsequent error to read the same file in the same script session, i.e. in the same session of Script Editor or Applet execution. I'd suspect your error -39 would be caused by not closing access for the file in the previous run.
To close all access for files which are inadvertently left open, you may quit the current script session, i.e., current application, e.g., Script Editor.

Good luck,
H

Message was edited by: Hiroto