Previous 1 13 14 15 16 17 Next 347 Replies Latest reply: Apr 9, 2015 5:54 AM by subrezze Go to original post Branched to a new discussion.
  • Edumara Level 1 Level 1 (0 points)

    When I did this, months ago, I didn't actually download iTunes 10.3.1 from anywhere. I retrieved a copy from a backup. I can tell you its size is 149.3 MB, but I have no idea from where it can be downloaded as such. There might be something in the Snow Leopard installation DVD, but I don't think it'll be 10.3.1 as such.

  • Edumara Level 1 Level 1 (0 points)

    Follow the instructions step by step. I think they appear on page 8 of this thread.

  • Edumara Level 1 Level 1 (0 points)

    Since I devised the above-referred temporary solution months ago, before iTunes 10.5, I think the instructions appearing on page 8 of this thread should be updated. So, here are up-to-date instructions:

     

     

     

    A TEMPORARY SOLUTION (updated, February 2012)

     

     

    Faced with the dilemma of having an iCloud-ready version of iTunes (10.4 and above) or a Front Row-compatible version of iTunes (10.3.1) running on Lion, and while we wait for a definitive solution brought by Apple, there are things we can do to have the best of both worlds running on Lion through some Applescript code. I've quickly put together the code presented below, which can still be greatly improved upon. Although it is offered with no guarantees, it should work well in most situations. For it to work properly, several requirements must be met:

    1. The script is intended to run on Lion. It's unnecessary in Snow Leopard and it won't work in anything below Lion.
    2. iTunes 10.4 or higher must be installed.
    3. A copy of the iTunes 10.3.1 application (i.e., not the framework or any other components) must ALSO be in the /Applications folder with the name "iTunes 10.3.1". If you already have iTunes (10.4 or higher) in place, simply copy a backup copy of the previous iTunes. Remember to rename it as "iTunes 10.3.1". Unless you have a backup copy of iTunes 10.3.1, you may need to search for the relevant installer on the Internet, but you'll need to extract just the application from it (using, for instance, Pacifist).
    4. A copy of the old-style iTunes Library (iTunes Library.itl) must exist in ~/Music/iTunes with the name "old-style iTunes Library.itl". You can get it from ~/Music/iTunes/Previous iTunes Libraries.
    5. A copy of the new-style iTunes Library (iTunes Library.itl if you have run iTunes 10.4 or higher)  must exist in ~/Music/iTunes with the name "new-style iTunes Library.itl".
    6. Front Row must have been reinstalled. Ralph Perdomo created a package to achieve this on Lion.

     

    If all six requirements are met, the following script (name it anything you like and place it wherever it suits you) will see to it that your iTunes Library is, at all times, ready to do what you want it to do, effecting EITHER (future) iCloud-compatibility OR Front Row-compatibility. Notice that this doesn't involve any hacks of any kind. When you swap from iCloud-compatibility to Front Row-compatibility, and vice versa, the script makes some noise (it sends temporary files to the trash). A revamped version of the script might avoid this noise in future. The script even allows you to launch Front Row from it if you've just used it to make your iTunes Library Front Row-compatible.

     

    Here's the script:


     

    #Make sure any instances of iTunes (10.3.1 or above) is closed

    set iTunesVersion to "iTunes"

    tell application iTunesVersion

           quit

    end tell

     

    #Establish common dialog title

    set dialogTitle to "iTunes integration with Front Row/iCloud on Lion"

     

    #Check that Lion is running

    set osVersion to do shell script "sw_vers -productVersion"

    if osVersion < "10.7" then

           display dialog "This is not intended for versions below OS X 10.7 Lion" buttons {"OK"} with title dialogTitle with icon stop

           return

    end if

     

    #Check that iTunes 10.4 or above is installed

    set iTunesMainVersion to ""

    tell application iTunesVersion

           set iTunesMainVersion to version

    end tell

    if iTunesMainVersion < "10.4" then

           display dialog "This can only run if your regular version of iTunes is 10.4 or above" buttons {"OK"} with title dialogTitle with icon stop

           return

    end if

     

    #Check that iTunes 10.3.1 is also installed

    try

           set iTunesFrontRowVersion to (path to applications folder as text) & "iTunes 10.3.1.app" as alias

    on error number -43

           display dialog "This can only run if, in addition to iTunes 10.4 or above, you have iTunes 10.3.1 in your Applications folder" buttons {"OK"} with title dialogTitle with icon stop

           return

    end try

     

    #Check that old-style iTunes Library.itl exists

    set oldStyle_iTunesLibrary to ""

    try

           set oldStyle_iTunesLibrary to (path to home folder as text) & "Music:iTunes:old-style iTunes Library.itl" as alias

    on error number -43

           display dialog "old-style iTunes Library.itl does not exist in" & (path to home folder as text) & "Music:iTunes:" buttons {"OK"} with title dialogTitle with icon stop

           return

    end try

     

    #Check that new-style iTunes Library.itl exists

    set newStyle_iTunesLibrary to ""

    try

           set newStyle_iTunesLibrary to (path to home folder as text) & "Music:iTunes:new-style iTunes Library.itl" as alias

    on error number -43

           display dialog "new-style iTunes Library.itl does not exist in" & (path to home folder as text) & "Music:iTunes:" buttons {"OK"} with title dialogTitle with icon stop

           return

    end try

     

    #Make sure iTunes 10.4 or above is closed

    tell application iTunesVersion

           quit

    end tell

     

    #Make sure iTunes 10.3.1 is closed

    set iTunesVersion to "iTunes 10.3.1"

    tell application iTunesVersion

           quit

    end tell

     

    #Check that Front Row is installed

    try

           set iTunesFrontRowVersion to (path to applications folder as text) & "Front Row.app" as alias

    on error number -43

           display dialog "This can only run if you have installed Front Row" buttons {"OK"} with title dialogTitle with icon stop

           return

    end try

     

    #Establish version of current iTunes Library.itl

    set currentItlLibrary to (path to home folder as text) & "Music:iTunes:iTunes Library.itl" as alias

    set currentItlLibraryVersion to (read (currentItlLibrary) from 18 to 23 as string)

     

    #Prompt the user as to their choices

    set message to "The current version of iTunes Library.itl is " & currentItlLibraryVersion & ", which is compatible with "

    if currentItlLibraryVersion < "10.4" then

           set message to message & "Front Row.

    Do you want to make it iCloud-compatible instead?"

    else

           set message to message & "iCloud.

    Do you want to make it Front Row-compatible instead?"

    end if

    set question to display dialog message buttons {"Yes", "No"} default button 2 with title dialogTitle with icon 2

    set answer to button returned of question

     

    #If the user decides not to change the format, quit

    if answer = "No" then

           return

    end if

     

    if currentItlLibraryVersion < "10.4" then

           #Copy iTunes Library.itl to old-style iTunes Library.itl

           tell application "Finder" to duplicate file currentItlLibrary

           tell application "Finder" to delete file oldStyle_iTunesLibrary

           set temporary_iTunesLibrary to (path to home folder as text) & "Music:iTunes:iTunes Library copy.itl" as alias

           tell application "Finder" to set name of file temporary_iTunesLibrary to "old-style iTunes Library.itl"

          

           #Copy new-style iTunes Library.itl to iTunes Library.itl

           tell application "Finder" to duplicate file newStyle_iTunesLibrary

           tell application "Finder" to delete file currentItlLibrary

           set temporary_iTunesLibrary to (path to home folder as text) & "Music:iTunes:new-style iTunes Library copy.itl" as alias

           tell application "Finder" to set name of file temporary_iTunesLibrary to "iTunes Library.itl"

          

           #Launch newer version of iTunes so that it will update the library, if necessary

           #     do shell script "/Applications/iTunes.app/Contents/MacOS/iTunes -ProfileManager"

           set iTunesVersion to "iTunes"

           tell application iTunesVersion

                  launch

           end tell

          

          

           #Advise the user

           display dialog "iTunes has been launched so that it will update its library with whatever purchases you may have made while running iTunes 10.3.1. You may quit iTunes whenever you are ready. Front Row integration has been suspended and iCloud integration restored." buttons {"OK"} with title dialogTitle with icon 2

    else

           #Copy iTunes Library.itl to new-style iTunes Library.itl

           tell application "Finder" to duplicate file currentItlLibrary

           tell application "Finder" to delete file newStyle_iTunesLibrary

           set temporary_iTunesLibrary to (path to home folder as text) & "Music:iTunes:iTunes Library copy.itl" as alias

           tell application "Finder" to set name of file temporary_iTunesLibrary to "new-style iTunes Library.itl"

          

           #Copy old-style iTunes Library.itl to iTunes Library.itl

           tell application "Finder" to duplicate file oldStyle_iTunesLibrary

           tell application "Finder" to delete file currentItlLibrary

           set temporary_iTunesLibrary to (path to home folder as text) & "Music:iTunes:old-style iTunes Library copy.itl" as alias

           tell application "Finder" to set name of file temporary_iTunesLibrary to "iTunes Library.itl"

          

           #Launch older version of iTunes so that it will update the library, if necessary

           set iTunesVersion to "iTunes 10.3.1"

           tell application iTunesVersion

                  launch

           end tell

          

           #Advise the user

           set question to display dialog "iTunes 10.3.1 has been launched so that it will update its library with whatever purchases you may have made while running newer versions of iTunes. You may quit iTunes whenever you are ready. iCloud integration has been suspended and Front Row integration restored." buttons {"Close", "Close iTunes", "Launch Front Row"} default button 3 with title dialogTitle with icon 2

           set answer to button returned of question

          

           #If the user decides not to do anything, quit

           if answer = "Close" then

                  return

           end if

           tell application iTunesVersion

                  quit

           end tell

           if answer = "Launch Front Row" then

                  tell application "System Events"

                         key code 53 using command down

                  end tell

           end if

    end if

     

    -------------------------------------------------------------

    Enjoy!

  • Aescleal Level 1 Level 1 (0 points)

    4.  A copy of the old-style iTunes Library (iTunes Library.itl) must exist in ~/Music/iTunes with the name "old-style iTunes Library.itl". You can get it from ~/Music/iTunes/Previous iTunes Libraries.

     

    I've never had iTunes 10.3 on my Mini.  I bought it with Lion and it came with iTunes 10.5.

    If Pacify can yank 10.3.1 from the .pkg I found, could I simply run the iTunes 10.3.1 .app and build a new 10.3 .itl?  Could it really be that simple?  Would this give me the old version of the .itl that I need for step 4?

     

    Edumara, I love what this script may do for me.  So I'm stoked to make it happen.  I just want to be sure it'll work for me in my environment without breaking things!

     

    Funny this is on the Apple forums, and no support is being provided by Apple.  Even funnier that this discussion isn't being shut down by Apple.

     

    Thank you for all the work you've done here,

    And thank you for being patient with fellows like me,

    Aescleal

  • Edumara Level 1 Level 1 (0 points)

    On a hunch, I would suggest that the following may work for you:

     

    1. Using Pacifist, copy iTunes.app to your desktop.
    2. On your desktop, rename the copied iTunes.app to iTunes 10.3.1.app
    3. Move the renamed application to /Applications
    4. Go to ~/Music/iTunes
    5. Move the "iTunes Library.itl" file (depending on your setup, you might not see the "itl" part) to your desktop
    6. Launch the iTunes 10.3.1 application. Hopefully, it will recreate a Front-Row-compatible itl version from the iTunes Library.xml file.
    7. If that works, you are almost done. Simply copy the newly created "iTunes Library.itl" to "old-style iTunes Library.itl"
    8. On your desktop, rename "iTunes Library.itl" to "new-style iTunes Library.itl" and move it back to ~/Music/iTunes

     

    If you follow this procedure, your iTunes library will be Front Row-compatible. Now, if you run my script, it will offer you the possibility of making the library iCloud-compatible instead. If you accept, Front Row compatibility will be partially (and temporarily) broken, until you run my script again and accept to make the library Front Row-compatible, thereby temporarily abandoning iCloud compatibility.

     

    In any case, remember that whenever you run the current iTunes application (version 10.5.3 as I type this), the library will be updated to the iCloud-compatible version if it was Front Row-compatible before, an action that can be reversed by again running my script.

     

    Sadly, I can't foresee what will happen when Apple release iTunes 10.6 or iTunes 11. Chances are the method I advocate will stop working as a result of fundamental differences in the iTunes frameworks this "toggle compatibility" relies on. That is, if the iTunes frameworks of versions 10.6 or 11.0 become different from those of version 10.3/10.4/10.5, this method might stop working, but, hopefully, that's still months or even years ahead of us.

  • Aescleal Level 1 Level 1 (0 points)

    Thanks for that.  I'll try this out tonight.  I hope it works.  I love Front Row.  First seen it on a friends Mini, and a year later I'm moved far from that friend and buy my first Mac.  I've tried Plex, and it works but is just to much/busy for my family to adopt.  So I'm very eager to get FR working in full glory.  And I understand I can't downgrade my Mini becuase it's firmware is patched up and locked for Lion +.  So that leaves playing with iTunes!

     

    So THANK YOU for taking this time to help me out.  I'm crossing my fingers this works out.  It sounds like the best tool on the internet!  So I can't wait!

     

    I'll post back here with my findings.

     

    And well, I'll cross my fingers that Apple will hear our plea, and give back Front Row, or an Apple TV app of similar funtionality.  And as mentinoed here, perhaps even a new iTunes with a media centre front end built in!

  • Michael Paine Level 2 Level 2 (320 points)

    No sign of a "fix" (bringing back Front Row or a replacement) in reviews of Mountain Lion. It will be able to stream videos to Apple TV but no media center capability.

     

    Grrr

  • Aescleal Level 1 Level 1 (0 points)

    Perhaps they will open up to developers wanting to write apps for iTunes.  Then some enterprising person or group can write an app that replaces Front Row and actually works directly with iTunes!

     

    Then it's just a matter of convincing them that less is more!

  • Apple4Ever556 Level 1 Level 1 (30 points)

    i'm confused how to do it?

  • Apple4Ever556 Level 1 Level 1 (30 points)

    On a hunch, I would suggest that the following may work for you:

     

    1. Using Pacifist, copy iTunes.app to your desktop.
    2. On your desktop, rename the copied iTunes.app to iTunes 10.3.1.app
    3. Move the renamed application to /Applications
    4. Go to ~/Music/iTunes
    5. Move the "iTunes Library.itl" file (depending on your setup, you might not see the "itl" part) to your desktop
    6. Launch the iTunes 10.3.1 application. Hopefully, it will recreate a Front-Row-compatible itl version from the iTunes Library.xml file.
    7. If that works, you are almost done. Simply copy the newly created "iTunes Library.itl" to "old-style iTunes Library.itl"
    8. On your desktop, rename "iTunes Library.itl" to "new-style iTunes Library.itl" and move it back to ~/Music/iTunes

     

    If you follow this procedure, your iTunes library will be Front Row-compatible. Now, if you run my script, it will offer you the possibility of making the library iCloud-compatible instead. If you accept, Front Row compatibility will be partially (and temporarily) broken, until you run my script again and accept to make the library Front Row-compatible, thereby temporarily abandoning iCloud compatibility.

     

    In any case, remember that whenever you run the current iTunes application (version 10.5.3 as I type this), the library will be updated to the iCloud-compatible version if it was Front Row-compatible before, an action that can be reversed by again running my script.

     

    Sadly, I can't foresee what will happen when Apple release iTunes 10.6 or iTunes 11. Chances are the method I advocate will stop working as a result of fundamental differences in the iTunes frameworks this "toggle compatibility" relies on. That is, if the iTunes frameworks of versions 10.6 or 11.0 become different from those of version 10.3/10.4/10.5, this method might stop working, but, hopefully, that's still months or even years ahead of us.

     

     

     

     

     

     

    i'll try this.

  • Apple4Ever556 Level 1 Level 1 (30 points)

    I Tried to do it but stopped in the middle cause it started up iTunes all over again from Beginning? so i wanted to know if it will Delete anything? before I Try again? & I Have a 2009 24inch iMac Computer.

  • Edumara Level 1 Level 1 (0 points)

    What do you mean "stopped in the middle"? In the middle of what? There are several things you need to do "manually", such as copying iTunes 10.3.1 to your Applications folder, and creating the relevant new- and old-style copies of iTunes Library.itl. That MUST be done before running the script. As for the script itself, you only need to copy the code I provided and SAVE it as a script or an application and then run it. The script is commented, so even people with no programming skills should figure out what the script does. And, yes, as the comments say, it does launch iTunes (either 10.3.1 or 10.4+). And yes, as the comments say, it does erase temporary versions of the new- and old-style copies of iTunes Library.itl. It won't delete any real elements of iTunes, unless you mess up everything yourself (for instance, wildly ranaming iTunes files to script-reserved names).

  • Apple4Ever556 Level 1 Level 1 (30 points)

    I Was doing the instructions then when I went on iTunes it felt like all my things were almost Erased cause iTunes started up all over again from New with nothing in it meaning all my items were gone? so thats why i stopped in the middle to Find out if thats the way it's suppose to be?

  • Edumara Level 1 Level 1 (0 points)

    OK. As I said, my suggestion for someone who never had previous version of iTunes installed was just a hunch. If you move your iTunes Library.itl to your desktop, it is obvious that iTunes (10.3.1 or any other) will have to rebuild it from scratch, which I guess will take a few minutes (depending on the contents). But perhaps it won't do it on its own, and you may need to "help" iTunes by signalling the albums, etc., you want to "import". In any case, once a new 10.3.1-compatible iTunes Library.itl has been (re)created, the script should work as described (if you place the relevant old- and new-style copies of the library alongside the newly created iTunes Library.itl. After that, having a Front Row-compatible iTunes or an iCloud-compatible iTunes ought to be trivial.

  • Aescleal Level 1 Level 1 (0 points)

    @ Edumara

    Well a big thank you!  Your advice had made Front Row work at 90% or greater functionality!  I'd even say nearly 100% if I had a frame of reference, but since I'm new to Front Row, it could just be that I don't understand some workings of iTunes and Front Row.

    But I no longer have to share my iTunes and run a localhost script just to get to see my collections in Front Row.  Now I simply just start FR and I see my movies/shows/music.  It's wonderful.

     

    My newbie questions, since I've a FR rookie, are:

    1. Does FR read all videos at music?  It seems to me my video colletion mostly shows up as an "Unkown" folder in FR if I don't populate all the music related fields in iTunes (Get Info).  Also in the description (left side of screen in FR) it identifies episodes at Tracks.

    2. All videos default to Media Kind: Movies when you first import them.  I believe that's normal.  But after changing media kind to TV Show in iTunes, they still show up in FR under Movies, but now also TV Shows.  At least under TV Shows, FR has them organized in folders.  Is this normal for FR to show duplicates of videos in both places?  Or is this a glitch there is an easy fix for?  Oh, and in the iTunes folder /iTunes Media/ I made sure the Movies folder is empty, and all tv shows are in the TV Shows folder.  Still no love!

    3.  FR seems slow to read and update/sync with iTunes 10.3.1.  iTunes 10.3.1 is running in the background when I run Front Row.  I made a change to my TV Show collection, and it seems I have to open/close FR several times before it recognized the changes.  Typical changes made are to add name of shows to Artist & Composer fields in hopes of better managing the Show.  Is that normal for Front Row?  Perhaps iTunes needs to be shut down to update/close the .itl file so FR can read it?

    4.  Lastly, i'm probably going to buy VideoDrive2 to help organize and manage metadata for my collections.  Does this metadata show up in FR?

     

    Again, I'm a rookie.  I'm not trying to be stupid...  I just am with this stuff.  I'm just hoping for some understanding, as I'm not only new to iTunes and Front Row, but Macintosh in general.

    Thanks Edumara,

    Aeacleal

     

    And I have to add...  Apple, what the heck are you doing getting rid of Front Row?  For the love of... please replace it in Lion or Moutain Lion with a new version.  Or if you have to, add an AppleTV app to the app store.  I'd pay money for a good Apple Media Centre I could run from my 2011 Mac Mini.

Previous 1 13 14 15 16 17 Next