iTunes - Applescript Help

Try something like this:

tell application "iTunes"

if (name of view of window "iTunes" is "Jazz") then

reveal (playlist 1 whose name is "Rock") -- to select the playlist

end if

end tell

or

tell application "iTunes"

if (name of view of window "iTunes" is "Jazz") then

play (playlist 1 whose name is "Rock") -- to play the playlist

end if

end tell

Message was edited by: Pierre L.

More simply:

tell application "iTunes"

if (name of view of window "iTunes" is "Jazz") then

reveal playlist "Rock" -- to select the playlist

end if

end tell

or

tell application "iTunes"

if (name of view of window "iTunes" is "Jazz") then

play playlist "Rock" -- to play the playlist

end if

end tell

Hello

You may try the following script which will rotate the given playlists. It will be terminated by error when specified playlist does not exist. Note that playlist name is treated in case-insensitive manner in this script and so you'd get into trouble if you have "Jazz" and "jazz" for instance. This case-related issue can be resolved by extra coding translating case-sensitive name to id, if necessary.

Regards,

H

set playlist_names to {"Jazz", "Rock", "Country"}
rotate_playlists(playlist_names)

on rotate_playlists(pp)
    (*
        list pp : list of name of playlists to rotate
    *)
    tell application "iTunes"
        set p to browser window 1's view's name
        set k to my bsearch(pp, p) -- current index
        set k1 to k mod (count pp) + 1 -- next index
        
        tell playlist (pp's item k1) -- playlist name is case insensitive
            reveal
            play
        end tell
    end tell
end rotate_playlists

on bsearch(xx, x)
    (*
        list xx : source list
        anything x : item to be searched in xx
        return integer : the first index of x in xx if {x} is in xx, or 0 if not.
    *)
    script o
        property aa : xx
        local i, j, k
        if {x} is not in my aa then return 0
        set i to 1
        set j to count my aa
        repeat while j > i
            set k to (i + j) div 2
            if {x} is in my aa's items i thru k then
                set j to k
            else
                set i to k + 1
            end if
        end repeat
        return i
    end script
    tell o to run
end bsearch

Hello

Glad to know it helped.

In case, here's a revised, safer version which resolved the said case-related issue.

Cheers,

H

(*
    rotate playlists in iTunes
    v0.2
    
        * playlist name is treated in case-sensitive manner
        * non-exsistent playlist name in given list is ignored

*)
set playlist_names to {"Jazz", "Rock", "Country"}
rotate_playlists(playlist_names)

on rotate_playlists(aa)
    (*
        list aa : list of name of playlists to rotate
    *)
    script o
        property pp : aa
        property qq : {}
        property nn : {}
        property ii : {}
        
        -- get list of name and id of playlists
        tell application "iTunes"
            tell playlists
                set {nn, ii} to {name, id}
            end tell
            set q to browser window 1's view's id
        end tell
        
        -- translate name list (pp) to id list (qq)
        repeat with p in my pp
            set k to my bsearch(nn, p's contents)
            if k > 0 then -- ignore non-existent playlist in pp
                set end of my qq to my ii's item k
            end if
        end repeat
        
        -- rotate playlist based on id list
        if (count my qq) = 0 then error "None of the specified playlists exist." number 8000
        tell application "iTunes"
            set k to my bsearch(my qq, q) -- current index (may be 0)
            set k1 to k mod (count my qq) + 1 -- next index
            tell playlist id (my qq's item k1)
                reveal
                play
            end tell
        end tell
    end script
    considering case -- for case-sensitive search
        tell o to run
    end considering
end rotate_playlists

on bsearch(xx, x)
    (*
        list xx : source list
        anything x : item to be searched in xx
        return integer : the first index of x in xx if {x} is in xx, or 0 if not.
    *)
    script o
        property aa : xx
        local i, j, k
        if {x} is not in my aa then return 0
        set i to 1
        set j to count my aa
        repeat while j > i
            set k to (i + j) div 2
            if {x} is in my aa's items i thru k then
                set j to k
            else
                set i to k + 1
            end if
        end repeat
        return i
    end script
    tell o to run
end bsearch