I have put together an Automator Quick Action that assumes that before the Quick Action is invoked from the Services menu, or the Finder Quick Actions menu, that you have copied that Dropbox folder link to the clipboard. Then you select the folder and run the Quick Action.
My solution uses two Automator variables:
- Storage - the name of the folder
- URLstring - the link from the clipboard
When you save an Automator Quick Action as somename.workflow, it has an internal plist file named document.wflow, which contains a variables key and an array of each variable name and its UUID string. It is the latter that you can reference in an outgoing Mail message as a UUID string). So technically, if I wanted to place the clipboard's URL behind the body text:
Here are your images for: $(1BE0792D-0DCD-4887-9A2A-2768C0F16A95)
and it would deposit the URL string from the clipboard there as an active link in the sent Mail message. However, you want to use a custom text anchor "Test Automator Folder" as the link name, which adds complication to the solution. What I do is put the entire anchor link with that text on the clipboard, and then present the Mail compose window, where you simply paste from the clipboard behind the text where you want it.
First, how do we get that crazy UUID for the variables which you will need to code the solution? Once you save the Quick Action you can get those variables and their UUID string into an AppleScript record. Here is the AppleScript to present a dialog of that result, where you can copy/paste that $(UUID string) for the variable you need into the Automator AppleScript action:
The AppleScript that produces the above dialog:
use framework "Foundation"
use scripting additions
property NSDictionary : a reference to current application's NSDictionary
property ServicesFolder : ((path to home folder as text) & "Library:Services") as alias
# set wflowFile to "~/Library/Services/Send email with variables.workflow/Contents/document.wflow"
set wflowFile to (choose file default location ServicesFolder)
set wflowFile to (wflowFile & "Contents:document.wflow") as text
set UUIDList to {}
set NameList to {}
set varRec to {}
tell application "System Events"
tell property list file wflowFile
set varList to (value of property list item "variables") as list
end tell
end tell
repeat with aRec in varList
copy aRec's |name| to the end of NameList
copy aRec's UUID to the end of UUIDList
end repeat
set varRec to my make_record(NameList, UUIDList)
set fmt1 to ("URLString: $(" & (URLString of varRec) as text) & ")"
set fmt2 to ("Storage: $(" & (Storage of varRec) as text) & ")"
display dialog fmt1 & return & fmt2
return
on make_record(k, v)
return (NSDictionary's dictionaryWithObjects:v forKeys:k) as record
end make_record
Due to the hosting software being restrictive about the size of a post, I will continue this on the immediate reply to this thread.
