Applescript error -1700 type item when open file

Replace the second line with:

set userHome to path to home folder as text

(69464)

Try using:

open (userHome & "Library:Safari:Bookmarks.plist")

(69465)

I just want to point out (for the edification of others, even if it doesn't help you) that this is a ridiculously clunky way to do this. Give me a minute, and see my next post...

Here's how you work through the property list file in applescript, without GUI scripting. This version is set to work on top level items in the Bookmarks Menu, but is easily expandable to bookmark subfolders, the Reading List, the Bookmarks Bar, or even the History list.

property searchText : "textToFix"

property replaceText : "replacmentText"

if application "Safari" is running then

display alert "Please quit Safari before running this script" as critical

return

end if

tell application "System Events"

set bookmarkPlist to property list file "~/Library/Safari/Bookmarks copy.plist"

tell bookmarkPlist

tell property list item "Children"

set bookmarkMenu to first property list item whose property list item "Title"'s value is "BookmarksMenu"

tell bookmarkMenu

tell property list item "Children"

set itemsToRevise to every property list item whose property list item "URLString"'s value contains searchText

repeat with thisItem in itemsToRevise

tell thisItem

set value of property list item "URLString" to my swapStrings(property list item "URLString"'s value)

end tell

end repeat

end tell

end tell

end tell

end tell

end tell

on swapStrings(txt)

set {oldTID, my text item delimiters} to {my text item delimiters, searchText}

set bits to text items of txt

set my text item delimiters to replaceText

set newString to bits as text

set my text item delimiters to oldTID

return newString

end swapStrings

Hey, if it works for you that's fine, but there's no sense encouraging others with the same issue to do it that way. To many things to trip over when you GUI script.