The best way to approach this is with AppleScript, though bearing in mind that Page's AppleScript dictionary does not expose header or footer content. The solution that I have used involves Pages placeholder text, where one creates a unique string in the header or footer location where the file path is desired, and Pages can replace that placeholder text with the file path.
Let's say that I place some (arbitrarily named) boilerplate text in the lower-left footer segment:
[filepath]
I then select all of that text including the brackets, and visit the Format menu > Advanced > Define as Placeholder Text. So now, it looks like this:

and then I run the following AppleScript to replace that placeholder text with a tilde path (for privacy reasons) of the currently opened Pages document (which was previously saved):

AppleScript to be copy/pasted into Script Editor and run on an opened, previously saved Pages document:
use framework "Foundation"
use AppleScript version "2.4" -- Yosemite or later
use scripting additions
property NSString : a reference to current application's NSString
set phtext to text returned of (display dialog "Enter entire placeholder string (e.g. [filename]):" default answer "")
set theTags to {} as list
tell application "Pages"
launch
if not (exists front document) then
display alert "Pages document must be open for this script to function properly."
if it is running then quit
return
end if
set thePath to POSIX path of (front document's file as alias) as text
set thePath to my tilde_path(thePath)
tell front document
set theTags to the tag of every placeholder text whose tag contains phtext
repeat with i from 1 to count of theTags
set thisTag to item i of theTags
set (every placeholder text whose tag is thisTag) to thePath as text
end repeat
end tell
end tell
return
on tilde_path(afile)
-- conceal user name in path as ~/Desktop/foo.pages
return ((NSString's stringWithString:afile)'s stringByAbbreviatingWithTildeInPath()) as text
end tilde_path