Return (character position from string) or (file name from file path)

Question

Level 3

714 points

Return (character position from string) or (file name from file path)

I am trying to do something very simple in AppleScript... search a string and have it return the character number. In VB there is a command to do this. I haven't found it in Applescript yet. I am left with walking through a string to find a delimater.

Here is what I am trying to do:
return a file name from a path:
myvolume:myfolder:myfile.txt

I want to return the file name.

Here is the handler I wrote to get the file name:

on getFileName(pathString)
set iCount to length of pathString

repeat while iCount > 1
if character iCount of pathString is ":" then
return (text (iCount + 1) thru (length of pathString)) of pathString as string
end if
set iCount to iCount - 1
end repeat
end getFileName

Is there an easier way to search a string?

Thank you.

g5 Dual 2ghz, Mac OS X (10.4.6), 2gb RAM

Posted on Jun 25, 2006 11:08 AM

Reply

Answer 1

Jun 25, 2006 12:23 PM in response to StephenZcat

Perhaps the simplest way to get the name of a file is to just ask Finder for it…

tell application "Finder" to get name of x_alias

…but if you want to get into delimiters, offsets and whatnot anyway, check out this thread for two examples of slicing and dicing filenames:
http://discussions.apple.com/thread.jspa?messageID=2514511&#2514511

Reply

Answer 2

HD

Level 5

4,945 points

Jun 25, 2006 2:44 PM in response to StephenZcat

This is how it works with AS's text item delimiters:

on getfilename(pathString)
set {olddelims, AppleScript's text item delimiters} to {AppleScript's text item delimiters, ":"}
set file_name to last text item of pathString
set AppleScript's text item delimiters to olddelims
return file_name
end getfilename

getfilename("myvolume:myfolder:myfile.txt")

Hope this helps.

H

Reply

Answer 3

StephenZcat Author

Level 3

714 points

Jun 26, 2006 6:27 PM in response to Michael Henley

Thanks for the response Michael...

I tried the tell application to get name of x_alias, substituting the x_alias with an alias path to my file. It returned an error, saying it couldn't get the name.

But there are other reasons to parse a string, one is you can work with a string instead of an object and get the same data faster.

Reply

Answer 4

StephenZcat Author

Level 3

714 points

Jun 26, 2006 6:28 PM in response to HD

Thanks for the post HD.

I saw this in the manual as well, and it is interesting and nice to be able to use delimaters, but was looking for some way to parse a string.

Again, thank you for the help.

Reply

Answer 5

StephenZcat Author

Level 3

714 points

Jun 26, 2006 6:29 PM in response to StephenZcat

on searchString(targetString, searchString, forwardDirection)
(*
This Handler searches a string for a smaller string and returns the positon of the found string.
Inputs:
targetString = string to be searched
searchString = string to be searched for
forwardDirection = (true/false) start at beginning of string or at end
0 is returned if no string is found.
*)

if forwardDirection is true then
set direction to 1
set iCount to 1
set endOfString to length of targetString
else
set direction to -1
set iCount to length of targetString
set endOfString to 1
end if

repeat until iCount = endOfString
if character iCount of targetString is searchString then
return iCount
else
set iCount to iCount + direction
end if
end repeat

set iCount to 0

end searchString

-------------------------------------------------------------------------------- ---------------------------------

on getFileName(pathString)
(*
Purpose: This Handler searches a file path string and looks for the last item in the
file path.
Dependancies: searchString handler
Input: pathString = myVolume:myFolder:myFile.txt
Output: myFile.txt
*)
set iCount to my searchString(pathString, ":", false)
return (text (iCount + 1) thru (length of pathString)) of pathString as string

end getFileName

Reply

Answer 6

StephenZcat Author

Level 3

714 points

Jun 26, 2006 6:30 PM in response to StephenZcat

on cutOutString(targetString, cutStart, cutLength)
(*
Purpose:
to cut out a string passed in from a larger string.
This handler became complex because applescript does not allow a range of 1 to 1
*)
set endOfString to length of targetString

