Numbers reference cell keep formatting

A more or less direct equivalent to your VBA is something like this in AppleScript.

tell application "Numbers"
	tell front document's active sheet
		tell (first table whose class of selection range is range)
			set tblName to its name
			my copyStyle("A2", tblName)
			delay 1 -- can vary; gives interface time to catch up
			my pasteStyle("B2", tblName)
		end tell
	end tell
end tell

to copyStyle(cellName, tblName)
	tell application "Numbers"
		tell front document's active sheet
			tell table tblName to set selection range to range cellName
			tell application "Numbers" to activate
			tell application "System Events" to keystroke "c" using {option down, command down}
		end tell
	end tell
end copyStyle

to pasteStyle(cellName, tblName)
	tell application "Numbers"
		tell front document's active sheet
			tell table tblName to set selection range to range cellName
			tell application "Numbers" to activate
			tell application "System Events" to keystroke "v" using {option down, command down}
		end tell
	end tell
end pasteStyle

1. Copy-paste into Script Editor (in Applications > Utility)
2. The first time make sure Script Editor is listed and selected at System Preferences > Security & Privacy > Privacy > Accessibility.
3. Change the cell references to match your setup
4. Click somewhere in the table, and the click the triangle 'run' button in Script Editor.

Note that this simply mimics the Copy Style and Paste Style in the Format menu. These are similar to the "paintbrush" in Excel. You can also add their equivalents to the Toolbar. So I tend to just use that easy-to-access built-in functionality, rather than a script.

SG

SG