Automate moving files into folders with the same name

I have just tested a short script that when given a starting folder, processes all files in that folder into their respective 7 or 13 character folder names. I have used five files per SKU in the test. I have some questions.

1. Will there be files in sub-directories within the starting folder requiring the script to be recursive in that hierarchy?
2. Are there files that use a different character (e.g. underscore) instead of the space character that you have shown in your example filenames? Different filenames altogether (e.g. alphanumeric, other characters, etc.)?
3. Do you work in the Terminal, or prefer an Automator application that lets you choose the starting folder and does the rest for you?

Had some time prior to departure, so decided to post the AppleScript (easier to read) Automator solution. Test it on a sample directory of SKU filenames to measure result.

Steps:

1. Launch /Applications/Automator.
   1. New Document
      1. Application
      2. Click Choose
   2. Drag and drop Library>Files & Folder>Ask for Finder Items into the larger right-hand workflow window.
      1. Start at: Desktop
      2. Type: Folders
      3. No Allow Multiple Selection
   3. Drag and drop Library>Automator>Run AppleScript, or Library>Utilities>Run AppleScript below the previous action in the workflow window. Whichever is present.
      1. Select and remove all content in this action's window.
      2. Copy and paste the code below into the Run AppleScript action's window
      3. Click the hammer icon to compile the action's content
   4. Save your Automator application to your Desktop with a catchy name like SKU2Folder. Double-click the application to be prompted for the parent folder to process the SKU filenames. When the whirling Automator activity in the right menu bar ends, you will know its done, unless I add more code.
   5. Quit Automator

Code:

# AppleScript to process filenames, create directories based on first numeric
# filename string prior to space in name, and then move those matching files
# into their namesake folder.

# Reference: https://discussions.apple.com/thread/252838354
# Tested: macOS 11.4
# VikingOSX, 2021-06-07, Apple Support Communities, No warranty/support expressed or implied.

use scripting additions

property DELIM : {space}

on run {input, parameters}
	
	# get selected folder passed from the Ask for Finder Items Automator action
	set sfolder to (item 1 of input) as alias
	
	tell application "Finder"
		# make a list of every regular file in the selected folder
		set fList to (every item in folder sfolder whose kind is not "Folder") as alias list
		
		repeat with anItem in fList
			# get filename from the individual path
			set anItemx to anItem's name
			
			# get variable number string up to space in filename from list
			set {TID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, DELIM}
			# example: {"9357753500167", "1.jpg"}
			set basename to item 1 of (text items of anItemx)
			set AppleScript's text item delimiters to TID
			
			# ignore the error if the folder already exists
			try
				make new folder at sfolder with properties {name:basename}
			end try
			
			move anItem to folder ((sfolder & basename) as text) with replacing
			
		end repeat
	end tell
	
	return input
end run

Traveling today, so won't be able to create and test the Automator solution until this evening. I have coded and successfully tested an AppleScript (slower in folders with large file count), and a Zsh shell script that runs flat out. Either script only handles the files (not sub-folders) in a selected parent folder.

When you first run the Automator application, the Big Sur operating system security will get in your face with this dialog. Just click OK and the application will proceed to completion.

Before and after, using third-party tree application to visualize hierarchy:

Good to hear. You are welcome. The Zsh shell script that I wrote will likely run faster, but the code is more arcane, even with copious comments, thus I went with AppleScript for legibility.