AppleScript: How to self-close AppleScript Editor window after execution of its own script?

You can't do that for the very reason given in the error message.

When you issue the 'close' command, the script has not completed. You can't terminate a script by closing a window, and thus you can't close a window when a script is still running.

What exactly are you trying to do? As the error message states, you can't close a document while the script is still running, although you can use an external script or quit the AppleScript Editor if your script has been saved.

The AppleScript Editor won't let you close the document while the script is running. You don't neccessarily need to use the editor to run your scripts, though - they can be run from the Scripts Menu, for example.

It seems doable because the execution always happens prior to window close.

The script doesn't end until the last command has received a reply from the Apple Event Manager. That's why you can't do it.

However, if you have other windows open, you can close the window by sending the close command from another window.

i.e, from window 1,

tell my window 2 to close

will work

Hello

You may try something like the script below.

Note that

a) you must call close_self() handler at the very end of your script, otherwise it won't work,

b) window of never-saved script won't close,

c) you may specify the close option – saving yes|no|ask – as parameter

Hope this may help,

H

display dialog "Good bye"
close_self({saving:yes})

on close_self(opt)
    (*
        record opt :  {saving: savo}
            savo : (constant) yes | no | ask (default = ask)

        * close window of this script in AppleScript editor
    *)
    set {saving:savo} to opt & {saving:ask}
    set p2m to (path to me)'s POSIX path -- [1]
    tell application id "com.apple.ScriptEditor2"
        set wid to -1
        repeat with i in (get windows's id)
            set i to i's contents
            try
                if window id i's document's path = p2m then
                    set wid to i
                    exit repeat
                end if
            end try
        end repeat
        if wid = -1 then return
    end tell
    do shell script "sleep 0.5; /usr/bin/osascript <<'EOF' - " & wid & " " & savo & " &>/dev/null &
on run argv
    set {wid, savo} to argv
    set wid to wid as integer
    if savo = \"yes\" then
        set savo to yes
    else if savo = \"no\" then
        set savo to no
    else
        set savo to ask
    end if
    tell application id \"com.apple.ScriptEditor2\"
        close window id wid saving savo
    end tell
end run
EOF"
    (*
        [1] (path to me) for never-saved script is path to script editor.
            Because of this and the logic to determine the target window id, this handler won't close window of never-saved script.
    *)
end close_self

Message was edited by: Hiroto (change "unsaved" to "never-saved" in script comment)

They should give prizes for work like this! :) :)

My pleasure. Glad to know it helps.

Here's some revisions. I noticed that sleep 0.5 as a guard interval in shell script is useless here because it is run in foreground and holds do shell script execution. Instead we'd need to use delay 0.5 in applescript run by osascript which is run in background. Corrected script is as follows.

display dialog "Good bye"
close_self({saving:yes})

