Apple script to change Desktop Picture

Hi Rob,

Here's a fairly robust example of a random desktop picture changer that uses an idle handler. You save idle handlers as stay open application. As is, it changes the desktop picture every 5 seconds.

property default_folder : path to "pdoc" -- current user's Pictures folder
property extension_list : {"jpg", "tiff", "pdf"}
property idle_minutes : 0
property idle_seconds : 5
global main_folder
--
on run
-- initialize variables, if any
end run
--
on reopen
set main_folder to choose folder with prompt "Choose folder with jpegs:"
end reopen
--
on idle
repeat
try
set this_jpg to some item of GetFiles(main_folder)
exit repeat
on error -- no jpgs in current main_folder
set main_folder to default_folder
end try
end repeat
tell application "Finder"
set desktop picture to this_jpg
end tell
return idle_minutes * minutes + idle_seconds -- return in n seconds
end idle
--
on GetFiles(this_folder)
set utid to AppleScript's text item delimiters
set AppleScript's text item delimiters to {return}
tell application "Finder"
set file_listing to ¬
(every file of this_folder whose name extension is in extension_list) as string
end tell
set AppleScript's text item delimiters to utid
if file_listing is "" then
set file_list to {}
else
set file_list to paragraphs of file_listing
end if
tell application "Finder" to set sub_folders to every folder of this_folder
repeat with sub_folder in sub_folders
set file_list to file_list & GetFiles(sub_folder)
end repeat
return file_list
end GetFiles

Edited: I first started with just jpegs. Hence, the comments and prompts refer to jpegs. Then I added more extension types. You can modify the few properties that were included.

gl,