Q: export same albums from Photos

You can export the Moments structure as subfolders, but not the album structure.

To export each album to a separate folder you would have to export each album separately to a separate folder and name the folder on your own.

If you export selected photos using File > Export, you can create subfolders for each Moment, but not for the albums.

Hi isra_BCN!

have you found a solution for exporting multiple albums in the photos app?

I'm also facing the same problem and am actually thinking of trying to write

a small utility that would allow me to export the album structure plus photos, but I'm not sure

if I can decipher the library format...

Best

Tom

I'm trying to workout something similar - in that I'm trying to split up my massive photos library (300Gb) into a separate file for each year - so that I can archive some of the photos to an external drive and regain some space on my macbook. I can easily export the moments for a particular year and create a new new library, but I would like to retain the albums that were based on those same photos. My albums are also structured in years and months so it would be easy to do if photos supported it - but I haven't found a way to do it. Any thoughts?

Or is it possible with applescript or automator?

Thanks,

Cam

Hello,

it's possible on El Capitan:

Important: the smart albums will be included in the albums, it's not possible to exclude it.

You can use this AppleScript:

set dest to "/Users/me/Desktop/photos-Albums/" as POSIX file as text -- the destination folder (use a valid path)

tell application "Photos"
    repeat with i in albums
        set tFolder to dest & (get name of i)
        my makeFolder(tFolder) -- create a folder named (the name of this album) in dest
        export (get media items of i) to (tFolder as alias) without using originals
    end repeat
end tell

on makeFolder(tPath)
    do shell script "mkdir -p " & quoted form of POSIX path of tPath
end makeFolder

Open the "Script Editor" application in /Applications/Utilities/

Copy the AppleScript and paste into the window of the "Script Editor".

Change the path of your folder in the first line of the script (use drag/drop to get the correct path of your folder).

if you want the originals, use this --> export (get media items of i) to (tFolder as alias) with using originals

Thanks Jacques,

I tried this script, but I got the following error:

error "Photos got an error: Can’t get every album." number -1728 from every album

I simplified the script to see if I could narrow down the problem:

tell application "Photos"

  repeat with i in albums

  display dialog ("Album: " & (get name of i))

  end repeat

end tell

But this still had the same problem.

Any thoughts?

Cheers,

Cam

EDIT: Just realised that you mentioned "El Captain" in your post, and forgot I'm still running Yosemite on my work Mac ... so I'll try this again at home tonight on ElCap.

Thanks Jacques.  This script did exactly what I needed to do.  You saved me much time in doing this manually.

Thanks Jacques!

That helps a lot. Your script is almost doing what I am exactly searching for. But: is it possible to export just the selected albums?

This would be perfect!

Hi,

GreLo wrote:

 

Your script is almost doing what I am exactly searching for. But: is it possible to export just the selected albums?

There is no AppleScript's command to get the selected albums.

Workaround, the "choose from list" command to select some names:

set dest to "/Users/myUserName/Desktop/photos-Albums/" as POSIX file as text -- the destination folder (use a valid path) 

tell application "Photos"
    activate
    set l to name of albums
    set albNames to choose from list l with prompt "Select some albums"
    if albNames is not false then -- not cancelled
        repeat with tName in albNames
            set tFolder to dest & tName
            my makeFolder(tFolder) -- create a folder named (the name of this album) in dest 
            export (get media items of album tName) to (tFolder as alias) without using originals
        end repeat
    end if
end tell

on makeFolder(tPath)
    do shell script "mkdir -p " & quoted form of POSIX path of tPath
end makeFolder

Caveat : this script may not work correctly on albums with the same name (if you select a name that is not unique).

Thanks, actually extremely helpful as I have organised all photos in albums, not moments and I wanted to export the stored photos to perform face recognition in Picasa.

Jaques:

Any way to allow the users to select more than one album at a time?

Also have you considered adding the script to the Photos User Tips section? 

Good Idea -  Jaques's script is already a user tip:  How to find out the albums a photo is in: Jacques Rioux's script

I posted it for him last month, but we need to add the updated version with the  new features.

This is a different script.  It displays the albums in the library for you to pick to download to a folder on the desktop.  His other script has you select a photo and it will tell you which albums it's in.