How to make an applescript into a service?
I don't see any way to create a service from within Big Sur's Script Editor. Am I missing something?
TIA,
David
Ok. I have a working Automator application using the GUI scripting code that I posted in your previous post. I added a Get Specified Finder Items action to use the name of a text file containing the list of cookies you want to remove from Safari. This way, you only have to edit this cookies.txt file and not the hard-coded list within the AppleScript code.
Because of the increased security measures in recent operating systems, there are some System Preferences : Security & Privacy additions one must make to avoid annoying restriction dialogs apppearing, and the ability to actually send keystrokes from an Automator application.
First, launch Automator from your Applications folder, Choose new Document, and select Application, then click Choose. Next, you only need to drag and drop the following actions from the libary, and in order onto the larger workflow window:
- Files & Folders : Get Specified Finder Items
- Add the name of the text file that you will be using to contain the list of cookies to remove, one to a line, unquoted.
- Utilities : Run AppleScript
The Run AppleScript action will default to a boilerplate on run handler. Select and remove everything in this Run AppleScript action. Then replace with the following code:
use scripting additions
on run {input, parameters}
# input is the name of the file passed in from Get Specified Finder Items
# read the contents of the input text file and automatically generate a list of cookies to remove
set deCookie to (read file (input as text) as text using delimiter linefeed) as list
# Safari must be running before this script can work properly
tell application "Safari" to if it is not running then activate
tell application "System Events"
tell application process "Safari"
set frontmost to true
keystroke "," using command down
delay 1
tell window 1
click button "Privacy" of toolbar 1 of it
try
repeat with d in deCookie
click button "Manage Website Data…" of group 1 of group 1
-- give cookies time to load in their scrollable window
delay 2
select -- focuses on the search window
try
keystroke d
delay 2
select row 1 of table 1 of scroll area 1 of sheet 1
delay 1
click button "Remove" of sheet 1
end try
end repeat
click button "Done" of sheet 1
on error errmsg number errnbr
click button "Done"
keystroke "w" using command down
display alert "No cookies to remove" giving up after 5
return
end try
end tell
keystroke "w" using command down
display alert "Selected cookies removed" giving up after 5
end tell
end tell
# because if you don't do this, the next time you open Preferences it will be hung
tell application "Safari" to if it is running then quit
return
end run
Click the hammer icon within the Run AppleScript action to compile the AppleScript code, and then you can save the Automator Application to your Desktop. I gave mine the name Remove_Cookies, and I would resist using white-space in the application name.
Now, you have some security work to do before you can run it. Open System Preferences : Security & Privacy with your administrator password. Do the following:
- Accessibility
- Add your just saved Automator Application name here, and ensure it is selected.
- Full Disk Access
- Add your Automator Application name here too
- Add Automator too
- Files and Folders
- Add your Automator Application name here.
- Automator should have already been added
Now, once you have built your text file of cookies to remove, you can double-click the saved Automator application on your Desktop and the familiar Safari Privacy panel antics will appear for each cookie that you have added to the cookie.txt file. If you need to edit your saved application, just launch Automator, and select open Recent.
