How to put text from email message into a range of Spreadsheet cells?

Hello

I don't think you need to resort to copy and paste becausee Excel has direct scripting support to set value of range. Try something liket the following code. (The part scripting Excel is not tested, for I don't have it.)

Good luck,

H

tell application "Mail"
    set mm to (get selection)
    set m to mm's item 1
    set t to m's content
    set pp to t's paragraphs 4 thru -1
end tell

set qq to {}
repeat with p in pp
    set qq's end to {p's contents}
end repeat
repeat 50 - (count qq) times
    set qq's end to {""}
end repeat
set r to "A1:A" & (count qq)
--return {r, qq} -- for test

tell application "Microsoft Excel"
    tell worksheet "TP from website" of workbook "Contacts Database (for script testing)"
        tell range r
            --clear range
            set value to qq
        end tell
    end tell
end tell

Hello

If I'm not mistaken, the following script will retrieve the value of range "A1:B3" of active sheet as list of value of rows:

tell application "Microsoft Excel"
    tell active sheet
        tell range "A1:B3"
            return value
        end tell
    end tell
end tell

E.g., if cell A1 contains string "A1" etc, then the resulting list will be:

{{"A1", "B1"}, {"A2", "B2"}, {"A3", "B3"}}

And the following script will set the value of range "A1:B3" to given list of lists:

tell application "Microsoft Excel"
    tell active sheet
        tell range "A1:B3"
            set value to {{11, 12}, {21, 22}, {31, 32}}
        end tell
    end tell
end tell

Here's the reference I use, which is old but the last excel applescript reference in pdf format I can find in their site.

http://download.microsoft.com/download/3/A/7/3A70FB4B-0C6A-43E3-AAB7-AC9166B2563 2/Excel2004AppleScriptRef.pdf

Good luck,

H

Well, the "return" statement exits the handler which lexiclally encloses the statment. If it is executed in top level of script, which is indeed in an implicit run handler of the script, it will exits the script itself.

So if perchance you're using "return" statement inadequately, that would be the reason you have your script be terminated prematurely.

* I use "return" statement to check the intermediate states of the script in testing, for "log" statement, which is supposedly to be used in testing, does some unsolicited conversions on values to be checked. If my use of "return" had confused you, my appologies.

The following script should run to the ends:

tell application "Microsoft Excel"
    tell active sheet
        tell range "A1:B3"
            --return value -- this will put the values in result window and terminate the script here
            --log value   -- this will log the values in event log window and let the script continue
            set old_values to value -- save the values in varable for later use and let the script continue
        end tell
    end tell
end tell

tell application "Microsoft Excel"
    tell active sheet
        tell range "A1:B3"
            set value to {{11, 12}, {21, 22}, {31, 32}}
        end tell
    end tell
end tell

return old_values

Hope this may help,

H

Congratulations! Good to hear you have earned the return statement. It is one of the core statements in AppleScript along with get, set, tell, it, me.

Allow me to recommend you THE language manual you can consult anytime.

https://developer.apple.com/library/mac/documentation/AppleScript/Conceptual/App leScriptLangGuide

Good luck,

H