Hallo Sam,
I have a PowerBook G4 and a Nokia 6630 and Orange is my mobile service provider, and I can connect to the internet using my Orange mobile.
I agree that Orange is not Mac-friendly, but I write as one who got their (PCMCIA) Orange Mobile Datacard, which they claimed would work only on Windows XP, working on my Pismo in about half-an-hour. Not to brag, but to illustrate that the nature of the Mac OS means that anyone can do it (what I did, was I looked at the Windows modem script, found the initialisation string they used there - the one that begins AT& - and pasted into one of Ross Barkman's modem scripts for the Nokia, of which more below).
Your phone has BlueTooth, and that your iBook does too. So use the BlueTooth Assistant to establish a connection between the two (you shouldn't need the data cable). Make sure that your phone and computer are both 'discoverable', as you may need to establish a BlueTooth connection from your computer to your phone and from your phone to your computer.
If you then go to Location:Network Prefs:Network Status, you should then see your N80 registered as a port. Now go to Internet Connect. You should see a telephone modem icon with Nokia N80 written below it.
So far so good. Now you will need a modem script that will enable you to dial a connection to Orange using this modem. Go to Ross Barkman's modem page (
http://www.taniwha.org.uk) and download the script entitled Nokia GPRS C1D1 and place it in /Library/Modem Scripts (script pasted below). The script will get your phone to dial the same access number (
99**1#) you dial if you are trying to access the internet on your N80. (You could also leave Ross the price of a pint - that's all he asks!).
So, all you now need to do is go back to Internet Connect, click on the N80 icon and create a new configuration using Nokia GPRS C1D1 as your modem. Your account name will be 'orangeinternet' and there is
no password. (In fact, 'orangeinternet'
is the password, but for reasons that escape me for the moment, but are no doubt clearly explained on Ross's site, the password has to be placed in the 'account name' slot). Click on 'connect' and you should be good to go.
One word of warning. Mobile megabytes are very expensive. Buy yourself a megabyte package similar to a text package (say, £25 for 80 'free' megabytes a month). And be aware that these packages are only valid for the UK (or if you're on Orange Ireland, only for Ireland, etc). That's what caught me out. I asked Orange which was the best package (speed/cost etc) for me -datacard or mobile phone (turns out they're identical) - while I was working in France. Turns out the answer is no UK package is valid in France, and the cost of roaming web access is £10/megabyte. See how easy it is to run up a £500 bill in a single day?!! A South African I met in Paris had some international business package from Vodaphone, which meant although he paid a high tariff, the cost of his internet access was constant wherever he was in the world. If you are intending to use the laptop abroad, I'd consider a different mobile provider.
Paul
Modem Script begins at next '!'
! Nokia GPRS CID1
!
! Author: Ross Barkman
!
! History:
! 06 Jan 02 First release
! 28 Jun 02 Change dialstring from *99# to
99**1#
! 13 Feb 03 Change flow control to +IFC=3,1
!
! 'mlts' resource info:
! byte 1 == 01 -> modem HAS built-in error correction protocols
! byte 2 == 01 -> modem HAS built-in data compression protocols
! byte 3 == 200 -> max number of chars in varstr 7
! byte 4 == 200 -> max number of chars in varstr 8
! byte 5 == 200 -> max number of chars in varstr 9
!
@ORIGINATE
@ANSWER
!
! ---- Modem setup ----
!
@LABEL 1
!
! Set serial port speed 115200, all interface signals off
!
note "Nokia GPRS CID1" 1
serreset 115200, 0, 8, 1
hsreset 0 0 0 0 0 0
settries 0
!
! Check the phone is responding
!
matchclr
matchstr 1 2 "OK\13\10"
write "AT\13"
matchread 30
jump 101
!
! Check the phone is a Nokia
!
@LABEL 2
matchclr
matchstr 1 3 "Nokia"
write "AT+CGMI\13"
matchread 60
jump 109
!
@LABEL 3
!
! Configure the phone
!
matchclr
matchstr 1 5 "OK\13\10"
matchstr 2 101 "ERROR\13\10"
write "AT&FE0V1&D2&S0&C1S0=0+IFC=3,1\13"
matchread 30
inctries
iftries 3 101
jsr 9
jump 3
!
@LABEL 5
pause 20
settries 0
!
@LABEL 6
!
! Set additional options
!
matchclr
matchstr 1 10 "OK\13\10"
matchstr 2 108 "ERROR\13\10"
!
! Check Access Point Name stored in dialstring (VarString 1)
! If APN is set to None, ignore it
!
ifstr 1 7 "None"
ifstr 1 7 "none"
ifstr 1 7 "NONE"
!
! Set APN using +CGDCONT=1,"IP","<APN>"
!
write "AT+CGDCONT=1,\34IP\34,\34^1\34\13"
jump 8
!
@LABEL 7
!
! No APN
!
@LABEL 8
matchread 60
inctries
iftries 3 101
jsr 9
jump 6
!
@LABEL 9
!
! Attempt to reset the phone
!
DTRClear
pause 5
DTRSet
flush
return
!
@LABEL 10
!
! Setup complete
!
ifANSWER 32
!
!
! ---- Place a call ----
!
@LABEL 20
!
!
note "Making GPRS connection" 3
write "ATD
99**1#\13"
!
!
! ---- Connect response ----
!
! Parses successful connect responses in the following format:
! CARRIER xxxxx
! PROTOCOL: ppp
! COMPRESSION: ccc
! CONNECT zzzzz
!
@LABEL 32
matchclr
matchstr 1 81 "RING\13\10"
matchstr 2 102 "NO DIALTONE\13\10"
matchstr 3 103 "NO CARRIER"
matchstr 4 103 "ERROR\13\10"
matchstr 5 104 "BUSY\13\10"
matchstr 6 105 "NO ANSWER\13\10"
matchstr 7 34 "CARRIER"
matchstr 8 34 "CONNECT"
matchstr 9 61 "PROTOCOL"
matchstr 10 66 "COMPRESSION"
matchread 700
ifANSWER 32
jump 105
!
!
! CARRIER/CONNECT parsing
!
@LABEL 34
!
! 2400 and 4800 have three entries each
! to distinguish them from 24000 and 48000
!
matchclr
matchstr 1 40 "2400\13"
matchstr 2 40 "2400/"
matchstr 3 40 "2400 "
matchstr 4 41 "4800\13"
matchstr 5 41 "4800/"
matchstr 6 41 "4800 "
matchstr 7 42 "7200"
matchstr 8 43 "9600"
matchstr 9 44 "12000"
matchstr 10 45 "14400"
matchstr 11 46 "19200"
matchstr 12 51 "28800"
matchstr 13 52 "38400"
matchstr 14 53 "57600"
matchstr 15 54 "115200"
matchstr 16 54 "115,200"
matchstr 17 55 "230400"
matchread 10
jump 59
!
! -- Connection rates --
!
! CommunicatingAt informs ARA of the link speed
!
@LABEL 40
note "Communicating at 2400 bps." 2
CommunicatingAt 2400
jump 60
!
@LABEL 41
note "Communicating at 4800 bps." 2
CommunicatingAt 4800
jump 60
!
@LABEL 42
note "Communicating at 7200 bps." 2
CommunicatingAt 7200
jump 60
!
@LABEL 43
note "Communicating at 9600 bps." 2
CommunicatingAt 9600
jump 60
!
@LABEL 44
note "Communicating at 12400 bps." 2
CommunicatingAt 12400
jump 60
!
@LABEL 45
note "Communicating at 14400 bps." 2
CommunicatingAt 14400
jump 60
!
@LABEL 46
note "Communicating at 19200 bps." 2
CommunicatingAt 19200
jump 60
!
@LABEL 51
note "Communicating at 28800 bps." 2
CommunicatingAt 28800
jump 60
!
@LABEL 52
note "Communicating at 38400 bps." 2
CommunicatingAt 38400
jump 60
!
@LABEL 53
note "Communicating at 57600 bps." 2
CommunicatingAt 57600
jump 60
!
@LABEL 54
note "Communicating at 115200 bps." 2
CommunicatingAt 115200
jump 60
!
@LABEL 55
note "Communicating at 230400 bps." 2
CommunicatingAt 230400
jump 60
!
@LABEL 59
note "Communicating at an unknown rate." 2
!
@LABEL 60
jump 70
!
! -- PROTOCOL parsing --
!
! Userhook 2 informs ARA that a modem-to-modem error
! correcting protocol has been negotiated
!
@LABEL 61
matchclr
matchstr 1 63 "NONE"
matchstr 2 62 "LAPM"
matchstr 3 62 "ALT"
matchstr 4 63 "\13"
matchread 10
jump 63
!
@LABEL 62
note "Modem Reliable Link Established." 2
userhook 2
!
@LABEL 63
jump 32
!
! -- COMPRESSION parsing --
!
! Userhook 3 informs ARA that a modem-to-modem compression
! protocol has been negotiated
!
@LABEL 66
matchclr
matchstr 1 68 "NONE"
matchstr 2 67 "V42B"
matchstr 3 67 "MNP5"
matchstr 4 68 "\13"
matchread 10
jump 68
!
@LABEL 67
note "Modem Compression Established." 2
userhook 3
!
@LABEL 68
jump 32
!
!
! -- Normal exit after "CONNECT" --
!
!
@LABEL 70
!
! Turn CTS on, for hardware flow control
!
HSReset 0 1 0 0 0 0
!
ifANSWER 71
pause 30
!
@LABEL 71
exit 0
!
!
! ---- Answer calls ----
!
! A RING result from the modem and in ANSWERING mode
! claims the serial port and answering the phone
!
@LABEL 81
ifORIGINATE 32
userhook 1
note "Answering phone..." 2
write "ATA\13"
jump 32
!
!
! ---- Hang up and reset modem ----
!
@HANGUP
@LABEL 90
settries 0
HSReset 0 0 0 0 0 0
!
@LABEL 92
!
! Escape from data to command mode
!
matchclr
matchstr 1 94 "OK\13\10"
pause 11
write "
+"
matchread 20
!
@LABEL 94
!
! Send hangup command
!
pause 10
matchclr
matchstr 1 98 "NO CARRIER\13\10"
matchstr 2 98 "OK\13\10"
matchstr 3 98 "ERROR\13\10"
matchstr 4 98 "0\13\10"
write "ATH0\13"
matchread 30
!
! If that fails, toggle DTR
!
DTRClear
pause 5
DTRSet
flush
!
! Try this three times only
!
inctries
iftries 3 101
jump 92
!
!
@LABEL 98
!
! Reset phone to default settings
!
pause 10
matchclr
matchstr 1 99 "OK\13\10"
write "AT&F\13"
matchread 30
jump 101
!
@LABEL 99
exit 0
!
! ---- Error messages -----
!
! Modem Not Responding
@LABEL 101
exit -6019
!
! No Dial Tone
@LABEL 102
exit -6020
!
! No Carrier or Error
@LABEL 103
exit -6021
!
! Busy
@LABEL 104
exit -6022
!
! No Answer
@LABEL 105
exit -6023
!
! User Cancellation
@LABEL 107
exit -6008
!
@LABEL 108
exit -6002 "The phone or network does not seem to support the GPRS options required for this script"
!
@LABEL 109
exit -6002 "This script is only suitable for Nokia mobile phones"
PowerBook G3 Pismo Mac OS X (10.3.9) Toshiba Satellite Pro
PowerBook G3 Pismo Mac OS X (10.3.9) Toshiba Satellite Pro
PowerBook G3 Pismo Mac OS X (10.3.9) Toshiba Satellite Pro
PowerBook G3 Pismo Mac OS X (10.3.9) Toshiba Satellite Pro