on close_self(opt)
    (*
        record opt :  {saving: savo}
            savo : (constant) yes | no | ask (default = ask)

        * close window of this script in AppleScript editor
    *)
    set {saving:savo} to opt & {saving:ask}
    set p2m to (path to me)'s POSIX path -- [1]
    tell application id "com.apple.ScriptEditor2"
        set wid to -1
        repeat with i in (get windows's id)
            set i to i's contents
            try
                if window id i's document's path = p2m then
                    set wid to i
                    exit repeat
                end if
            end try
        end repeat
        if wid = -1 then return
    end tell
    do shell script "/usr/bin/osascript <<'EOF' - " & wid & " " & savo & " &>/dev/null &
on run argv
    set {wid, savo} to argv
    set wid to wid as integer
    if savo = \"yes\" then
        set savo to yes
    else if savo = \"no\" then
        set savo to no
    else
        set savo to ask
    end if
    delay 0.5
    tell application id \"com.apple.ScriptEditor2\"
        close window id wid saving savo
    end tell
end run
EOF"
    (*
        [1] (path to me) for never-saved script is path to script editor.
            Because of this and the logic to determine the target window id, this handler won't close window of never-saved script.
    *)
end close_self

And indeed the code can be simplified as follows using document instead of window:

display dialog "Good bye"
close_self({saving:yes})

on close_self(opt)
    (*
        record opt :  {saving: savo}
            savo : (constant) yes | no | ask (default = ask)

        * close window of this script in AppleScript editor
    *)
    set {saving:savo} to opt & {saving:ask}
    set p2m to (path to me)'s POSIX path -- [1]
    do shell script "/usr/bin/osascript <<'EOF' - " & p2m's quoted form & " " & savo & " &>/dev/null &
on run argv
    set {p, savo} to argv
    if savo = \"yes\" then
        set savo to yes
    else if savo = \"no\" then
        set savo to no
    else
        set savo to ask
    end if
    delay 0.5
    tell application id \"com.apple.ScriptEditor2\"
        tell document 1 whose path = p
            if exists then close saving savo
        end tell
    end tell
end run
EOF"
    (*
        [1] (path to me) for never-saved script is path to script editor.
            Because of this, this handler won't close window of never-saved script.
    *)
end close_self

All the best,

H

Message was edited by: Hiroto (fixed the comment in the second script)

Hello

You may use good old "load script" command or new "use" statement introduced in AppleScript 2.3 under 10.9.

Script library using "load script" command is something like this. Here it assumes lib.scptd is saved in ~/Library/Scripts.

-- caller script
set lib to load script POSIX file ((path to scripts folder from user domain)'s POSIX path & "lib.scptd") -- ~/Library/Scripts/lib.scptd
display dialog "Good bye"
lib's close_self({saving:yes})

-- lib.scptd
on close_self(opt)
    (*
        record opt :  {saving: savo}
            savo : (constant) yes | no | ask (default = ask)
            
        * close window of this script in AppleScript editor
    *)
    set {saving:savo} to opt & {saving:ask}
    set p2m to (path to me)'s POSIX path -- [1]
    do shell script "/usr/bin/osascript <<'EOF' - " & p2m's quoted form & " " & savo & " &>/dev/null &
on run argv
    set {p, savo} to argv
    if savo = \"yes\" then
        set savo to yes
    else if savo = \"no\" then
        set savo to no
    else
        set savo to ask
    end if
    delay 0.5
    tell application id \"com.apple.ScriptEditor2\"
        tell document 1 whose path = p
            if exists then close saving savo
        end tell
    end tell
end run
EOF"
    (*
        [1] (path to me) for never-saved script is path to script editor.
            Because of this, this handler won't close window of never-saved script.
    *)
end close_self

If I'm not mistaken, script library using "use" statment would be something like this. (Not tested, for I'm using 10.6.8)

-- caller script
(*
    OSX 10.9 or later (AppleScript 2.3 or later)
*)
use script "MyLib" -- [1]
use scripting additions -- [2]
(*
    [1] MyLib.scpt or MyLib.scptd is searched in the following locations in this order and the first matching script is used:
        Contents/Resources/Script Libraries/
        ~/Library/Script Libraries/
        /Library/Script Libraries/
        /Network/Library/Script Libraries/
        /System/Library/Script Libraries/
    
    [2] If you use any "use" statement, you need to specify "use script additions" explicitly in order to use scripting additions.
    
    cf.
    https://developer.apple.com/library/mac/documentation/AppleScript/Conceptual/AppleScriptLangGuide/
    AppleScript Language Guide
        > Script Objects
            > Script Libraries

        > Control Statements Reference
            > use Statements
*)
display dialog "Good bye"
close_self({saving:yes})

-- MyLib.scptd
property name : "MyLib"
property id : "org.someone.mylib"
property version : "0.1.1"

on close_self(opt)
    (*
        record opt :  {saving: savo}
            savo : (constant) yes | no | ask (default = ask)
            
        * close window of this script in AppleScript editor
    *)
    set {saving:savo} to opt & {saving:ask}
    set p2m to (path to me)'s POSIX path -- [1]
    do shell script "/usr/bin/osascript <<'EOF' - " & p2m's quoted form & " " & savo & " &>/dev/null &
on run argv
    set {p, savo} to argv
    if savo = \"yes\" then
        set savo to yes
    else if savo = \"no\" then
        set savo to no
    else
        set savo to ask
    end if
    delay 0.5
    tell application id \"com.apple.ScriptEditor2\"
        tell document 1 whose path = p
            if exists then close saving savo
        end tell
    end tell
end run
EOF"
    (*
        [1] (path to me) for never-saved script is path to script editor.
            Because of this, this handler won't close window of never-saved script.
    *)
end close_self

Good luck,

H