Applescript to find a text string in a PDF

Apple removed Python from macOS 12.3, so here is an AppleScript/Objective-C approach. It prompts for a search string, and then one or multiple PDFs. Each PDF is searched in its entirety for the search string and if found, a boolean true is returned, otherwise false. It does not loop through PDF pages, nor split those pages into separate PDF.

use framework "Foundation"
use framework "PDFKit"
use AppleScript version "2.4"
use scripting additions

property NSString : a reference to current application's NSString
property NSURL : a reference to current application's NSURL
property PDFDocument : a reference to current application's PDFDocument

set searchStr to text returned of (display dialog "Enter your search string: " default answer "") as text
if searchStr is "" or searchStr is missing value then return

set thesePDF to (choose file of type {"PDF"} with multiple selections allowed) as list

repeat with aPDF in thesePDF
	set truth to (my find_PDF_String(aPDF, searchStr)) as boolean
	log (truth & tab & searchStr's quoted form & tab & tab & aPDF as text)
end repeat
return

on find_PDF_String(aPDF, thestring)
	set aurl to NSURL's fileURLWithPath:(NSString's stringWithString:(POSIX path of aPDF))
	set pdf to PDFDocument's alloc()'s initWithURL:aurl
	# NSCaseInsensitiveSearch = 1, NSLiteralSearch = 2 and 1 | 2 = 3
	set options to 3
	# searches the entire PDF for searchStr
	set found to pdf's findString:thestring withOptions:options
	if (found as list) = {} then
		return (false as boolean)
	else
		return (true as boolean)
	end if
end find_PDF_String

Phil,

The following is a revised version of the original Hiroto script you posted. It omits a regular expression search for the search string, on each page, and instead uses the PDFDocument's find method that searches all Pages of the PDF. If there is a match, then it places 0 in the ret variable and if no matches, it sets it to 1. I excised the entire section that splits out and writes the individual PDF pages.

on main(inputs, outputFolder, params)
    
        (*
    
            list inputs : list of POSIX path of input files
    
            string outputFolder : POSIX path of output folder
    
            list params : optional parameters as list of strings
    
            return string : "OK" | "Warning" | "Error"
    
            * to be invoked by Esko Automation Engine
    
            cf.
    
            https://docs.esko.com/docs/en-us/automationengine/16/userguide/pdf/ae_ScriptRunner.pdf
    
        *)
    
        set a1 to ""
    
        repeat with a in inputs
            set a1 to a1 & a's quoted form & ":"
        end repeat
    
        set a1 to a1's text 1 thru -2 -- remove last excessive :
        set a2 to outputFolder's quoted form
    
        set ar to ""
    
        repeat with a in params
            set ar to ar & a's quoted form & space
        end repeat
    
        set args to a1 & space & a2 & space & ar
    
        try
    
            do shell script "/usr/bin/python <<'EOF' - " & args & "
    
    # coding: utf-8
    
    #   sys.argv[1]   : input files separatated by :
    
    #   sys.argv[2]   : output directory
    
    #   sys.argv[3..] : additional parameters
    
    #       sys.argv[3] => search string in page
    
    # 
    
    import sys
    import os
    import re
    from Foundation import NSURL
    from Quartz.PDFKit import PDFDocument
    
    uargv = [ a.decode('utf-8') for a in sys.argv ]
    outdir = uargv[2].rstrip('/')
    # re_pattern = re.compile(re.escape(uargv[3]) + '\\S*')
    search_string = uargv[3]
    ret = 0
    
    for f in [ a for a in uargv[1].split(':') if os.path.splitext(a)[1] == '.pdf']:
    
        url = NSURL.fileURLWithPath_(f)
        doc = PDFDocument.alloc().initWithURL_(url)
        options = 3  # NSCaseInsensitiveSearch | NSLiteralSearch
        found = doc.findString_withOptions_(search_string, options)
    
        # found will be an array of PDFSelections if there is a string(s) match in the entire PDF
        # or an empty array if nothing found
        ret = 0 if len(found) else 1
    
    sys.exit(ret)
    EOF"
    
            set {r, err} to {result, 0}
    
        on error errs number errn
            set {r, err} to {errs, errn}
        end try
    
        if err = 0 then
            return "OK"
        else if err = 1 then
            log r
            return "Warning"
        else
            log r
            return "Error"
        end if
    end main

Good, and you are welcome. Unfortunately, Script Editor does not automatically honor Python indenting, and if you are off by one space, it grumbles.

Oh, I forgot about you and Esko. 😎

If instead, you need this written in Python, I can do that for you too.

Phillip,

I will need some more time to look at this. Probably Sat 2022-04-02 afternoon. Will need more work than what I provided so far.