Hi Aaron,
Unfortunately, I know nearly nothing about Automator. So I cannot help you with the last part of your script. What I've done, however (now that I've got a better idea of what you want to do) was to revise and improve my previous script. The new version of the script seems to work flawlessly under OS X 10.9, even with big archives. Here it is:
set theFolder to POSIX file "/Users/Shared/AvidMediaComposer/Shared Avid Projects/Reciprocity" as alias
set theSpreadSheet to POSIX file "/Users/Aaron/Desktop/Reciprocity/Reciprocity Work Log.numbers" as alias
set theDestinationFolder to POSIX file "/Users/Aaron/Dropbox/Reciprocity Backup" as alias
-- Dialog asking to "Check In" or "Check Out":
display dialog "What will it be?" default answer "Project Name or Notes" buttons {"Cancel", "Check In", "Check Out"} cancel button 1 with icon 1 with title "Some title"
set {theAnswer, theButton} to {text returned, button returned} of result
tell application "Numbers ’09"
if not (exists (document 1 whose path is theSpreadSheet)) then
open theSpreadSheet
repeat until (document 1 whose path is theSpreadSheet) exists
end repeat
end if
-- fill in the appropriate cell:
tell table 1 of sheet 1 of front document
if theButton is "Check In" then
set checkIn to true
set theProject to cell 1 of column "A" whose (value = 0) and (name is not "A1")
set theCurrentRow to address of row of theProject as text
set value of theProject to theAnswer
set value of cell ("B" & theCurrentRow) to (current date) as text
else
set checkIn to false
set theProject to last cell of column "A" whose (value is not 0)
set theCurrentRow to address of row of theProject
set value of cell ("C" & theCurrentRow) to (current date) as text
set value of cell ("E" & theCurrentRow) to theAnswer
add row below theProject
end if
end tell
delay 2 -- optional, just to see the values entered in the cells
quit -- or "save" if you don't want to quit right now
end tell
if checkIn then
tell application "TextEdit" to activate -- launch the application to begin work
else
tell application "TextEdit" to quit -- quit the application
-- Create a zip archive of your Reciprocity folder
-- and move it into your Reciprocity Backup folder:
set theFolderPath to POSIX path of theFolder
set theArchive to POSIX file (text 1 through -2 of theFolderPath & ".zip")
tell application "Finder"
activate
select theFolder
end tell
tell application "System Events" to tell process "Finder"
tell menu 1 of menu bar item "File" of menu bar 1
click (menu item 1 whose name begins with "Compress")
end tell
end tell
tell application "Finder"
repeat until exists theArchive
end repeat
move theArchive to folder theDestinationFolder with replacing
end tell
end if
Hope it can help.