How to export emails into a .CSV file

Here are detailed instructions on how to use this latest version to export emails into a .CSV or .TSV file:

Open a Script Editor app window (Click on an empty area of the Mac desktop so that no app window is currently active, then on the taskbar at the top of the Mac desktop select Go > Utilities > Script Editor). When a new empty Script Editor window opens, copy&paste the script into the window.

Open a Mail app window (Click on an empty area of the Mac desktop so that no app window is currently active, then on the taskbar at the top of the Mac desktop, select Go > Applications > Mail. If you have difficulty getting the Mail app window to open or if desired emails are not showing up in the Mail app, on the taskbar at the top of the Mac desktop, use Mail > Accounts... and select the desired account on the right or press the + sign at the bottom of the Internet Accounts window.

Once the desired emails are showing in the Mail app window, select the emails to be exported. Best to first select only a few emails and confirm that the script works properly before running it on a large number of emails.

You can use search to find selected emails based upon keywords, but best not to search in "All Mailboxes". Instead, best to select a folder (eg, Inbox) and search within that folder. If "All Mailboxes" is searched, the 'Mailbox folder' column in all rows of the exported .CSV or .TSV file are going to contain "Import", no matter what folder the selected emails are actually in and even if the selected emails are all in a single folder.

In the Script Editor app window, click the run button and watch the Running... indicator. If there are more than a hundred emails, the script can take many minutes to finish. If the script fails with a "Numbers got an error: Invalid row count.", then the script is not seeing any emails selected in the Mail app.

When the script runs successfully, it opens a new Numbers app window and writes the results into that window. When the script finishes, look for the new Numbers app window or open the Numbers app from the app bar that pops up from the bottom of the Mac desktop when the cursor is moved there. With Numbers app window active on the Mac desktop, use File > Export To > CSV... to save the result in .CSV format in the directory and file of your choice. (There is also an option to save the file in TSV (Tab-Separated Value) format, which is often a better option than CSV format.) Then, close the Numbers app window and click Delete if you don't want to save the result in spreadsheet format.

The Accounts... window in the Mail app suggests that it can be used to access emails on many different email servers (iCloud, Microsoft Exchange, Google Gmail, Yahoo Mail, AOL, and perhaps others). If that is true, then the attached Apple script can be used to extract emails from all those different servers. That is, of course, a big if. As we all know, despite Apple's mantra, Apple software often doesn't just work! 😣

By the way, the Apple support item at Save emails as files or PDFs in Mail on Mac - Apple Support explains how to save multiple selected emails into a single Rich Text Format file which will preserve an image of each email as displayed in the Mail app. When saving in .RTF format, leaving 'Include Attachments' selected may cause problems when later attempting to access the .RTF file on Microsoft Windows. The Microsoft Windows Wordpad app does not display page breaks, so it appears that all emails are on a single giant page, but the Microsoft Word app will display the emails with a page break between each email.

And please note that the Apple support item at Save emails as files or PDFs in Mail on Mac - Apple Support is quite misleading! 😣 The first option is "Save messages as files:". That option actually saves all selected emails into a single file. And there is no indication that there are potential issues when saving in .RTF format with 'Include Attachments' selected. The second option is "Save messages as PDFs:". That option saves each selected email into a separate .PDF file. The subject of the email is used as the name of the .PDF file. There is nothing in the Apple support item which explains what is going to happen if two emails have the same subject or what is going to happen if an email has no subject. The answers to those questions are almost certain to disappoint some users! 😣

When you are finished exporting all desired emails, if you no longer want the Mail app to access your email server, on the taskbar at the top of the Mac desktop, use Mail > Accounts... and in the Internet Accounts window, select the account which was added above and press the - sign at the bottom of the window.

And, oops, Microsoft Excel typically won't be able to properly import .CSV or .TSV files created by this script because the Excel legacy import wizard does not properly handle carriage return characters within text delimiters ("). 😣 I have written a 1000-line Perl script to parse a .TSV file produced using the attached Apple script and to build a sparse .TSV file suitable for import into Microsoft Excel and other spreadsheet programs. I can make that Perl script available if others need it. Just post a reply here.

My thanks again to SGIII for posting the original version of this Apple script.

Here is my latest version of the script which I enhanced to export the email subject:

# Edited from https://discussions.apple.com/thread/253056753
set dataLst to {{"SenderAddress", "SenderName", "Mailbox folder", "RecipientAddresses", "Date", "Time", "Subject", "Content"}}

tell application "Mail"
	repeat with aMsg in items of (get selection)
		tell aMsg
			set senderNameAddr to my splitEmail(sender)
			set senderAddr to item 2 of senderNameAddr
			set senderName to item 1 of senderNameAddr
			# Why the heck must 'of aMsg' be added to the end of this line?!??
			set nameMailbox to name of mailbox of aMsg
			set toRecipients to to recipients
			set theRecipientAddrs to address of item 1 of toRecipients
			repeat with i from 2 to (count of toRecipients)
				set theRecipientAddrs to theRecipientAddrs & " " & address of (get to recipient i) as rich text
			end repeat
			set ccRecipients to cc recipients
			repeat with i from 1 to (count of ccRecipients)
				set theRecipientAddrs to theRecipientAddrs & " " & address of (get cc recipient i) as rich text
			end repeat
			set bccRecipients to bcc recipients
			repeat with i from 1 to (count of bccRecipients)
				set theRecipientAddrs to theRecipientAddrs & " " & address of (get bcc recipient i) as rich text
			end repeat
			set msgSubj to subject
			set msgDate to date received
			set msgTime to time string of msgDate
			set msgDate to my dateFormat(date string of msgDate)
			set msgContent to content
			set msgLst to {senderAddr, senderName, nameMailbox, theRecipientAddrs, msgDate, msgTime, msgSubj, msgContent}
			copy msgLst to dataLst's end
		end tell
	end repeat
end tell

tell application "Numbers"
	set newDoc to make new document
	tell table 1 of active sheet of newDoc
		delete column "A" -- remove default Header Column
		set column count to length of item 1 of dataLst
		set row count to (length of dataLst)
		repeat with i from 1 to length of dataLst
			repeat with j from 1 to length of item 1 of dataLst
				set value of cell j of row i to item j of item i of dataLst
			end repeat
		end repeat
	end tell
end tell

to dateFormat(aDateString) --> yyyy-mm-dd
	set {year:y, month:m, day:d} to date aDateString
	tell (y * 10000 + m * 100 + d) as string to text 1 thru 4 & "-" & text 5 thru 6 & "-" & text 7 thru 8
end dateFormat

to splitEmail(nameAddress)
	set text item delimiters to "<"
	tell nameAddress
		set theName to text item 1
		set theAddress to text 1 thru -2 of text item 2
	end tell
	return {theName, theAddress}
end splitEmail

Here is my new version of the script:

# Edited from https://discussions.apple.com/thread/253056753
set dataLst to {{"SenderAddress", "SenderName", "Mailbox folder", "RecipientAddresses", "Date", "Time", "Content"}}

tell application "Mail"
	repeat with aMsg in items of (get selection)
		tell aMsg
			set senderNameAddr to my splitEmail(sender)
			set senderAddr to item 2 of senderNameAddr
			set senderName to item 1 of senderNameAddr
			# Why the heck must 'of aMsg' be added to the end of this line?!??
			set nameMailbox to name of mailbox of aMsg
			set toRecipients to to recipients
			set theRecipientAddrs to address of item 1 of toRecipients
			repeat with i from 2 to (count of toRecipients)
				set theRecipientAddrs to theRecipientAddrs & " " & address of (get to recipient i) as rich text
			end repeat
			set ccRecipients to cc recipients
			repeat with i from 1 to (count of ccRecipients)
				set theRecipientAddrs to theRecipientAddrs & " " & address of (get cc recipient i) as rich text
			end repeat
			set bccRecipients to bcc recipients
			repeat with i from 1 to (count of bccRecipients)
				set theRecipientAddrs to theRecipientAddrs & " " & address of (get bcc recipient i) as rich text
			end repeat
			set msgSubj to subject
			set msgDate to date received
			set msgTime to time string of msgDate
			set msgDate to my dateFormat(date string of msgDate)
			set msgContent to content
			set msgLst to {senderAddr, senderName, nameMailbox, theRecipientAddrs, msgDate, msgTime, msgContent}
			copy msgLst to dataLst's end
		end tell
	end repeat
end tell

tell application "Numbers"
	set newDoc to make new document
	tell table 1 of active sheet of newDoc
		delete column "A" -- remove default Header Column
		set column count to length of item 1 of dataLst
		set row count to (length of dataLst)
		repeat with i from 1 to length of dataLst
			repeat with j from 1 to length of item 1 of dataLst
				set value of cell j of row i to item j of item i of dataLst
			end repeat
		end repeat
	end tell
end tell

to dateFormat(aDateString) --> yyyy-mm-dd
	set {year:y, month:m, day:d} to date aDateString
	tell (y * 10000 + m * 100 + d) as string to text 1 thru 4 & "-" & text 5 thru 6 & "-" & text 7 thru 8
end dateFormat

to splitEmail(nameAddress)
	set text item delimiters to "<"
	tell nameAddress
		set theName to text item 1
		set theAddress to text 1 thru -2 of text item 2
	end tell
	return {theName, theAddress}
end splitEmail

By the way, can anyone tell me why the heck the line 'set nameMailbox to name of mailbox of aMsg
' must have 'of aMsg' at the end? Doesn't 'tell aMsg' imply 'of aMsg' for each line?

The 'Invalid row count' error occurs when there are no emails selected in the Mail app. The script only exports those emails which are selected.