How do I disable the"warnings" drop-down window?

-- [SCRIPT changeFont]
(*
Save the script as an Application Bundle (Application under 10.6.x)
Store it on the Desktop.
Drag and drop the icon of a Pages, Numbers or Keynote document on the script icon.
You may also double click the script's icon.
The script will replace oldFontName by newFontName.
It's your duty to define the list of couples {oldFontName,newFontName} used by the script.
This may be done in the handler named BuildListOfFonts()
A list of 564 font names is available on my iDisk:
<http://idisk.me.com/koenigyvan-Public?view=web>
Download:
ForiWork:despolices.numbers.zip
Yvan KOENIG (VALLAURIS, France)
5 juin 2008
22 décembre 2008
8 mars 2009 for iWork '09
2010/05/20 specific font choice for DaveC
*)
property permittedK4 : {"com.apple.iWork.keynote.sffkey", "com.apple.iWork.keynote.sffkth"}
property permittedK5 : {"com.apple.iwork.keynote.key", "com.apple.iwork.keynote.kth"}
property permittedKey : permittedK5 & permittedK4
(* Keynote documents are treated differently *)
property permitted4 : {"com.apple.iWork.pages.sffpages", "com.apple.iWork.pages.sfftemplate", "com.apple.iwork.numbers.sffnumbers", "com.apple.iWork.numbers.sfftemplate"} & permittedK4
property permitted5 : {"com.apple.iwork.pages.pages", "com.apple.iwork.pages.template", "com.apple.iwork.numbers.numbers", "com.apple.iwork.numbers.template"} & permittedK5
property permitted : permitted5 & permitted4
property typeID : missing value
property wasFlat : missing value
property oldAndNews : {}
property newFont : "Arial"
--=====
on BuildListOfFonts()
 local couple
 (* define your couples oldFontName, newFontName *)
 
 if newFont is "Arial" then
 set couple to {"Calibri", "ArialMT"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Bold", "Arial-BoldMT"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-BoldItalic", "Arial-ItalicMT"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Italic", "Arial-BoldItalicMT"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 end if
 
 if newFont is "Helvetica" then
 set couple to {"Calibri", "Helvetica"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Bold", "Helvetica-Bold"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-BoldItalic", "Helvetica-BoldOblique"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Italic", "Helvetica-Oblique"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 end if
 
 if newFont is "LucidaSans" then
 set couple to {"Calibri", "LucidaSans"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Bold", "LucidaSans-Demi"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-BoldItalic", "LucidaSans-DemiItalic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Italic", "LucidaSans-Italic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 end if
 
 if newFont is "NewsGothicStd" then
 set couple to {"Calibri", "NewsGothicStd"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Bold", "NewsGothicStd-Bold"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-BoldItalic", "NewsGothicStd-BoldOblique"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Italic", "NewsGothicStd-Oblique"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 end if
 
 if newFont is "ScalaSansPro" then
 set couple to {"Calibri", "ScalaSansPro-CondRegular"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Bold", "ScalaSansPro-Bold"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-BoldItalic", "ScalaSansPro-BoldItalic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Italic", "ScalaSansPro-Italic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 end if
 
 if newFont is "TrebuchetMS" then
 
 set couple to {"Calibri", "TrebuchetMS"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Bold", "TrebuchetMS-Bold"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-BoldItalic", "Trebuchet-BoldItalic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Italic", "TrebuchetMS-Italic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 end if
 
 if newFont is "Verdana" then
 set couple to {"Calibri", "Verdana"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Bold", "Verdana-Bold"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-BoldItalic", "Verdana-BoldItalic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 
 set couple to {"Calibri-Italic", "Verdana-Italic"} (* edit to fit your needs *)
 copy couple to end of my oldAndNews
 end if
end BuildListOfFonts
(* Some font names:
Arial-Black 
Arial-BoldItalicMT 
Arial-BoldMT 
Arial-ItalicMT 
ArialHebrew 
ArialHebrew-Bold 
ArialMT 
ArialNarrow 
ArialNarrow-Bold 
ArialNarrow-BoldItalic 
ArialRoundedMTBold 
ArialUnicodeMS 
Bookman-Demi
Bookman-DemiItalic
Bookman-Light
Bookman-LightItalic
Chalkboard 
CourierNewPSMT
Didot
Didot-Bold
Didot-Italic
Geneva
GillSans
Helvetica
Helvetica-Oblique
Helvetica-Bold
Helvetica-BoldOblique
HelveticaNeue-CondensedBold
HelveticaNeue-CondensedBlack
HelveticaNeue-UltraLight
HelveticaNeue-UltraLightItalic
HelveticaNeue-Light
HelveticaNeue-LightItalic
HelveticaNeue-Regular
HelveticaNeue-Italic
HelveticaNeue-Bold
HelveticaNeue-BoldItalic
Herculanum
HumanaSerifITCTT-Medium
Julius
LucidaGrande
LucidaGrande-Bold
MarkerFelt-Thin
Palatino-Roman
Palatino-Italic
Palatino-Bold
Palatino-boldItalic
TektonPro-Bold
TektonPro-BoldCond
TektonPro-BoldExt
TektonPro-BoldObl
*)
--=====
on run (* 
lignes exécutées si on double clique sur l'icône du script application
• lines executed if one double click the application script's icon *)
 
 tell application "System Events"
 if my parleAnglais() then
 set myPrompt to "Choose an iWork’s document"
 else
 set myPrompt to "Choisir un document iWork"
 end if -- parleAnglais
 
 if 5 > (system attribute "sys2") then (*
if Mac Os X 10.4.x *)
 set allowed to my permitted
 else (*
it's Mac OS X 10.5.x with a bug with Choose File *)
 set allowed to {}
 end if -- 5 > (system…
 my commun(choose file with prompt myPrompt of type allowed) (* un alias *)
 end tell
end run
--=====
on open (sel) (* 
sel contient une liste d'alias des élémentsqu'on a déposés sur l'icône du script (la sélection)
• sel contains a list of aliases of the items dropped on the script's icon (the selection) *)
 
 my commun(item 1 of sel) (* an alias *)
end open
--=====
on commun(thePack) (*
• thePack is an alias *)
 local pFold, pName, path2Index, texteXML
 my nettoie()
 tell application "System Events" to tell disk item (thePack as text)
 set typeID to (type identifier) as text
 set pFold to package folder
 set pName to name
 set pExt to name extension
 end tell
 
 if typeID is not in my permitted then
 if my parleAnglais() then
 error "“" & (thePack as text) & "” is not an iWork’s document!"
 else
 error "«" & (thePack as text) & "» n’est pas un document iWork !"
 end if -- my parleAnglais() 
 end if -- typeID
 
 if pFold then
 set wasFlat to false
 else
 set wasFlat to true
 my expandFlat(thePack) (* an alias *)
 end if
 
 try
 if typeID is in my permittedKey then (*
special case Keynote *)
 set path2Index to (thePack as text) & "Index.apxl"
 else (*
Pages or Numbers *)
 set path2Index to (thePack as text) & "Index.xml"
 end if -- typeID starts …
 
 set texteXML to my lis_Index(path2Index)
 
 my BuildListOfFonts()
 (*
remplace une police par une autre
• replace a font by an other one *)
 repeat with l in my oldAndNews
 set texteXML to my recolle(my decoupe(texteXML, quote & item 1 of l & quote), quote & item 2 of l & quote)
 end repeat (*
The quotes are important. Without them we may get a fontname
like Palatino-Oblique which doesn't exists (it's Palatino-Italic) *)
 my enregistre(texteXML, path2Index)
 if wasFlat then
 tell application "Finder"
 if pExt = "key" then
 set name of thePack to (text 1 thru -4 of pName & "kth")
 else if pExt = "pages" then
 set name of thePack to (text 1 thru -6 of pName & "template")
 else if pExt = "numbers" then
 set name of thePack to (text 1 thru -8 of pName & "nmbtemplate")
 end if -- pExt
 end tell -- Finder
 end if -- wasFlat
 on error error_message number error_number
 my nettoie()
 if error_number is not -128 then my affiche(error_message)
 end try
 my nettoie()
end commun
--=====
on nettoie()
 set typeID to missing value
 set wasFlat to missing value
 set my oldAndNews to {}
end nettoie
--=====
on affiche(msg)
 tell application "Finder"
 activate
 if my parleAnglais() then
 display dialog msg buttons {"Cancel"} default button 1 giving up after 120
 else
 display dialog msg buttons {"Annuler"} default button 1 giving up after 120
 end if -- parleAnglais()
 end tell -- application 
end affiche
--=====
on lis_Index(cheminXML0)
 local cheminXML0, cheminXMLgz, txtXML
 set cheminXMLgz to cheminXML0 & ".gz"
 
 tell application "System Events"
 if exists file cheminXMLgz then
 if exists file cheminXML0 then delete file cheminXML0 (* 
un curieux a pu dé-gzipper le fichier
• someone may have gunzipped the file *)
 my expand(cheminXMLgz)
 set txtXML to my lisIndex_xml(cheminXML0)
 else if exists file cheminXML0 then
 set txtXML to my lisIndex_xml(cheminXML0)
 else
 if typeID is in my permittedKey then (*
special case Keynote *)
 if my parleAnglais() then
 error "Index.apxl missing"
 else
 error "Il n'y a pas de fichier Index.apxl"
 end if -- parleAnglais()
 else (*
Pages or Numbers *)
 if my parleAnglais() then
 error "Index.xml missing"
 else
 error "Il n'y a pas de fichier Index.xml"
 end if -- parleAnglais()
 end if -- typeID
 end if -- exists file cheminXMLgz
 end tell -- to System Events
 return txtXML
end lis_Index
--=====
on expand(f)
 do shell script "gunzip " & quoted form of (POSIX path of (f))
end expand
--=====
on lisIndex_xml(f)
 local t
 try
 set t to ""
 set t to (read file f)
 end try
 return t
end lisIndex_xml
--=====
on enregistre(leTexte, nDoc)
 local aliasNDoc
 set aliasNDoc to nDoc as alias
 write leTexte to aliasNDoc starting at 0
 (*
I removed the code which was gzipping the index.xml in packages because iWork '09
don't like files compressed this way. It destroys the index at next save.
 *)
end enregistre
--=====
on expandFlat(f) (* f is an alias *)
 local zipExt, qf, d, nn, nz, fz, qfz
 set zipExt to ".zip"
 set qf to quoted form of POSIX path of f
 tell application "System Events"
 tell disk item (f as text)
 set d to path of container
 set nn to name
 set nz to nn & zipExt
 set fz to d & nz
 if exists disk item fz then set name of disk item fz to nn & my horoDateur(modification date of file fz) & zipExt
 set name to nz
 end tell -- disk item
 make new folder at end of folder d with properties {name:nn}
 end tell -- System Events
 
 set qfz to quoted form of POSIX path of fz
 
 do shell script "unzip " & qfz & " -d " & qf & " ; rm " & qfz
end expandFlat
--=====
on flattenPackage(f) (* f is an alias *)
 (*
 local zipExt, qf, nn, d, nz, fz, qfz
 set zipExt to ".zip"
 set qf to quoted form of POSIX path of f
 tell application "System Events"
 tell disk item (f as text)
 set d to path of container
 set nn to name
 set nz to nn & zipExt
 set fz to d & nz
 if exists disk item fz then set name of disk item fz to nn & my horoDateur(modification date of file fz) & zipExt
 end tell -- disk item
 make new file at end of folder d with properties {name:nz}
 end tell -- System Events
 
 set qfz to quoted form of POSIX path of fz (* ditto is lazy, we must build the quoted form before calling it *)
 do shell script "ditto -ck " & qf & " " & qfz & " ; rm -d -R " & qf
 
 tell application "System Events" to set name of disk item fz to nn
 *)
end flattenPackage
--=====
(*
• Build a stamp from the modification date_time
*)
on horoDateur(dt)
 local annee, mois, jour, lHeure, lesSecondes, lesMinutes
 set annee to year of dt
 set mois to month of dt as number (* existe depuis 10.4 *)
 set jour to day of dt
 set lHeure to time of dt
 set lesSecondes to lHeure mod 60
 set lHeure to round (lHeure div 60)
 set lesMinutes to lHeure mod 60
 set lHeure to round (lHeure div 60)
 return "_" & annee & text -2 thru -1 of ("00" & mois) & text -2 thru -1 of ("00" & jour) & "-" & text -2 thru -1 of ("00" & lHeure) & text -2 thru -1 of ("00" & lesMinutes) & text -2 thru -1 of ("00" & lesSecondes)
 (* 
• Here, the stamp is "_YYYYMMDD-hhmmss" *)
end horoDateur
--=====
on decoupe(t, d)
 local l
 set AppleScript's text item delimiters to d
 set l to text items of t
 set AppleScript's text item delimiters to ""
 return l
end decoupe
--=====
on recolle(l, d)
 local t
 set AppleScript's text item delimiters to d
 set t to l as text
 set AppleScript's text item delimiters to ""
 return t
end recolle
--=====
on parleAnglais()
 local z
 try
 tell application "Pages" to set z to localized string "Cancel"
 on error
 set z to "Cancel"
 end try
 return (z is not "Annuler")
end parleAnglais
--=====
-- [/SCRIPT]
--