vbs script for iTunes converted for use on Mac?

What's there to translate?

with timeout of 10000 seconds
tell application "iTunes"
play playlist "run" -- change to actual playlist name
delay (5 * minutes)
play playlist "walk" -- change to actual playlist name
delay (2 * minutes)
end tell
end timeout

[edit] :o) it's can get very complicated: see this http://hac.95mb.com/Techs.html, those two apps were written in AppleScript.

Cy,
You forgot the ding 😉

play playlist "run" -- change to actual playlist name
delay (5 * minutes)
beep
play playlist "walk" -- change to actual playlist name

Reese

doh!

my bad, you mean stopping at the end of 2 minutes of playlist "walk"?

with timeout of 10000 seconds
tell application "iTunes"
play playlist "run" -- change to actual playlist name
delay (5 * minutes)
beep
play playlist "walk" -- change to actual playlist name
delay (2 * minutes)
beep
stop
end tell
end timeout

or for a real interval work out:

with timeout of 10000 seconds
repeat 10 times -- this is ten interval, that 70 min 🙂
tell application "iTunes"
play playlist "run" -- change to actual playlist name
delay (5 * minutes)
beep
play playlist "walk" -- change to actual playlist name
delay (2 * minutes)
beep
end tell
end repeat
end timeout

IMHO: do it outside... Luke, don't let the machines rule you. :o)

Correct me if I'm missing something here, but isn't the point of the script to set new end times for each track of a playlist? That way the timed ding works on your iPod while out running, not just while at your computer (on a treadmill?).

Assuming you haven't replaced your iPod's firmware with iPodLinux, you can consider the iPod software sealed. In other words, it's not going to run an AppleScript. To get around this all we need to do is manipulate two basic features of the iPod:

The iPod...
A. respects arbitrary end points set by individual tracks.
B. will play a static playlist in order.

So as you can imagine this requires a somewhat fragile arrangement be set up ahead of time in iTunes. The steps might be something like this:

You...
1. create a playlist with all the tracks you want to listen to on your run.
2. select the playlist in iTunes and run the AppleScript.

The Script...
1. gets a list of tracks in the original playlist.
2. creates a new blank static playlist.
3. gets the length of the first track in the track list.
4. if the track is less than five minutes, it adds the track to the new playlist, and gets the length of the next track from the track list.
5. if the length of the next track plus the length of all previously added tracks is greater than five minutes, the script sets an arbitrary end point in the next track at the five minute total-elapsed-time mark.
6. the modified track is added to the new playlist.
7. the 'ding' track is added to the new playlist.
8. steps 4 thru 7 repeat, alternating between a five and two minute limit, until the script reaches the end of the track list.

You...
3. add the new playlist to your iPod. (by syncing, etc.)
4. play the new playlist on your run.

Now, there are a couple problems with this set up. For one, there is no mechanism for resuming a track that has been interrupted for a ding. You could re-play the track from the beginning, but it will still end prematurely. The only way around that would be to have the script actually duplicate the physical mp3 file and set the start time of the copy to match the end time of the original.

Another problem arises when you want to listen to a truncated track normally (either on your mac or the iPod). In this case you'll want a script that can undo all the changes the first script made. It would delete the generated playlist (it's useless without a strict arrangement of tracks) and set all of the track end points to the actual length of each track.

But does running this script on a certain playlist mean that the songs in that playlist will also play truncated in other playlists as well?

Yes. A playlist is merely a collection of references to individual files and their database entries. Changing a property of a track from a playlist is the same as changing it from the Library or anywhere else, because every reference points to the same data.

Okay, try this.

click here to open this script in your editor <pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">property run_min : 5
property walk_min : 2

tell application "iTunes"
set source_pl to the view of the front browser window
try
set ding_track to the first track of the first playlist whose name is "Ding"
on error
display dialog "Please make sure a track with the title \"Ding\" is in your iTunes library before running this script." buttons {"Cancel"} default button 1
end try
if the name of source_pl is "Library" then if the button returned of (display dialog "It appears that you have selected your entire iTunes Library (" & (count tracks of the source_pl) & " tracks), are you sure you want to continue?" buttons {"why not?", "NO!!!!!!!!"} default button 2) is not "why not?" then
error number -128
else if the text returned of (display dialog "...because the script will take awhile, and you'll end up with annoying end points inserted randomly throughout your entire library, that's why. If you're still certain this is what you want, type \"yes\" below and click Nuke It, or you can Chicken Out instead." default answer "" buttons {"Nuke It", "Chicken Out"} default button 2) is not "yes" then
error number -128
end if
set {error_msg, error_str} to {"", "Syntax Error!" & return & return & "To enter fractions of a minute use:" & return & "1.5 (for 1 min 30 sec)" & return & "5.25 (for 5 min 15 sec)" & return & "etc." & return & return}
repeat
try
set run_min to text returned of (display dialog error_msg & "Set the running interval: (in minutes)" default answer run_min) as number
if result ≤ 0 then error
set error_msg to ""
repeat
try
set walk_min to text returned of (display dialog error_msg & "Set the walking interval: (in minutes)" default answer walk_min) as number
if result ≤ 0 then error
exit repeat
on error number x
if x is -128 then error number -128
end try
set error_msg to error_str
end repeat
set {run_sec, walk_sec} to {run_min * minutes, walk_min * minutes}
exit repeat
on error number x
if x is -128 then error number -128
end try
set error_msg to error_str
end repeat
set new_pl to "*" & source_pl's name
repeat
if not (playlist new_pl exists) then
set new_pl to make new playlist with properties {name:new_pl}
exit repeat
else if button returned of (display dialog "A playlist with the name \"" & new_pl & "\" already exists. What would you like to do?" buttons {"Cancel", "Use Different Name", "Replace Playlist"} default button 3) is "Use Different Name" then
set new_pl to text returned of (display dialog "Enter a different name for the new playlist:" default answer new_pl & space & (do shell script "date '+%y-%b-%d %H.%M.%S'"))
else
set new_pl to playlist new_pl
exit repeat
end if
end repeat
set the view of the front browser window to new_pl
delete tracks of new_pl
set {trip_tally, trip_time} to {0, run_sec}
repeat with a_track in source_pl's tracks
set a_length to the duration of a_track
if a_length + trip_tally > trip_time then
set finish of a_track to trip_time - trip_tally
duplicate a_track to new_pl
duplicate ding_track to new_pl
set trip_tally to 0
if trip_time is run_sec then
set trip_time to walk_sec
else
set trip_time to run_sec
end if
else
set trip_tally to trip_tally + a_length
duplicate a_track to new_pl
end if
end repeat
end tell
</pre>Note that since the default values are persistent properties, you won't need to edit the script to change them. Any new value will be automatically remembered between runs.

Here is another script to undo changes made by the first script. Note here that it doesn't really clear the arbitrary end, it merely matches it to the length of the track. I'm not sure there is a way to accomplish the former, but this may be good enough:

click here to open this script in your editor <pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">tell application "iTunes" to repeat with a_track in tracks of the front browser window's view
tell a_track
get duration -- this needs to be on its own line for some reason
set finish to result
end tell
end repeat</pre>

I put the warnings in there because the script isn't meant to be run on the entire Library. It's meant to be run on the currently selected playlist in iTunes. On second read, I think my dialogs may be unclear on this point. The feature could be re-worked or removed entirely to avoid the confusion.