Q: Convert VIDEO_TS FOLDERS to ISO applescript

This is pretty straightforward. Assuming I read your post correctly, you have one directory that contains a number of subdirectories that correspond to individual movies. Each of these subdirectories has a subsequent VIDEO_TS directory.

If that's the case, this should do the trick (untested since I don't have any VIDEO_TS on my system). The comments should give you an idea of what the script is doing, but feel free to ask if you need clarification.

use AppleScript version "2.4" -- Yosemite (10.10) or later

use scripting additions

-- define where to save the output .iso

set outputFolder to "/path/to/output/"

set films_list to {}

-- prompt for the top level folder

set topFolder to (choose folder with prompt "Select the folder that contains your films")

tell application "Finder"

  -- get a list of the subdirectories (c.f. movie folders) within the selected folder

  set films_folders to every folder of topFolder

  repeat with each_film_folder in films_folders

  -- check there's actually a VIDEO_TS folder inside

  if exists folder "VIDEO_TS" of each_film_folder then

  -- build a list of films

  copy each_film_folder as alias to end of films_list

  end if

  end repeat

  -- now we have a list of valid film folders

  -- work through the folders

  repeat with this_film in films_list

  set film_name to name of this_film

  set this_video_ts_file to POSIX path of this_film & "VIDEO_TS"

  -- now we can work our magic:

  do shell script "/usr/bin/hdiutil makehybrid -udf -udf-volume-name " & film_name & " -o " & output_folder & film_name & ".iso " & this_video_ts_file

  end repeat

end tell

Hello

If I'm not mistaken, you might try something like this.

set src to (choose folder with prompt "Choose source folder")'s POSIX path
set dst to (choose folder with prompt "Choose destination folder")'s POSIX path
set args to ""
repeat with a in {src, dst}
    set args to args & a's quoted form & space
end repeat

do shell script "/bin/bash -s <<'EOF' - " & args & "
SRC=${1%/}
DST=${2%/}
while IFS= read -r -d $'\\0' f
do
    # f = VIDEO_TS directory
    # d = f's parent directory
    # n = d's name
    d=${f%/*}                   
    n=${d##*/}
    hdiutil makehybrid -udf -udf-volume-name \"$n\" -o \"$DST/$n.iso\" \"$d\"
