Preview - Export to PDF is grayed out.... Use to work regardless of Pdf on Catalina

If you want to flatten your PDF so no annotations (e.g. markup) are accessible to others, then your only real option on Ventura is to Print… PDF > Save as PDF.

I have an IRS tax form here that its PDF v1.7 and created by Adobe's Livecycle Designer on Windows. If I start to fill in the form, I see that Export as PDF is grayed out. If I highlight some text (annotation), fill in a few fields in the form and then Print… > PDF > Save as PDF, the resulting PDF will not allow me to edit the annotations, or alter any [un]filled form fields. Seems like that is your goal for any recipient of the PDF.

What is past is not necessarily prologue between Apple operating systems and why that Export as PDF is gray I can't say, but suffice to say it is not an option any more in Ventura.

Preview is not a clone of the more capable Adobe Acrobat Reader DC, and will not handle every PDF consistently that you open in it.

I do have an AppleScript that flattens PDFs without using Preview… It just prompts for the PDF to flatten and then exports that PDF flattened with a "_flattened" suffix to the original PDF location. This does essentially the same thing as the Print panel PDF > Save as PDF.

Launch Apple's Script Editor via Dock > Launchpad > Other > Script Editor. Click the Desktop in the Favorites sidebar, and click New Document.

Copy/paste the following code into the Script Editor, click the compile (hammer) tool, and the click run.

use framework "Foundation"
use framework "AppKit"
use framework "PDFKit"
use AppleScript version "2.4"
use scripting additions

property SUFFIX : "_flattened"
property NSString : a reference to current application's NSString
property NSURL : a reference to current application's NSURL
property PDFDocument : a reference to current application's PDFDocument
property NSDictionary : a reference to current application's NSDictionary
property NSPrintInfo : a reference to current application's NSPrintInfo

set thisPDF to POSIX path of (choose file of type "com.adobe.pdf" default location (path to desktop) without invisibles) as text

set basename to (NSString's stringWithString:thisPDF)'s stringByDeletingPathExtension()
set basename_sfx to basename's stringByAppendingString:SUFFIX
set outPDF to basename_sfx's stringByAppendingPathExtension:"pdf"
set outURL to NSURL's fileURLWithPath:outPDF

set inURL to NSURL's fileURLWithPath:thisPDF
set pdf to PDFDocument's alloc()'s initWithURL:inURL

set {{x, y}, {w, h}} to (pdf's pageAtIndex:0)'s boundsForBox:(current application's kPDFDisplayBoxMediaBox)
set pdict to (NSDictionary's dictionaryWithObject:outURL forKey:(current application's NSPrintJobSavingURL))'s mutableCopy()
pdict's setObject:(current application's NSPrintSaveJob) forKey:(current application's NSPrintJobDisposition)
pdict's setObject:outURL forKey:(current application's NSPrintJobSavingURL)
set printInfo to NSPrintInfo's alloc()'s initWithDictionary:pdict

printInfo's setVerticalPagination:(current application's NSPrintingPaginationModeAutomatic)
printInfo's setJobDisposition:(current application's NSPrintSaveJob)
printInfo's setTopMargin:36.0
printInfo's setBottomMargin:36.0
printInfo's setLeftMargin:36.0
printInfo's setRightMargin:36.0
printInfo's setPaperSize:(current application's NSMakeSize(w, h))

set printOp to pdf's printOperationForPrintInfo:printInfo scalingMode:0 autoRotate:false
printOp's setShowsPrintPanel:false
printOp's setShowsProgressPanel:false
printOp's runOperation()

return

I would visit the Script Editor's File menu and save this AppleScript. On the Save panel, set the File Format to Text which will set the Save As: extension to AppleScript. I called my flatPDF.applescript. Once saved, you can double-click this to open it, then run it, or subsequently, you can press option+Save As… and change the File Format to any of Script, Script Bundle, or Application and save it. These can be run with a double-click from the Desktop.

Tested: macOS Ventura 13.4 with a PDF form and applied highlight annotation.

What happens if while in Preview with that open PDF, you press the option key and select Save As… from the Preview File menu. That should allow you to save your filled forms to another PDF document and retain the filled forms.