import csv to become a list in applescript

The original AppleScript code that I posted was for a 3 x 3 CSV. As the CSV may have more rows and columns, the original example becomes less efficient. Here is an example for a 3x5 CSV:

R1C1,R1C2,R1C3,R1C4,R1C5
R2C1,R2C2,R2C3,R2C4,R2C5
R3C1,R3C2,R3C3,R3C4,R3C5

The goal is to get each column in each row into its own list. The following AppleScript is a modification of my first post, and takes advantages of repeat loops and a list of lists:

-- from an n-column CSV, create separate lists of column data by row
-- change delim if not comma-delimited fields
-- select the document icon in the bottom toolbar to see the log output of the lists. Asterisks are
-- part of the log output and not actually within the lists.

set DELIM to {","}
set L1 to {} -- column 1 items
set L2 to {} -- column 2 items
set L3 to {} -- column 3 items
set L4 to {} -- column 4 items
set L5 to {} -- column 5 items

set Lx to {L1, L2, L3, L4, L5}

set acsv to (choose file)

set csvList to read acsv using delimiter linefeed
set {TID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, DELIM}
repeat with arow in csvList
	set ritems to text items of arow
	repeat with i from 1 to (count of ritems)
		copy (item i of ritems) to the end of (item i of Lx)
	end repeat
end repeat
set AppleScript's text item delimiters to TID

log L1
log L2
log L3
log L4
log L5
return

The stylized list results output that cleans up the log output:

L1 = {R1C1, R2C1, R3C1} -- all column 1 data
L2 = {R1C2, R2C2, R3C2} -- all column 2 data
L3 = {R1C3, R2C3, R3C3} -- all column 3 data
L4 = {R1C4, R2C4, R3C4} -- all column 4 data
L5 = {R1C5, R2C5, R3C5} -- all column 5 data

Give this a whirl. Here is what it does:

1. It prompts you to pick the CSV file.
2. It read that CSV file into a list, row by row, including the comma separators (e.g. {R1C1,R1C2,R1C3", "R2C1,R2C2R2C3"..."RnC1,RnC2,RnC3"} )
3. It then loops through this list splitting on the comma delimiter, and appending these items to the end of their respective list
   1. Item 1 of row 1 is R1C1
   2. Item 2 of row 1 is R1C2
   3. Item 3 of row 1 is R1C3
4. You end up with three lists containing their respective column number items

Assumption: The CSV has no header row, and it originated on macOS, so no Windows line endings to deal with.

set DELIM to {","}
set D to {} -- dates
set T to {} -- times
set Tel to {} -- telephone numbers

set acsv to (choose file)

set csvList to read acsv using delimiter linefeed
set {TID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, DELIM}
repeat with arow in csvList
	copy item 1 of text items of arow to the end of D
	copy item 2 of text items of arow to the end of T
	copy item 3 of text items of arow to the end of Tel
end repeat
set AppleScript's text item delimiters to TID

log D
log T
log Tel
return

Result:
	D   = {R1C1, R2C1, R3C1}
	T   = {R1C2, R2C2, R3C2}
	Tel = {R1C3, R2C3, R3C3}

Your virgole4.csv file produced the following list content when run in the exact same AppleScript that I provided. I have reformatted the output for legibility:

D   = {"13 maggio 2019", "13 maggio 2019", "13 maggio 2019"}
T   = {"10:15", "10:45", "11:00 "}
Tel = {"3311778887", "3482434440", "3472952297"}

All the script does is generate the lists. If you did not check the document icon on the bottom toolbar of the Script Editor, and the Replies button in the middle toolbar, the script will appear to do nothing because no result will be shown.

At the bottom of Script Editor, click the blue themed icon shown below:

and once you have done that, click the Replies button shown:

Now, you will see that the AppleScript that I posted does not fail to produce your three lists as I originally indicated.

Do not worry about those asterisks inside the lists. That is a visual by-product of using the log command, and those asterisks are simply not in your lists. I manually reformatted the lists in my previous post for readability.

You should review the integrity of the formatting within the CSV file though, as it looks as though the final Telephone number list data has inherited newlines, as those individual data items should appear on one line as the previous lists.