This is actually a little tricker than it first sounds, for two reasons.
One is that you want to increment the timestamp on each file (so you need to keep some kind of counter), the second is there are very few ways of changing the creation date of a file.
First, to change creation dates, you need to download and install Xcode from Apple's: https://apps.apple.com/us/app/xcode/id497799835?mt=12
If you're not a developer, you can ignore 99% of what gets installed, but you will need the command line tool setfile (you might be able to get away with just downloading and installing the Xcode command line tools from: Command Line Tools for Xcode 16.2.dmg but I haven't verified this).
Once you have setfile installed, the next part is to iterate through your files making the changes.
This AppleScript I whipped up prompts the user for a folder and then changes all the files in that folder to have consecutive creation and modification dates, on a 3-minute incremement.
Copy and paste the script into a new Script Editor document and click Run. The comments tell you what each step does:
use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions
-- starting date for the first file
set thedate to date "1/1/2025 at 00:00:00"
-- how much time to add for each incremental file
set theOffset to 3 * minutes
tell application "Finder"
-- ask the user for the folder to process, and get a list of files
set theFiles to every file of (choose folder) as alias list
-- loop through the files
repeat with each_file in theFiles
-- format the date in a specific format
set date_string to my formatDate(thedate)
-- use setfile to make the change
do shell script "setfile -d '" & date_string & "' -m '" & date_string & "' " & (get POSIX path of file each_file)
-- increment the date for the next file
set thedate to thedate + theOffset
end repeat
end tell
on formatDate(the_date)
-- setfile requires the date in a specific format.
-- This handler converts from AppleScript's date to something setfile can use.
set {y, m, d, t} to {year, month, day, time string} of the_date
set {myTID, my text item delimiters} to {my text item delimiters, ":"}
set {hr, min, sec} to text items 1 through 3 of t
set my text item delimiters to myTID
set returnString to (m as number) & "/" & d & "/" & y & space & hr & ":" & min & ":" & sec as text
return returnString
end formatDate
Change the starting date at the top of the script. This will be the date used for the first file.
The increment is set in the next line (3 * minutes). You can set this to any number of seconds (where AppleScript knows that a minute is 60 seconds, so 3 * 60 =180
The script then prompts for a folder and will blindly change all the files in that folder to have new creation and modification dates. There is no error checking (e.g. for valid dates, file types, etc.), and there is no undo, so make sure you select the right folder.
