The following AppleScript prompts you for file(s) from which to generate thumbnail images using the Quick Look Manager (qlmanage) utility that ships with OS X. As it generates the thumbnails, it writes LaTeX syntax into a metafile consisting of each document file URI, and the path to the image. This solution does not require installation of TeX, or LaTeX distribution, or knowledge of them, to produce results.
When done, it uses Pandoc to translate the LaTeX metafile into Word .docx, or OpenDocument Format .odt documents. The metafile is deleted and recreated with each run of the AppleScript. Here is a screen shot of the finished Word document in LibreOffice 5.2.1.2 (click to enlarge).
The AppleScript will introduce a newpage into the metafile after every four images. There is a manpage for qlmanage, and it also responds to qlmanage -h in the Terminal.
The only item you will need install is Pandoc. The cleanest way to install it is with the Homebrew package manager, and then you install pandoc as (type in blue):
# This will install pandoc as /usr/local/bin/pandoc
$ brew install pandoc
About every two weeks, I do the following to keep homebrew and applications up to date:
$ brew update
$ brew upgrade
The AppleScript:
property default_loc : ((path to desktop) as text) as alias
property qmesg : "Choose file(s) to generate thumbnails"
property metafile : (path to desktop as text) & "meta.tex"
property thumbpath : (path to desktop as text) & "Thumbs:"
property fileCnt : missing value
tell application "Finder"
if exists file metafile then
delete file metafile
end if
if not (exists folder thumbpath) = true then
make new folder at (path to desktop as text) with properties {name:"Thumbs"}
end if
end tell
-- create the empty metafile and return a file handle used to write to it
set fRef to openMetaFile(metafile)
-- initialize with the preamble LaTeX stuff
init_metadata(fRef)
set inPath to (choose file with prompt qmesg default location default_loc with multiple selections allowed without invisibles and showing package contents)
set fileCnt to (count of inPath)
repeat with afile in inPath
tell application "Finder"
set ImgPath to ""
set theURL to (afile's URL) as text
set theImgName to afile's name & ".png"
set ImgPath to POSIX path of (thumbpath & theImgName)
set inFile to (afile's POSIX path)'s quoted form
end tell
try write_metadata(fRef, theURL, ImgPath)
-- use the QuickLook manager to generate a 128 pixel icon at 90% scale
do shell script "/usr/bin/qlmanage -tif 0.9 -s 128 " & inFile & " -o " & POSIX path of thumbpath & " >& /dev/null"
on error errmsg number errnbr
my error_handler(errnbr, errmsg)
set fileCnt to 0
return
end try
end repeat
write "\\end{document}" & linefeed to fRef starting at eof
close access fRef
-- do shell script "/usr/local/bin/pandoc -s -f latex -o ~/Desktop/work.odt " & POSIX path of metafile
do shell script "/usr/local/bin/pandoc -s -f latex -o ~/Desktop/work.docx " & POSIX path of metafile
display dialog (fileCnt as text) & " records written. Document produced."
set fileCnt to 0
return
on openMetaFile(filePath)
-- influenced by twtwtw from https://discussions.apple.com/thread/4256380?tstart=0
try
set fp to (open for access file filePath with write permission)
on error errmsg number errnbr
if errnbr = -49 then
close access filePath
set fp to (open for access filePath with write permission)
else
my error_handler(errnbr, errmsg)
return false
end if
end try
return fp
end openMetaFile
on init_metadata(fh)
-- latex preamble
write "\\documentclass[10pt, twocolumn]{article}" & linefeed to fh starting at eof
write "\\usepackage{url}" & linefeed to fh starting at eof
write "\\usepackage{graphicx}" & linefeed to fh starting at eof
write "\\" & linefeed to fh starting at eof
write "\\setmainfont{Helvetica}" & linefeed to fh starting at eof
write "\\begin{document}" & linefeed to fh starting at eof
return
end init_metadata
on write_metadata(fh, aURL, imagePath)
-- attempt to control quantity of images on a page
set imagecnt to (do shell script "[[ -s " & metafile & " ]] && egrep -c includegraphics " & metafile & " || echo \"0\"") as integer
-- every four images we introduce a new page
if imagecnt > 0 and ((imagecnt mod 4) as integer) = 0 and imagecnt < fileCnt then
write "\\newpage" & linefeed to fh starting at eof
end if
-- write data to it
write "\\url{" & aURL & "}" & linefeed to fh starting at eof
write "\\\\\\\\" & linefeed to fh starting at eof
write "\\includegraphics{" & imagePath & "}" & linefeed to fh starting at eof
write "\\\\\\\\" & linefeed to fh starting at eof
return
end write_metadata
on error_handler(nbr, msg)
return display alert "[ " & nbr & " ] " & msg as critical giving up after 10
end error_handler
kaiuweheinz
Level 1
(8 points)
