Q: How can I identify which albums photos are assigned to in Photos.

Please understand that I know how to use a smart album to find Unassigned photos, but how to you find albums assigned to photos?

Photos does not support this. You cannot get a list of standard albums a photo has been assigned to.

If you want to know for a photo, which albums a photo is in, use only smart albums based on keywords. You can see the keywords in the Info panel for a photo and know directly, which smart albums will contain it.

To find all standard albums a photo is in you would have to program an Apple Script.

And it's a take-away because it was available in iPhotos and Aperture.

In you could reveal the project a photo is in, and in iPhoto you could reveal the event.  Neither of them could revel the albums.  The difference is, that any photo was in only one event in Photos or in only one project in Aperture. But it can be in many albums, and neither iPhoto nor Aperture could reveal photos in albums. t is exactly the same in Photos.

The iPhoto events and Aperture projects have been replaced by the moments, and you can reveal a photo in the moment by ctrl-clicking it and selecting "Show in Moment".

  Do you think there may be an automator or Apple script out there that already exists?      I'm hopeful

• I have not yet found such a script. 

The moments are using the capture dates, if they are available.

For my scanned photos I added capture dates using an apple script.

We posted a few scripts in the User Tips section:    Photos for Mac User Tips

You may want to have a look at this script:  Photos for Mac: Batch Change the Date and Time to a Fixed Date

It will basically take a few selected photos and then change the date of the photos to the date of the first photo, but add a small increment between successive photos, for example 1 minute. This way the photos will have the same date and time as the first photo, but if sorted by the date, the sequence will be the same, because of the increment in time.

Moments can be quite powerful, if the photos have been tagged with useful dates and with location data. Then Photos will group photos taken at the same tie at the same place together.  But it requires Photos 1,2 or later; otherwise it is not possible to assign locations in Photos.

I assign estimated dates and locations to my scans of old family pictures and add a keyword, that date and location are estimates.Also I assign faces labels. The dates and locations  will help to sort the photos and show them on a map.

Can we insert Text instead of a date for Moments?   For example, can I call (a) moment "1st Generation ancestors", "2nd Generation ancestors", etc?  Can I call a moment "Dad Growing Up"?

Moments are created automatically and we cannot name them. I use albums to give names to related sets of photos. The folders, albums, and smart albums will replace the iPhoto events or Aperture projects.

Hello,

socraties wrote:

 

Would it work to program an Apple Script, then insert it in the contextual menu so that I can select any picture and run the script?  If so it would be a great workaround!!!  Do you think there may be an automator or Apple script out there that already exists?      I'm hopeful.

This AppleScript show the name of albums which contains the selected photo:

tell application "Photos"
    set sel to selection
    if sel is {} then return -- no selection
    set thisId to id of item 1 of sel
    set theseNames to name of (albums whose id of media items contains thisId)
end tell
if theseNames is not {} then
    set {oTid, text item delimiters} to {text item delimiters, return}
    set {t, text item delimiters} to {theseNames as string, oTid}
else
    set t to "No album"
end if
activate
display dialog t buttons {"OK"} default button "OK" -- you can press the Enter key or the return Key to close the dialog

You can run this AppleScript from an Automator's service, and you can assign a shortcut to this service.

Or, you can run this AppleScript from some third party utilities (some free) which run (shell script,  AppleScript script or javascript), and you can assign a shortcut to this action

Great work, Jaques!

The script is working well on my small local test library.

May I suggest to add a line;

set the clipboard to t

right before the last "display dialog"?

This way the result will be copied to the clipboard, and we can paste it into any text document and do not need to copy it manually from the dialog panel.

When I try the script on my iCloud Photo Library with nearly 40000 photos however, I get a timeout error:

error "Photos got an error: AppleEvent timed out." number -1712

I'm getting the same error for any script that is using the "selection" to pass photos to a script, if the library is an iCloud Photo Library-

Jaques,

would you mind, if we post a link to your script in the user Tip section?

-- Léonie

Hello,

léonie wrote:

 

Jaques,

would you mind, if we post a link to your script in the user Tip section?

 

-- Léonie

Yes, you can do it.

Thank you.

léonie wrote:

 

 

When I try the script on my iCloud Photo Library with nearly 40000 photos however, I get a timeout error:

error "Photos got an error: AppleEvent timed out." number -1712

I'm getting the same error for any script that is using the "selection" to pass photos to a script, if the library is an iCloud Photo Library-

This script was a starting point, I suspected that it would not be free of issues.

Unfortunately, I only have a small library, and I don't use iCloud.

If there are people who can improve this script, I'd be happy.

Jacques.

It is a very valuable starting point.  When I tried to write a similar script, I always failed when comparing the ids of the photos,  Your line "whose id of media items contains thisId"  was the missing link for me! 

Apple scripts do not work well with iCloud Photo Library at all, if they are trying to access the current selection.  It will result in time out errors.

There is a fix by NicFletcher - create a top level album that contains the photos to be processed. Here is Nic's sample script, that uses this method:

https://discussions.apple.com/message/28087786#28087786

I am using a fixed album called PhotosDropBox to pass photos to scripts.

For iCloud Photo Library I might modify your script like this:

tell application "Photos"

  -- Add the photo you want to search for to a top level album as the first item in the album

  set theAlbumName to "PhotoDropBox" -- change this to the name of the album you will use

  try

  if exists container theAlbumName then

  set thePhotosBuffer to container theAlbumName

  set sel to every media item of thePhotosBuffer

  else

  error "Album " & theAlbumName & "does not exist"

  end if

  on error errTexttwo number errNumtwo

  display dialog "Cannot open album: " & errNumtwo & return & errTexttwo

  end try

end tell

-- From Jacques Rioux's script:

tell application "Photos"

  -- set sel to selection

  if sel is {} then return -- no selection 

  set thisId to id of item 1 of sel

  set theseNames to name of (albums whose id of media items contains thisId)

end tell

if theseNames is not {} then

  set {oTid, text item delimiters} to {text item delimiters, return}

  set {t, text item delimiters} to {theseNames as string, oTid}

else

  set t to "No album"

end if

activate

set the clipboard to t -- léonie

display dialog t buttons {"OK"} default button "OK" -- you can press the Enter key or the return Key to close the dialog

return t -- léonie