Toggle Grayscale keyboard shortcut problem (Catalina)

I have upgraded my set_grayscale.applescript so that it now works on High Sierra, Mojave, and Catalina. Thanks to SteverX1 for providing the Catalina related GUI scripting information.

-- set_grayscale.applescript
-- alternates between grayscale and normal display with each run.
-- Tested on High Sierra (10.13.6), Mojave (10.14.6), and Catalina 10.15.1
-- Revision: 11/19/2019, Upgrade script for Catalina
-- VikingOSX, 12/30/2018, Apple Support Communities, No warranty at all

set os_ver to do shell script "sw_vers -productVersion | cut -d '.' -f1-2"

tell application "System Preferences"
	launch
	if os_ver < "10.15" then
		reveal anchor "Seeing_Display" of pane id "com.apple.preference.universalaccess"
	else
		reveal anchor "Seeing_ColorFilters" of pane "Accessibility"
	end if
end tell

tell application "System Events"
	tell application process "System Preferences"
		set frontmost to true
		delay 1
		if os_ver = "10.15" then
			tell window "Accessibility"
				repeat until exists checkbox "Enable Color Filters" of tab group 1 of group 1
					delay 0.01
				end repeat
				click first checkbox of tab group 1 of group 1
			end tell
		else if os_ver = "10.14" then
			tell group 1 of window "Accessibility"
				click checkbox "Use grayscale"
			end tell
		else if os_ver < "10.14" then
			tell window "Accessibility"
				click checkbox "Use grayscale"
			end tell
		end if
	end tell
end tell
tell application "System Preferences" to if it is running then quit

Well this should be handwriting on the wall about the fragility of GUI scripting and its failure as soon as Apple modifies the underlying panel elements. I wrote that script and it works correctly on High Sierra and Mojave. I probably will not even bother to upgrade to Catalina until the .1 or .2 updates are out, so no fixes coming from me on this script.

I found this script on StackOverflow (https://stackoverflow.com/questions/52583402/applescript-mojave-toggle-accessibility-grayscale-on-off) and it works for me:

# quit system preferences if running

if running of application "System Preferences" then

try

tell application "System Preferences" to quit

on error

do shell script "killall 'System Preferences'"

end try

end if

# wait for system preferences to quit

with timeout of 10 seconds

repeat while running of application "System Preferences" is true

delay 0.01

end repeat

end timeout

# switch to correct anchor

tell application "System Preferences" to reveal anchor "Seeing_ColorFilters" of pane "Accessibility"

#tell application "System Preferences" to activate

#get the name of every anchor of pane "Accessibility" of application "System Preferences"

tell application "System Events" to tell process "System Preferences" to tell window "Accessibility"

#return UI elements of tab group 1 of group 1

with timeout of 10 seconds

repeat until exists checkbox "Enable Color Filters" of tab group 1 of group 1

delay 0.01

end repeat

end timeout

click the checkbox "Enable Color Filters" of tab group 1 of group 1

end tell

tell application "System Preferences" to quit

Hey VikingOSX,

Many thanks for the script! I have tried using it, and it's opening up the colour filters, but isn't checking the "Enable Colour Filters" box.

I'm on Catalina 10.15.1 - any ideas? Pretty new to using Apple Scripts so I'm no very familiar with the language :)

I copied the content of the Nov 19 posted script above — into Script Editor on Catalina 10.15.1. Unsurprisingly, I was able to set grayscale, or remove it in subsequent runs of the script. Exactly how it tested before I posted it.

I can watch it open the colored filters panel and check the Enable Color Filters box, as it would have to do for correct operation.

While using names of GUI elements is self documenting, it causes an issue when the spelling is different in that name description. The script also works correctly with this repeat statement:

repeat until exists first checkbox of tab group 1 of group 1



Ahhhhh, thank you! This solved it!