Can't figure out how to read from plist

Standard Additions has a path to command that will return paths to most of the common places.

You will need to use either the Property List Suite from System Events or the defaults shell utility to access the individual keys in the plist file. Since you are using defaults in your example, that is what I used in mine. The following example script includes plist read, write, file check and creation:

set prefsFolder to (path to preferences from user domain) as text -- the user's preferences folder
set plistFile to POSIX path of (prefsFolder & "example") -- the plist file, minus extension
#default values
set username to "Joseph Blow"
set emailaddress to "nunya@bizness"
set ipaddress to "192.168.1.255"
try -- test for file and read values if there
   (plistFile & ".plist") as POSIX file as alias
   set username to (do shell script "defaults read " & plistFile & " username")
   set emailaddress to (do shell script "defaults read " & plistFile & " emailaddress")
on error errmess -- no file, so make one
   log errmess
   do shell script "touch " & quoted form of (plistFile & ".plist") -- make new file
   do shell script "defaults write " & plistFile & " username " & quoted form of username
   do shell script "defaults write " & plistFile & " emailaddress " & emailaddress
   do shell script "defaults write " & plistFile & " ipaddress " & ipaddress
end try
set currentAddress to word 25 of (do shell script "curl checkip.dyndns.org")
set oldAddress to (do shell script "defaults read " & plistFile & " ipaddress")
if oldAddress is not currentAddress then -- update and notify
   do shell script ("defaults write " & plistFile & " ipaddress " & currentAddress)
   tell application "Mail"
      activate
      set newMessage to make new outgoing message with properties {visible:true, subject:"Your IP address has changed", content:"Your current IP address is: " & currentAddress}
      tell newMessage
         make new to recipient at end of to recipients with properties {name:username, address:emailaddress}
      end tell
      -- send newMessage -- remove comment to 'go live'
   end tell
else
   log "no change"
end if

AppleScript doesn't do a lot of stuff by itself, such as getting IP addresses, but instead calls on other applications or utilities to do things beyond the language itself. A shell script is a typical way to get the IP address, I just used a shorter one.

My example checks to see if the plist file exists (the try...on error...end try part) - if it does the username and emailaddress keys are read from the plist, otherwise a new plist file is created and set to the default values. You didn't include your other script, so I just posted a complete script - the plist file should have a format such as:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
   <key>emailaddress</key>
   <string>nunya@bizness</string>
   <key>ipaddress</key>
   <string>192.168.1.255</string>
   <key>username</key>
   <string>Joseph Blow</string>
</dict>
</plist>

Removing the plist file test/create part, the script would be something like the following (the plist file needs to exist in the user's preferences folder, so change the name as needed):

set prefsFolder to (path to preferences from user domain) as text -- the user's preferences folder
set plistFile to POSIX path of (prefsFolder & "example") -- the plist file, minus extension
set username to (do shell script "defaults read " & plistFile & " username")
set emailaddress to (do shell script "defaults read " & plistFile & " emailaddress")
set currentAddress to word 25 of (do shell script "curl checkip.dyndns.org")
set oldAddress to (do shell script "defaults read " & plistFile & " ipaddress")
if oldAddress is not currentAddress then -- update and notify
   do shell script ("defaults write " & plistFile & " ipaddress " & currentAddress)
   tell application "Mail"
      activate
      set newMessage to make new outgoing message with properties {visible:true, subject:"Your IP address has changed", content:"Your current IP address is: " & currentAddress}
      tell newMessage
         make new to recipient at end of to recipients with properties {name:username, address:emailaddress}
      end tell
      -- send newMessage -- remove comment to 'go live'
   end tell
else
   log "no change"
end if