Apple Script - Copy and Paste Between Two Tables in Numbers

No promises (this was written for Numbers 2.3), but see if this works:

tell application "Numbers"
	activate
	tell document 1
		tell sheet 1
			tell table 1
				set selection range to range "F87"
			end tell
		end tell
	end tell
end tell

copyit()

tell application "Numbers"
	activate
	tell document 1
		tell sheet 1
			tell table 2
				set selection range to range "D2"
			end tell
		end tell
	end tell
end tell

pasteit()

on copyit()
	tell application "System Events"
		tell application "Numbers" to activate
		keystroke "c" using {command down}
	end tell
end copyit

on pasteit()
	tell application "System Events"
		tell application "Numbers" to activate
		keystroke "v" using {command down}
	end tell
end pasteit

The use of the 'handlers' (copyit, pasteit) means that you can do other copy/pastes in the same script without having to keep typing out the code.

Tested in Numbers 5.3 (won't work in versions of Numbers 10 years old):

tell application "Numbers"
	tell front document
		tell active sheet
			set table "Table 2"'s cell "D2"'s value to table "Table 1"'s cell "F87"'s value
		end tell
	end tell
end tell



Assuming both tables are in the active sheet of the frontmost open document then that's all there is to it!

If you need to address a specific open document that may not be the frontmost one then you would:

tell document "MyDocumentName.numbers"

I've found you generally need the .numbers extension in the name.

If you need to address a specific sheet that may not be the active one then you would:

tell sheet "MySheetName"

If you are copying values of a large number of cells into a new table, then this will be a little slow. If you are often doing that just post and can give an example of bulk transfer using tab-delimited values pasted in from the clipboard.

Lot's of good stuff on scripting Numbers at this site.

SG

You can do this:

tell application "Numbers"
	tell front document
		tell active sheet
			if table "Table 1"'s cell "F87"'s value is not missing value then
				set table "Table 2"'s cell "D2"'s value to table "Table 1"'s cell "F87"'s value
			else
				set table "Table 2"'s cell "D2"'s value to table "Table 1"'s cell "E87"'s value
			end if
		end tell
	end tell
end tell

Unlike in formulas where you use '' in AppleScript you need to use missing value.

Also, you forgot the value after:

 if "Table 1"'s cell "F87"

It needs to be:

 if table "Table 1"'s cell "F87"'s value

Keep up the scripting. Used properly, it can save time working in Numbers.

SG