Hiding file extensions in Automator

Let's start over.

I have revised and tested an Automator solution on macOS Mojave 10.14.6 that will hide the extension of all files in the hierarchy of a selected directory in the Finder, or individually selected (⌘) files instead. I have added an initial dialog that with appropriate button selection, will then allow the Quick Action to hide or unhide the file extensions in the selection.

Just press return to enable Hide processing.

Build the Quick Action

1. Launch /Applications/Automator.app. In its dialog, select New Document, the Quick Action category, and then click the Choose button.
2. At the top of the empty Quick Action, set the following:
   1. Workflow receives current [ files or folders ↕︎ ] in [ Finder ]
   2. Change nothing else in this Quick Action header
3. On the left are the action libraries.
   1. Select Utilities, locate Run AppleScript, and then click and drag that action onto the large workflow window.
   2. Remove all boilerplate content in that Run AppleScript action.
   3. Replace the content of the now-empty Run AppleScript with the code below via copy/paste.
   4. Once the paste is complete, click the hammer icon in that Run AppleScript to syntax check and compile that AppleScript.
4. Save the Quick Action and give it a meaningful name (.e.g. Hidden Extensions).
5. Quit Automator
6. Right-click on a Folder, or selected files, and from the Finder's secondary menu, choose Quick Actions > Hidden Extensions.
7. The Quick Action will run, produce the initial dialog, change the files, and quit.

Code (to go into the Run AppleScript action)

use scripting additions
property hidden_status : true as boolean

on run {input, parameters}
	
	-- allow user to choose whether to hide or unhide file extensions
	try
		set ret to button returned of (display alert "Hide or Unhide File extensions?" buttons {"Cancel", "Unhide", "Hide"} default button "Hide" cancel button "Cancel" as informational)
		if ret is "Unhide" then set hidden_status to false
	on error number -128
		quit
	end try
	
	-- recursively hide file extensions in a selected folder, or on 
	-- individually selected files in the Finder
	tell application "Finder"
		repeat with anItem in input
			if kind of anItem is "Folder" then
				set theFiles to (every file in entire contents of folder anItem)
				repeat with afile in theFiles
					my hide_extension(afile, hidden_status)
				end repeat
			else
				my hide_extension(anItem, hidden_status)
			end if
		end repeat
	end tell
	return
end run

on hide_extension(sfile, abool)
	tell application "Finder"
		set owner privileges of sfile to read write
		set extension hidden of sfile to abool
		set owner privileges of sfile to read only
	end tell
	return
end hide_extension

on quit
	display alert "User Canceled and quitting…"
	continue quit
	# Automator will throw a dialog about encountering an error. Ignore it.
end quit

Here is what the finished Quick Action will look like in Automator:

The operating system requires the .pdf file extension to comprehend what type of files these are and what application category to open them. You can hide the displayed extension via the Finder, but should not remove it. The Finder also allows you to use the extended attribute comment field that exists on every file too.

Here is the replacement script for the Automator Quick Action's Run Shell Script. It will change the file to read/write before hiding the extension, and then setting the owner permission back to read only. If you don't want that last bit, you can place a comment # before that line, or remove it entirely. I also changed the shell in the script to Zsh.

Tested: macOS Monterey 12.2.1.

#!/bin/zsh

# make absolute path to folder
STARTDIR="${1:a:s/\~\//}"

function hide_ext () {
    # usage: $1 is folder
    #        $2 is true to hide extensions, or false to unhide them
    /usr/bin/osascript <<AppleScript
        use scripting additions

        set aFolder to (POSIX file "${1}") as alias
        tell application "Finder"
            set theFiles to (every file in entire contents of folder aFolder)
            repeat with anItem in theFiles
                set owner privileges of anItem to read write
                set extension hidden of anItem to ${2}
                set owner privileges of anItem to read only
            end repeat
        end tell
        return
AppleScript
    return
}

hide_ext "${STARTDIR}" "${2}"
exit 0



You are welcome. Something I also thought about after I posted this morning…

Ideally, the code should save the current owner privileges set on the file to a variable. If that result turns out to already be read write, then just hide (or unhide) the extension. If it is not read write, then change the owner privileges to read write and afterward, set the original owner permissions back on the file.

I now have the code to do this if you need it, and it can be integrated into the existing AppleScript.

To avoid setting the files to read-only, I would recommend the following change to the code:

Testing a script fix now…

Out of town right now. I will test the whole updated Automator solution on Mojave when I get home later this evening.