Setting Cells to RGB (or hex) color in Numbers?

With a bunch of iterations and testing and kibitzing in discord and forums, I've written new code that does what I want, using the original data set.

It's running now, and hopefully will actually finish on the full data set, vs the small test data set where it works fine.

tell application "Numbers"
	activate
	tell document 1
		tell active sheet
			set thisTable to first table
			tell thisTable
				set the width of fifth column to 500
				#set the height of every row to 24
				set alignment of every cell to center
				set vertical alignment of every cell to center
				repeat with i from 2 to the count of rows
					try
						set ColorName to value of first cell of row i
						set RVariable to (65535 * (value of second cell of row i))
						set GVariable to (65535 * (value of third cell of row i))
						set BVariable to (65535 * (value of fourth cell of row i))
						set BGColor to {RVariable, GVariable, BVariable}
						set the background color of fifth cell of row i to BGColor
						set value of fifth cell of row i to ColorName as text
						
						set InverseColor to {}
						repeat with iTwo from 1 to 3
							copy (65535 - (item iTwo of BGColor)) to end of InverseColor
						end repeat
						
						set the text color of fifth cell of row i to InverseColor
						#log InverseColor
					end try
					
				end repeat
			end tell
		end tell
	end tell
end tell

I updated the finalized code with comments to explain my mad thinking if someone finds this in a search:

(*  
Script for NUMBERS to add a color swatch to a cell of a row with RGB info in it.
the table this is written for has R,G,and B in it's own cells (Columns B,C,D) in float (0-1)format. It puts the swatch in Column F and then adds the Color name or code (from Column A) into the cell in an inversed color

*)




tell application "Numbers"
	activate
	with timeout of 3600 seconds #Script reads thru whole table cell by cell, apparantly, before excuting.  Will time out without this.
		tell document 1
			tell active sheet
				set thisTable to first table
				try
					tell thisTable
						
						### Formatting commands for table appearance ###
						set the width of fifth column to 500
						#set the height of every row to 24
						set alignment of every cell to center
						set vertical alignment of every cell to center
						### End Formatting Commands ###
						
						
						repeat with i from 2 to the count of rows
							try #Catches cells without values in them, otherwise would error on calculations
								set ColorName to value of first cell of row i
								set RVariable to (65535 * (value of second cell of row i))
								set GVariable to (65535 * (value of third cell of row i))
								set BVariable to (65535 * (value of fourth cell of row i))
								set BGColor to {RVariable, GVariable, BVariable}
								set the background color of fifth cell of row i to BGColor
								
								
								### Section adds the ColorScale name from the first cell into swatch cell in an inversed color for clarity --- (needs some adjustment for greys) ###
								set value of fifth cell of row i to ColorName as text
								set InverseColor to {}
								repeat with iTwo from 1 to 3
									copy (65535 - (item iTwo of BGColor)) to end of InverseColor
								end repeat
								set the text color of fifth cell of row i to InverseColor
								#log InverseColor
								### End Colorscale name section ###
								
							end try
						end repeat
					end tell
				end try
			end tell
		end tell
	end timeout
end tell

# Beagle for Luck
#                 ___
#                /      \__
#|\            /      @   \
#\ \______|      \   .:|)
# \       ##|      | \__/
#  |  ####\__/   \
#  /   /  ##           \
# /   _________\    \
# L_JJ                \__JJ

# beagle should look right in compiled applescript editor

I'm doing an ongoing log of my attempts to engineer a new script (or something) at macrumors

https://forums.macrumors.com/threads/using-applescript-to-color-cells-in-numbers.2313996/