Applescript: Adding a custom tag to a selected file in Finder

I have a Voice Dictation command "Tag Photo" working with an AppleScript that sets the "Photo" tag on selected filesystem objects. The AppleScript is written so you only need to make one change with each script and that is to change the TAG_NAME properties tag string. If a filesystem object already has a tag name on it, the script will add your tag name to that file or folder.

Here is the AppleScript that you copy/paste into Script Editor (Launchpad > Other > Script Editor). You then click the compile button, and save it twice: 1) as a text format tagname_photo.applescript in your preferred location, and then with option+Save As as a script format tagname_photo.scpt in /Users/yourname/Library/Scripts/Applications/Finder folder. The latter is where you will tell your new Voice Control command to find the workflow…

The AppleScript:

(*
AppleScript that checks selected filesystem obect(s) for existing tags
and adds the current tag name defined in the property beginning with TAG_

This script does not gather all defined tag names and attempt to validate
the user supplied tag name.

The user changes *one* location <== EDIT ==> for different tag name strings

Reference: https://discussions.apple.com/thread/252807460
Tested: macOS 11.4
VikingOSX, 2021-05-29, Apple Support Communities, No warranties expressed/implied
*)

use AppleScript version "2.4" -- Yosemite (10.10) or later
use framework "Cocoa"
use scripting additions

property NSUTF8StringEncoding : a reference to 4
property NSString : a reference to current application's NSString

property NSWorkspace : a reference to current application's NSWorkspace
property NSURL : a reference to current application's NSURL
property NSArray : a reference to current application's NSArray
property NSURLTagNamesKey : a reference to current application's NSURLTagNamesKey
property NSDictionary : a reference to current application's NSDictionary

property TAG_NAME : {"Photo"} # <== EDIT ==>

# assumption is that the filesystem object(s) are already selected before this
# script is invoked by Dictation.
set tagFileList to {}

# process selected items
tell application "Finder"
	if selection is {} then return
	set selList to selection
	repeat with anItem in selList
		copy POSIX path of (anItem as text) to the end of tagFileList
	end repeat
end tell

repeat with anItem in tagFileList
	my set_tag(anItem, TAG_NAME)
end repeat
return

on set_tag(theFile, atag)
	-- atag is always a list, even if single tag element
	-- place single, or multiple tags from atag on the specified file
	set existingTags to {}
	set tagArray to (NSArray's arrayWithArray:atag)'s mutableCopy()
	set existingTags to my file_tags(theFile)
	if (count of existingTags) ≥ 1 then
		# add the detected tag(s) to the existing TAG_NAME list item
		tagArray's addObjectsFromArray:existingTags
	end if
	
	set fileURL to NSURL's fileURLWithPath:theFile
	fileURL's setResourceValue:tagArray forKey:NSURLTagNamesKey |error|:(missing value)
	return
end set_tag

on file_tags(apath)
	-- Get all tags from the file, or an empty list if none
	-- apath = POSIX path to file
	set metadata to NSDictionary's dictionary()
	set aurl to NSURL's fileURLWithPath:apath
	set metadata to aurl's resourceValuesForKeys:{NSURLTagNamesKey} |error|:(missing value)
	-- file has no tags yet
	if (metadata's objectForKey:{NSURLTagNamesKey}) is missing value then return {""} as list
	-- file has tags, so return them as a list
	return (metadata's objectForKey:NSURLTagNamesKey) as list
end file_tags

In Accessibility > Voice Control > Commands… create your new command with the [+] button, and configure as follows. For testing purposes, I did not save the script as tagname_photo.scpt, but you should. And each variation of that script to match the voice command tag name should follow that format of the tag name in the filename.

Make certain that your file(s) are selected before speaking your voice command to trigger the script.

When you speak "tag photo", and dictation recognizes the command, then it can do one of several things including triggering an AppleScript, or even an Automator workflow. That AppleScript has no means to obtain the spoken tag name from Dictation, and thus cannot set tag name "photo" or any other tag name on the selected file or folder. Unless your AppleScript was programmed with the tag name "photo" in it so it had that name to apply. This could get out of hand with several custom tag names.

Another solution might be the command "show tags". Dictation recognizes the command and fires an AppleScript that presents a scrollable list of your custom tag names, where you can select one or more tags to apply or remove on a selected file. That AppleScript code already exists in the first link you provided earlier.

I took a closer look at this problem this afternoon, and it cannot be done. Not by me, anyway.

Speech recognition wants to match what you speak in a list of prefabricated strings ("add green", "remove red", etc) and does not perform speech-to-text capture. Thus, I cannot get the tag name string from your spoken command, or even the index into that list of commands, and that is crucial to manipulating tag names on filesystem objects.

Although Apple does have a Speech to text framework, it comes with an Apple privacy requirement that one must interactively request permission of the user to use their microphone and to send spoken content to Apple's speech recognition servers. I have never coded in this framework.

I will help you get the example code from the first link working as it pops a dialog allowing you to chose n-tuple tag names to apply on selected filesystem objects. Rather simple to use.

Yes, the command recognition takes place with Dictation, and based on that recognition an AppleScript can be run. However, since AppleScript has no idea what tag name you want to be applied, that would require a separate AppleScript for each tag name that you use in your dictation command (e.g. tagname_photo.applescript, etc.). If that is what you want, I will write one of these for you, and the others are on you for your other commands and custom scripts.

This is the reason that I wrote that original script to get a list of all tag names and present it in a scrollable list, where one or more tag name selections would then be applied to selected files or folders. One script, not n-tuple scripts. It too, could be voice activated.

The code that I provided in the first link still works (copy/paste) unchanged on macOS 11.4. However, there is additional code that needs to be added before the speech synthesizer can detect your spoken word, and compare that to a list of known tag names on your Mac.

I wrote an AppleScript several years ago that could detect spoken words and unhide a selected file extension. I will have to test if that code still works on Big Sur. Then I need to determine how to merge that code with some of the existing text tag manipulation code. The trick will be the word detection now, comparing the tag name to a list of current tag names, and applying it.

I will let you know if it is feasible or not, and a timeframe (if I have the time) to code it.

[Update: Just ran unchanged, the SpeechRecognitionServer AppleScript and it performed the spoken task. Now the real trick is merging the code, verifying your spoken tag to a list of valid tag names, and applying it to a selected filename.]

The amount of time it will take to borrow useful code from two different scripts, adding new code, and testing is too much for my current schedule. I will work on this in early June and post the result (if I can get it working) here.

You are welcome. Be productive…