if cutLength ≥ endOfString then
return ""
end if

if (cutStart + cutLength) ≥ endOfString then
cutLength = endOfString - cutStart
end if

if cutStart is 1 then
--return right portion of string
if (cutStart + cutLength) is endOfString then
set returnText to (character endOfString of targetString)
else
set returnText to text (cutStart + cutLength) thru endOfString of targetString
end if
else if (cutStart + cutLength) is endOfString then
--return left portion of string
if (cutStart - 1) is 1 then
set returnText to (character 1 of targetString)
else
set returnText to text 1 thru (cutStart - 1) of targetString
end if
else
--return left & right of string
if (cutStart - 1) is 1 then
set returnText to character 1 of targetString
else
set returnText to text 1 thru (cutStart - 1) of targetString
end if

if (cutStart + cutLength) is endOfString then
set returnText to returnText & character endOfString of targetString
else
set returnText to returnText & (text (cutStart + cutLength) thru endOfString of targetString)
end if
end if

return returnText
end cutOutString

Reply

Answer 7

Niel

Level 10

741,971 points

Jun 27, 2006 8:53 AM in response to StephenZcat

Use this:

set my_string to "myvolume:myfolder:myfile.txt"
repeat until (offset of ":" in my_string) is 0
set the_offset to offset of ":" in my_string
set my_string to items (the_offset + 1) thru (count my_string) of my_string as string
end repeat
my_string

The offset command is located in the Standard Additions scripting addition, which is bundled with all versions of Mac OS 9 and Mac OS X. It is under String Commands when you open the addition.

(13598)

Reply

Answer 8

StephenZcat Author

Level 3

714 points

Jun 27, 2006 9:01 PM in response to Niel

Excellent! That's what I was looking for!

Thank-you Niel.

I did some more looking around on the internet and found someone else who had done something similar. They used reverse to reverse the string and find the last :

if not (thePath ends with ":") then
set x to the offset of ":" in (the reverse of every character of thePath) as string
set thePath to (characters 1 thru -(x) of thePath) as string
end if

here's where I found this one:

http://www.bigbold.com/snippets/posts/show/1046

Reply

Answer 9

StephenZcat Author

Level 3

714 points

Jun 27, 2006 9:54 PM in response to StephenZcat

Previous post was to return thepath, here is for the file:

if not (thePath ends with ":") then
set x to the offset of ":" in (the reverse of every character of thePath) as string
set theFile to (characters ((length of thePath) - x + 2) thru (length of thePath) of thePath) as string
end if

Reply

Answer 10

dev_sleidy

Level 4

1,570 points

Jun 27, 2006 10:13 PM in response to StephenZcat

As per the subject ('... file name from file path') -

set thePath to "HD3:Users:s:Desktop:Dock AddApplication.scpt"

if not (thePath ends with ":") then
set a to ((reverse of every character of thePath) as string)
set file_Name to (reverse of every character of ((characters 1 through ((offset of ":" in a) - 1) of a) as string) as string)
end if

Reply

Answer 11

StephenZcat Author

Level 3

714 points

Jun 27, 2006 11:36 PM in response to StephenZcat

Leaner version...

on cutOutString(targetString, cutStart, cutLength)

set endOfString to length of targetString
set leftText to ""
set rightText to ""

if cutStart = endOfString then
cutStart = endOfString - 1
end if

if cutStart + cutLength > endOfString then
set cutLength to endOfString - cutStart + 1
end if

set cutEnd to cutStart + cutLength

if cutStart > 1 then set leftText to text 1 thru (cutStart - 1) of targetString
if cutEnd < endOfString then set rightText to text cutEnd thru endOfString of targetString

return leftText & rightText

end cutOutString

Reply

Answer 12

Jul 9, 2006 2:45 AM in response to StephenZcat

so if you want the enclosing folder for a file, try

set theFolder to the container of (theFile as alias)

or is there more ?

I understand the frustration at the lack of great string handling in AS, since the demise of OS9 and ACME Script Widgets.

Reply