done < <(find \"$SRC\" -type d -iname VIDEO_TS -print0)
EOF"

Good luck,

H

Your problem here is completely different.

the problem is that your film names contain spaces, and spaces are used by the shell to delimit parameters, so when it sees something like "... -udf-volume-name The Big Sleep' this gets interpreted as: "-udf-volume-name The', while "Big" and "Sleep" are interpreted as different parameters, hence the failure.

To get around this you typically need to single-quote any parameter that contains spaces, so:

... -udf-volume-name 'The Big Sleep' ...

Now the -udf-volume-name switch will see 'The Big Sleep' as its value and the rest should work fine.

Now, that said, there are other errors in your script. You are running checks that are subsequently ignored. For example you start with:

choose folder with prompt "Select the folder that contains your films"

but you don't store that result anywhere or reference it anywhere in the script.

In addition, you:

get every folder of alias "OtherFilms:America:AL:"

but then ignore the result and target specific, named directories, which requires that you know in advance what the relevant directories are.

I suggest going back to my original script, just change the do shell script command to quote the parameters and you should be fine. So change:

  do shell script "/usr/bin/hdiutil makehybrid -udf -udf-volume-name " & film_name & " -o " & output_folder & film_name & ".iso " & this_video_ts_file

to:

  do shell script "/usr/bin/hdiutil makehybrid -udf -udf-volume-name '" & film_name & "' -o '" & output_folder & film_name & ".iso' " & quoted form of this_video_ts_file

(note the extra single quotes around the variables)

Certainly the Folders With the film names have spaces ... and I am not at all experienced therefore I wasn't aware of this problem.

It's OK. Spaces in file names are something that Mac users are very used to, but they do need extra care in the shell.

The problem with:

set output_folder to (choose folder with prompt "Select destination folder for conversion")

is that choose folder returns an Apple-specific alias object that contains way more data than a simple filename or pathname. The shell has no idea how to deal with aliases or their associated data, so the shell command chokes. The solution (once you know it) is pretty straightforward - just extract the UNIX-style path from the alias, which is something that the shell can handle.

So instead of:

set output_folder to (choose folder with prompt "Select destination folder for conversion")

use:

set output_folder to quoted form of POSIX path of (choose folder with prompt "Select destination folder for conversion")

the 'POSIX path of..' an alias returns the UNIX-style path (e.g. '/path/to/folder'). Then I've added 'quoted form of...' to properly quote it for the shell in case the path has spaces or other characters that choke the shell.

If it still doesn't work, edit the shell command to prefix with 'echo' (e.g. do shell script "echo /usr/bin/hdiutil...") and you should see the full command that it's trying to execute. Post that here and it might provide more clues.

Hello

I'm not sure but you might try the following alternative. It will create .iso on desktop and then move it to destination.

* If perchance your files are on NAS, I think you'd need to first copy the source folder to local volume, run the script and select copy on local volume as source. Directly manipulating files on NAS is not at all good idea.

set src to (choose folder with prompt "Choose source folder")'s POSIX path
set dst to (choose folder with prompt "Choose destination folder")'s POSIX path
set args to ""
repeat with a in {src, dst}
    set args to args & a's quoted form & space
end repeat

do shell script "/bin/bash -s <<'EOF' - " & args & "
SRC=${1%/}
DST=${2%/}
TMP=~/Desktop
cd \"$TMP\" || exit
while IFS= read -r -d $'\\0' f
do
    # f = VIDEO_TS directory
    # d = f's parent directory
    # n = d's name
    d=${f%/*}                   
    n=${d##*/}
    hdiutil makehybrid -udf -udf-volume-name \"$n\" -o \"$n.iso\" \"$d\"
    mv \"$n.iso\" \"$DST\"
done < <(find \"$SRC\" -type d -iname VIDEO_TS -print0)
EOF"

Regards,

H

Hello

NAS = Network-attached Storage, which is a class of storage accessed via network. E.g., if your OtherFilms volume is on a network and you mount it via AFP, SMB etc, it is NAS. Meanwhile, if your OtherFilms volume is of an external hard disk attached via USB, FireWire etc, it is not NAS (usually).

---

As for the missing .IFO files, I wonder your original command using hdiutil in Terminal produces complete iso image with those files in question?

In other words, provided that your source VIDEO_TS directory is ~/Desktop/test/FilmName/VIDEO_TS, does the following commands in Terminal produce proper iso image as ~/Destop/test/FilmName.iso:

#!/bin/bash
cd ~/Desktop/test || exit
hdiutil makehybrid -udf -udf-volume-name FilmName -o FilmName.iso FilmName

?

If it does, I see no reason why the following script, that is the same as the preivous alternative except for src and dst, does not:

--APPLESCRIPT 2a
set src to (path to desktop)'s POSIX path & "test"
set dst to src
set args to ""
repeat with a in {src, dst}
    set args to args & a's quoted form & space
end repeat

do shell script "/bin/bash -s <<'EOF' - " & args & "
SRC=${1%/}
DST=${2%/}
TMP=~/Desktop
cd \"$TMP\" || exit
while IFS= read -r -d $'\\0' f
do
    # f = VIDEO_TS directory
    # d = f's parent directory
    # n = d's name
    d=${f%/*}                   
    n=${d##*/}
    hdiutil makehybrid -udf -udf-volume-name \"$n\" -o \"$n.iso\" \"$d\"
    mv \"$n.iso\" \"$DST\"
done < <(find \"$SRC\" -type d -iname VIDEO_TS -print0)
EOF"
--END OF APPLESCRIPT 2a

Regards,

H