Aperture 3 import date format

I agree with this being a bizarre omission from Aperture.

I had the clever idea that maybe it was following one of the formats defined in the International preference pane, but changing them had no effect.

Fortunately, Aperture 3 allows running an AppleScript after import. Choose Actions from the Import settings and select an AppleScript file you want to run after the images have been imported. The documentation provided in the Aperture AppleScript Referenceprovides an example on page 30. What is left unsaid is that the handler is called once for each project created during the import, with the input argument being a list of images added to that project.

Here's an AppleScript you can save and use as an import action. It changes the name of each folder to a date string in the form yyyy-mm-dd. It should be pretty easy to change if you want some other format. It should also be pretty easy to change if you want to add the date as a suffix to the project name you provided in the input settings if you didn't leave that blank.

(* Aperture 3 Script by Mitchell L Model, mlm at acm dot org, May 28, 2011 *)

(* Choose this script to run after importing images with automatic split

selected; it will rename the projects created for each date to the format

defined by the crude handler formatImageDate defined below.

Yes, that handler could have been written as:

return do shell script "date +'%Y-%m-%d'"

but this way demonstrates the use of EXIF tag values.

Change or generalize the formatting as you wish.

It would be nice if Aperture used one of the date formats set in the International

Preference Pane -- in particular the short date -- so that you could simply change

that to be the way you want the split folders to be named, but it deosn't.

*)

-- Experimentation shows that the handler is called once for each project created by the import,

-- with input a list of images placed in that project

on ImportActionForVersions(input)

tell application "Aperture"

set the name of the parent of the first item of input to my formatImageDate(the first item of input)

end tell

end ImportActionForVersions

-- Note: numerical EXIF tag values are real numbers and must be converted to integers for these manipulations

to formatImageDate(theImage)

tell application "Aperture"

set y to the value of EXIF tag named "CaptureYear" of theImage

set m to the value of EXIF tag named "CaptureMonthOfYear" of theImage

set d to the value of EXIF tag named "CaptureDayOfMonth" of theImage

return (y as integer as string) & "-" & my twoDigitString(m) & "-" & my twoDigitString(d)

end tell

end formatImageDate

on twoDigitString(num)

set n to num as integer-- to handle floats

if n < 10 then

return "0" & n as string

end if

return n as string

end twoDigitString

Works like a charm. I whish I could bend my mind around applescript, it is too weird. 😀

Thanks for the script! Works great.

Any Scripting Guru around who might explain how to apply this to "old" folders which have the undesired automatic name?

Thanks for sharing the script - it worked perfectly.

It worked for me as well, thanks!