How to find the build date of a Mac Mini

gop1947 Said:

"How to find the build date of a Mac Mini: I have just purchased a brand new late 2014 Mac Mini A1347 from a Mac reseller. Since these were current up to October 2018, is there any way to establish when it was ordered or built?[...]"

-------

Check the AppleCare Information:

The closest way you could find out would be to go here, and enter your Serial Number:

Go Here: Check Your Service and Support Coverage - Apple Support

Since the original question was to determine the build date, and not just the market introductory string (e.g. Late-2013), the following AppleScript will answer both questions without any user input. It requires that 1) the Mac is not a 2020 model, and 2) that no motherboard replacement has occurred to conceal the serial number.

Here is the output from my Late-2013 iMac:

Due to the 5000 character limitations of the hosting software, I cannot post the AppleScript code as one contiguous post, but as two separate Part 1 and Part 2 posts. After you launch the Script Editor from Dock : Launchpad: Other, you would copy/paste Part 1 into the Script Editor, and then append Part 2 afterward. Then you click the compile (hammer) icon, and then click Run.

Note: The posted code is scrollable both vertically and horizontally, so be certain that you have selected all of the text before performing the copy/paste of both Part 1 and Part 2.

Part 1

-- For serial number break-down and technique for calculating manufacture
-- date, reference: https://beetstech.com/blog/decode-meaning-behind-apple-serial-number
-- Caveat: Apple Serial number fields and length of serial number subject to change
-- VikingOSX, 2020-02-27, Apple Support Communities.

use framework "Foundation"
use AppleScript version "2.4" -- Yosemite 10.10 or later
use scripting additions

property NSDictionary : a reference to current application's NSDictionary

set sn to (do shell script "ioreg -l | awk '/IOPlatformSerialNumber/ {print $4;}' | tr -d '[\"]'")

if not (length of sn) = 12 then
	display alert "Mac is earlier than 2010, and cannot process serial number"
	return
end if

-- extract last four characters from s/n
set sn4 to (do shell script "sed -E 's/.*(....)$/\\1/' <<<" & sn's quoted form)

-- take the first country code from returned list and change its second '-' to '_'.
set country to (do shell script "defaults read -g AppleLanguages | awk 'NR==2 {$1=$1;printf \"-%s\", substr($0,2,5)}' | sed 's/-/_/2'")

-- construct .plist key string
set pkey to ":CPU Names:" & sn4 & country

-- return the Mac market introduction timeframe (e.g. iMac (27-inch, Late-2013))
-- which is same as shown in  menu : About This Mac
set model to (do shell script "/usr/libexec/PlistBuddy -c \"print " & pkey's quoted form & "\" ~/Library/Preferences/com.apple.SystemProfiler.plist")

-- now determine manufacture date

set ml to (characters 1 thru 3 of sn) as text -- manufacturing location, UNUSED
set yom to (character 4 of sn) -- year of manufacture
set wom to ((character 5 of sn) as text) -- week of manufacture
set mu to (characters 6 thru 8 of sn) as text -- a unique identifier code, UNUSED
set mn to (characters 9 thru 12 of sn) as text -- the model number, UNUSED

I think you need to decode the serial number, found under About This Mac / System Report / Hardware Overview

According to this link: https://beetstech.com/blog/decode-meaning-behind-apple-serial-number, the 4th alphanumeric digit refers to the year, and the fifth digit refers to the week. They may have used an alien alphabet in the process.

Part 2

set dateYr to {C:"2010(1st half)", D:"2010(2nd half)", F:"2011(1st half)", G:"2011(2nd half)", H:"2012(1st half)", J:"2012(2nd half)", K:"2013(1st half)", L:"2013(2nd half)", M:"2014(1st half)", N:"2014(2nd half)", P:"2015(1st half)", Q:"2015(2nd half)", R:"2016(1st half)", S:"2016(2nd half)", T:"2017(1st half)", V:"2017(2nd half)", W:"2018(1st half)", x:"2018(2nd half)", Y:"2019(1st half)", Z:"2019(2nd half)"}

-- Apple codes for first 28 week builds
set week28 to {"1", "2", "3", "4", "5", "6", "7", "8", "9", "C", "D", "F", "G", "H", "J", "K", "L", "M", "N", "P", "Q", "R", "T", "V", "W", "X", "Y", "Z"}

set manyear to my dict_value(dateYr, yom) as text
set manweek to 0 as integer

repeat with i from 1 to count of week28
	if ((item i of week28) contains wom) is true and (manyear contains "(1st half)") is true then
		set manweek to (i as integer)
	else if manyear contains "2nd half" then
		set manweek to (i + 26) as integer
	end if
	
	if not manweek = 0 then exit repeat
end repeat

set YR to characters 1 thru 4 of manyear
set YR_WK to ((YR as text) & space & manweek as text)'s quoted form
-- monday of manufacture week
set mondate to (do shell script "date -j -f \"%Y %V\" " & YR_WK & " +%F")
-- saturday of manufacture week
set satdate to (do shell script "date -j -v Sat -f \"%Y %V\" " & YR_WK & " +%F")
display dialog "Model: " & model & return & "Manufactured: " & "Mon " & mondate & " thru Sat " & satdate with title "Model and Manufactured Week"
return

on dict_value(adict, akey)
	return ((NSDictionary's dictionaryWithDictionary:adict)'s valueForKey:akey) as text
end dict_value