Automator help : quick action to split the first page of a PDF

Ok. Here is the Quick Action.

Launch Automator and Choose new document > Quick Action > Choose.

1. Workflow receives current PDF Files in Finder
2. Utility LIbrary > Run AppleScript action. Drag this into the larger right-hand workflow window.
   1. Remove all content from the Run AppleScript action as it will be entirely replaced by the following code
   2. When you have copy/pasted the following code into the Run AppleScript action, click the hammer icon in the action to compile the AppleScript.
   3. Save the Quick Action with a brief but unmistable name
   4. In System Preferences > Extensions > Finder, be certain that your named Quick Action is enabled.
   5. Select one or more PDFs in the Finder and from a right-click Finder secondary menu, choose Quick Actions > Your Quick Action name

The original PDFs will be untouched, and you will have the first page and remainder (_split.pdf) filenames for each originally selected PDF. This was tested on Ventura 13.2, instead of Big Sur.

Code:

use framework "Foundation"
use framework "PDFKit"
use AppleScript version "2.4" -- on macOS 10.10 (Yosemite or later)
use scripting additions

property ca : current application
property SUFFIX_1 : "_1"
property SUFFIX_SPLIT : "_split"

on run {input, parameters}
	
	if input = {} then return
	
	repeat with apdf in input
		
		if (apdf as text) ends with ".pdf" then
			
			set thePDF to (POSIX path of apdf) as text
			set pdfPageOne to (ca's NSURL's fileURLWithPath:(my add_PDF_suffix(thePDF, SUFFIX_1)))
			
			set pdf to (ca's PDFDocument's alloc()'s initWithURL:(ca's NSURL's fileURLWithPath:thePDF))
			set page_one to (pdf's pageAtIndex:0)'s dataRepresentation()
			set file_exists to false
			try
				tell application "Finder" to set file_exists to (exists POSIX file pdfPageOne as alias) as boolean
			end try
			if not file_exists then
				set status to (page_one's writeToURL:pdfPageOne atomically:true) as boolean
			end if
			
			set pdfSplitFile to my add_PDF_suffix(thePDF, SUFFIX_SPLIT)
			set pdfSplitURL to (ca's NSURL's fileURLWithPath:pdfSplitFile)
			set file_exists to false
			try
				tell application "Finder" to set file_exists to (exists POSIX file pdfSplitFile as alias) as boolean
			end try
			
			if status and not file_exists then
				(pdf's removePageAtIndex:0)
				(pdf's writeToURL:pdfSplitURL)
			end if
		end if
	end repeat
	return input
end run

on add_PDF_suffix(apdf, suffix)
	-- change filename.pdf to filename_1.pdf
	set ext to (ca's NSString's stringWithString:apdf)'s pathExtension()
	set basename to (ca's NSString's stringWithString:apdf)'s stringByDeletingPathExtension()
	set base_with_suffix to (basename's stringByAppendingString:suffix)'s stringByAppendingPathExtension:ext
	return base_with_suffix as text
end add_PDF_suffix

That original linked Automator solution was unique to that request, though it can be adapted to your need without altering the original PDF content.

Are you starting with an original PDF that you have already renamed from filename.pdf to filename_split.pdf? If that is the case, do you want the first page that is split from the PDF to be named original filename with the numeric 1 as a suffix — as filename_1.pdf?

I have a working solution that writes out the first page of a selected PDF with a numeric one as a suffix (e.g. filename.pdf -> filename_1.pdf. Waiting for your reply and any necessary refinements.

Presently, the solution will write the two extra requested PDFs in the same location as the original. Is that OK?

Are you still on macOS Big Sur, or a later operating system (e.g. Monterey, or Ventura) now?

I wrote a Quick Action Shortcut solution to your problem that features the same AppleScript in a repeat loop for one or more selected PDFs. I withheld the Shortcut as that functionality is not on Big Sur.

An alternative to Automator is Shortcuts.

This will do what you ask with the only difference is that "-0" is added to the original name instead of "-1"

You are welcome.