Apple Script

Use Automator instead.

Create a new Workflow and add these Actions. Set them with the necessary data.

Select the mailbox by using the Add… button in the Get Specified Mail Items.

You can add more than one.

Set the date criteria in the Filter Mail Items action as appropriate.

If you want to add additional criteria, the All button means "AND" and the Any button means "OR".

The + buttons add new criteria lines or groups.

Change the AppleScript code to:

on run {input, parameters}
	tell application "Mail"
		repeat with aMessage in input
			delete aMessage
		end repeat
	end tell
end run

If you want to understand the syntax of AppleScript for this purpose, here is some info.

Then would a script command like set box to mailbox named "Newspapers" of account named "iCloud"

followed by: set maxMessages to count of messages in "Newspapers"

then loop through all the messages looking for a date and delete the message if it the test was true?

The syntax for that would be something like:

set box to mailbox whose name is "Newspapers" of account whose name is "iCloud"

But, I'm not certain that will work and isn't necessary.

set box to mailbox "Newspapers" of account "iCloud"

You don't need to create a counter as you can

tell application "Mail"
	set cutoffDate to date "Saturday, June 1, 2019 at 12:00:00 AM"
	set theMessages to messages of mailbox "Newspapers" of account "iCloud"
	repeat with aMessage in (theMessages whose date received < cutoffDate)		
		delete aMessage
	end repeat
end tell

Or, shorter:

tell application "Mail"
	set cutoffDate to date "Saturday, June 1, 2019 at 12:00:00 AM"
	set theMessages to messages of mailbox "Newspapers" of account "iCloud" whose date received < cutoffDate
	repeat with aMessage in theMessages
		delete aMessage
	end repeat
end tell

Using the mailbox command - mailbox "Newspapers" in "Pete's iCloud" . IT seems to like the syntax because when I save it there is not error report. The bold part of the command is highlighted but when I execute the script and I got a script error - Can’t make "Newspapers" into type integer.

Whatever you are doing with mailbox "Newspapers" it thinks you want to enumerate them. It is expecting an integer result and you are trying to pass a list.

set theMessages to mailbox "Newspapers" in "Pete's iCloud" whose date received < target <<<---- this not working

First, you are trying to set the variable "theMessages" to a Mailbox, not the messages in the mailbox.

Second, in "Pete's iCloud" isn't correct. The preposition "in" is for enumerating over a list of items. E.g.

aMessage in theMessages

That gets each message that is in the list "theMessages". The correct preposition is "of"

Third, you never initialized your counter, "oldCount."

Fourth, aMessage cannot be coerced into text for the dialog box. There are parts of the message that can be coerced into text, like the subject. If you understand Object Oriented Programming, aMessage is an instance of a Message object. It has various properties which can be get or set.

Here is what you need for the correct syntax (I don't know if the mailbox path is correct):

set interval to -15
set theDate to current date
set target to (theDate) + interval * days
tell application "Mail"
	set theMessages to messages of mailbox "Newspapers" of account "Pete's iCloud" whose date received < target
	set oldCount to 0
	repeat with aMessage in theMessages
		display dialog subject of aMessage as string
		#delete aMessage
		set oldCount to (oldCount + 1)
	end repeat
end tell

At the bottom of Script Editor window, click on the right-most icon which looks like a box with lines in it.

Click on Result.

Run this Script:

tell application "Mail"
	get mailboxes of account "Pete's iCloud"
end tell

You should see listed all of the names and id's of the mailboxes in that account.

Those are the correct names to use.

If you use,

get name of mailboxes of account "Pete's iCloud"

It will show the names without showing the Path, i.e., "Information/Newspapers" vs. "Newspapers"

If it fails, is "Pete's iCloud" correct?

tell application "Mail"
	get name of accounts
end tell

get messages of mailbox "Sent" of account "iCloud"

Are you certain "Newspapers" is a mailbox in your iCloud account?

Or, is Newspapers in a subfolder? That would need the path, such as "Subscriptions/Newspapers"