Truncate file name with Automator

The following AppleScript will prompt for a folder that contains the files in the specified format. It does not do recursion, so ignores folders in the selected folder. It renames the files with just the first six characters, provided the "_" location is after the sixth character, and if it exists, will append the original extension.

Launch the Script Editor from Dock : Launchpad : Other.

Copy/and paste the following AppleScript code into the Script Editor. Click the hammer icon to compile the code and check for errors (there are none). Then click the Run button. You can save this as an AppleScript application to your Desktop, where you can double-click to launch it.

If you wanted an Automator application where you could drag and drop these file formats on it, then that will be different AppleScript code.

set sFolder to (choose folder default location (path to desktop))

tell application "Finder"
	set fLst to (every item in folder sFolder whose kind is not "Folder") as alias list
	if fLst is {} then return
	
	repeat with anItem in fLst
		if (offset of "_" in anItem's name as text) > 6 is true then
			set prefix to characters 1 thru 6 of (anItem's name as text) as text
			set ext to anItem's name extension
			if not ext = "" then set ext to "." & ext
			set name of anItem to prefix & ext
		end if
	end repeat
end tell
return



Same result, less AppleScript overhead by removing redundant Finder name and name extension calls.

-- Rename files of format xxxxxx_xxx which may or may not have an extension to
-- first six characters preceding the "_", and if it exists, the extension.
-- Second version which is more efficient by reducing calls to name and name extension.

set sFolder to (choose folder default location (path to desktop))

tell application "Finder"
	set fLst to (every item in folder sFolder whose kind is not "Folder") as alias list
	if fLst is {} then return
	
	repeat with anItem in fLst
		set name_ext to anItem's name
		set ext to anItem's name extension
		if (offset of "_" in name_ext) > 6 is true then
			set prefix to (characters 1 thru 6 of name_ext) as text
			if not ext = "" then set ext to "." & ext
			set name of anItem to prefix & ext
		end if
	end repeat
end tell
return

The following script prompts for a folder containing the files, just as before. It assumes that the first underscore is always at character location 41, but the "__" has a variable character location in the provided examples. So, I trim off the first characters, leaving the desired name with its trailing character string in the variable temp.

I make a new list from the temp string by breaking on the "__" character forming the desired final name as the first element, and all of the text after the "__" location as the second element. The first item of that list is returned for the file renaming.

Tested with your three name strings, and obtained the desired rename string.

set sFolder to (choose folder default location (path to desktop))

tell application "Finder"
	set fileLst to (every item in folder sFolder whose kind is not "Folder") as alias list
	if fileLst is {} then return
	
	repeat with anItem in fileLst
		set fname to anItem's name
		if (offset of "_" in fname) = 41 and fname contains "__" then
			set name of anItem to my trim_name(fname) as text
		end if
	end repeat
end tell
return

on trim_name(aname)
	set first_trim to (offset of "_" in aname) + 1
	-- cannot depend on "__" being in the same character location for each file
	set temp to characters first_trim thru -1 of (aname as text) as text
	set {TID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, "__"}
	-- splits into a list bearing the name string before the "__", and the string after
	set final_name to item 1 of (text items of temp) as text
	set AppleScript's text item delimiters to TID
	return final_name as text
end trim_name

The trim_name handler can be replaced with something more succint that returns the extracted filename.

on sed_trim(aname)
	return (do shell script "sed -En 's/^[a-fA-F0-9]+_(.*)__.*$/\\1/p' <<<" & aname)
end sed_trim

You are welcome.

Safe is the keyword. 😎