FYI: Generate custom Finder icon for RAW images (even if image format is not supported by macOS)

Another approach that does not use Adobe DNG converter, and instead uses the free third-party tool ExifTool.

In this case, it is an AppleScript that determines if ExifTool is installed and quits otherwise. It prompts for images of type public.camera-raw-image and then using that selected RAW image, will extract its internal icon data to a temp file. It then converts that temp data into an NSImage and proceeds to set the icon image on the RAW image.

# raw_icon.applescript

# extract the icon data from an unsupported camera RAW image and then set that image
# data on its icon.
# Dependency: ExifTool (https:exiftool.org) which installs into /usr/local/bin.
# Tested: macOS Big Sur 11.6.3, Exiftool 12.37

use framework "AppKit"
use AppleScript version "2.4" -- Yosemite or later
use scripting additions

property NSImage : a reference to current application's NSImage
property NSWorkspace : a reference to current application's NSWorkspace

# get the shell so we know which source statement to use below to get PATH info
set shell to (do shell script "echo $SHELL")

if shell is "/bin/zsh" then
	set XIF to (do shell script "source ~/.zshrc;/usr/bin/which exiftool")
else if shell = "/bin/bash" then
	set XIF to (do shell script "source ~/.bash_profile;/usr/bin/which exiftool")
end if

if XIF is missing value or XIF is "" then
	display alert "Need ExifTool installed." giving up after 10
end if

# only allow camera RAW images
set theImage to POSIX path of (choose file of type {"public.camera-raw-image"} default location (path to desktop) without invisibles) as text

# now check if the RAW image really does not have an icon set on it and quit if it does
try
	# returns 13 if sips cannot extract icon from RAW image when it is not supported by camera RAW db
	set ret to (do shell script "sips -i " & theImage & " > /dev/null; echo $?")
	if ret = 0 then return # because image was on it
on error number -128
	# user canceled
	return
end try

# extract the image icon data from the RAW file
do shell script XIF & " -a -b -preview:all " & theImage & " > /tmp/XXImage.png"
set thisImg to NSImage's alloc()'s initWithContentsOfFile:"/tmp/XXImage.png"
set status to ((NSWorkspace's sharedWorkspace)'s setIcon:thisImg forFile:theImage options:0) as boolean
tell application "Finder"
	delete POSIX file "/tmp/XXImage.png" as alias
	if status then reveal POSIX file theImage as alias
end tell
return

For the Nikon Z fc RAW image:

From:

To:

Hi there,

I'm trying to configure this for my A7IV files and I could not get it to work. I'm not sure if I'm doing something wrong but I tried to follow the steps in the READ ME file and I'm getting the error below. Should I change something in Automator app? For a life of me I can't figure out what I'm doing wrong. Any insights are highly appreciated.

Macbook Air M1 // Big Sur 11.5

Hey,

First of all thanks for a quick reply, I really appreciate it! I did few tests:

1) I placed four RAW (.ARW) files in the folder and as advised I changed the file names from .ARW to .CR3 (for 3/4 photos) and it worked! The thumbnails for .CR3 were updated

2)

A) After that I ran the "Start RAW Preview Batch' again (NOTE: currently in the folder there are three .CR3 files and only one .ARW)

B) When I got ask to select extension I entered ARW (screenshot below)

C) Selected the same folder as in the first test

D) Got a notification that three icons were not replaced:

It seems that AWR extension is not being picked by the script? Do you maybe have any idea on how to correct this behavior or if you have a scrip that defaults to .AWR files that would be awesome!

Thanks in advance :)