This script might help. I have posted it before, to allow a single reply to multiple selected emails. You might like to modify it so that it uses Bcc; change the line "make new to recipient at end of to recipients with properties {name:TheName, address:TheAddress}" so that the two occurences of to become bcc. Note that it has not been tested with this!
What I would suggest is this: after saving the script, select the first group of your replies, maybe as many as 50 of them. Don't try all 300 as I imagine that, even if the script doesn't crash, your ISP will block them as spam. Run the script, put your email in the To box (ISPs don't like emails without a To), and type in your reply. Before clicking send, select and copy your reply. After sending, select the next bunch of emails, run the script, put in your email address and paste in your copied reply. You might have to repeat six times to get all 500 done. It would probably be better to spread the sending over two days, again to avoid getting you flagged as a spammer.
AK
<pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">(*Save the script in the Library/Scripts/Applications/Mail folder of your home directory. With several messages selected in Mail run
the script from the Scripts menu item on the menu bar. It will generate a new message with the sender of each of the selected
mails asa recipient, and the subject of the first selected mail as subject. Non-adjacent messages can be selected with Command-click.
AK Sep 2005 kinsella@itcarlow.ie *)
using terms from application "Mail"
on perform mail action with messages TheMail
tell application "Mail"
set theSubject to ""
repeat with ThisMail in TheMail
set TheName to extract name from sender of ThisMail
set TheAddress to extract address from sender of ThisMail
if theSubject is "" then -- set subject, make message 1st time through
set theSubject to subject of ThisMail
if theSubject does not start with "Re:" then set theSubject to "Re: " & theSubject
set newMessage to make new outgoing message with properties {subject:theSubject}
end if
tell newMessage
make new to recipient at end of to recipients with properties {name:TheName, address:TheAddress}
end tell
end repeat
tell newMessage to set visible to true
end tell
end perform mail action with messages
end using terms from
using terms from application "Mail"
on run
tell application "Mail" to set sel to selection
tell me to perform mail action with messages (sel)
end run
end using terms from</pre>
