Bulk renaming portion of files using automator workflow and csv file

I created a CSV using your example, and for each old file basename, I created 50 numerical suffix variations of it in a folder. Thus, 250 test files for 5 CSV rows. You would put your CSV file in the same folder as the images with the name of data.csv.

From /Applications folder, launch Automator. Choose New document, Application, and click Choose. Now, you will need two library actions dragged and dropped onto the larger workflow window in the following order:

1. Files and Folders Library > Ask for Finder Items
   1. Start At: Desktop
   2. Type: Folder (do not check Allow multiple selection)
2. Utilities Library > Run Shell Script
   1. Shell: /bin/zsh
   2. Pass input: as arguments
   3. Select and remove all default boilerplate script in this action, as it will be replaced by the following script code
3. Paste the following script code into the Run Shell Script action
4. Save the Application to your Desktop
5. Quit Automator

Script Code for the Run Shell Script action

#!/bin/zsh

: <<'COMMENT'
Given a folder containing the data.csv file, rename every image basename
to the newfile name, retaining the original suffix format of the oldfile.

Example: SS1234_5.jpg -> T83_KK_5.jpg

Usage: csv.zsh foldername
Reference: https://discussions.apple.com/thread/252521799
Tested: macOS 11.2.2, zsh v5.8
Author: VikingOSX, 2021-03-08, Apple Support Communities, no warranties
COMMENT

typeset -a files=()

SDIR="${1:a:s/\~\//}"
[[ -d $SDIR ]] || exit 1
cd "${SDIR}"
CSV="data.csv"
[[ -s $CSV ]] || exit 1

# assumption that the CSV separator is a comma
while IFS=',' read oldfile newfile
do
    # skip CSV header if present
    [[ "$oldfile" == "oldfile" ]] && continue

    # get all case-insensitive instances of oldfile into an array
    setopt no_CASE_GLOB
    files=( "$oldfile"_*.(jpg|jpeg)(.N) )

    # each oldfile instance will have it's basename replaced by newfile
    # while retaining the respective oldfile suffix and extension.
    for f in $files;
    do 
        # capture () the current oldfile suffix and extension into match array
        [[ $f =~ '^[A-Z0-9]+(_.*)$' ]] || continue
        # rename using newfile basename with oldfile suffix
        mv "${f}" "${newfile}$match[1]"
    done
    files=()
    # ensure there are no quoted CSV elements, or any CR line endings
done < <(sed -e 's/"//g;' "${CSV}" | tr -d '\r')
unset files
exit 0

You appear to have a different filename in the oldfile CSV column than the reality of what you show in your Finder listing.

1. Can there be multiple filenames with the same basename (e.g. SS1234) but with different suffixes (e.g. _1, _2, _n)?
2. Is there just a unique file named SS1234.jpg with no suffix, and it is these that you want to be renamed?

You mention you want to replace only sections of filenames? Explain with an example using from existing filename -> to a final filename. This is a different problem than what the script you attempted to adopt performs as it would involve finding and changing substrings.

The following regular expression revision will handle the following file formats and extract just the suffix part of the filename, just as the original script does, which is then used as a suffix for the replacement filename:

• 101301844-01.jpg
  • $match[1] => -01.jpg
• SD_WW_T83_3202_A0_SP21_EC_90.jpg
  • $match[1] => _90.jpg
• All original filenames that have been working

replace the original regular expression pattern with this one. I recommend that you comment the original with a '#' sign in the first column.

# [[ $f =~ '^[A-Z0-9]+(_.*)$' ]] || continue

[[ $f =~ '^[A-Za-z0-9_]+([_-]+.*\..*)$' ]] || continue
mv "${f}" "${newfile}$match[1]"



I can copy/paste the code that I previously posted directly into an Automator application's Run Shell Script action, and the application runs correctly, and without error dialogs, when passed the selected full folder path from the preceding Ask for Finder Items action. The same unmodified script runs in the Terminal by providing a direct or indirect path to the folder containing the images, and the data.csv file.

The code runs as intended for me on either macOS 11.2.2 or 11.2.3 update.

You should have the following as your Automator application contents, which you can right-click on and choose to open in a new Window for enlargement:

You are welcome. Should save you some time.

Apple's Automator is macOS only. The script uses UNIX commands and the Zsh shell. So the short answer is that it is not portable to Windows.