Applescript Built In Progress Indicator Not Working Properly

I think the main problem is that your script blocks the UI while it is speaking (pretty much any script will block the UI most of the time), so the progress text only gets updated when the run loop is given a chance to get events. AppleScriptObjC will give you a bit more control, in this case using a handler to manually update the event queue is a little bit easier than recreating the progress dialog, for example:

use framework "Foundation"
use scripting additions

on run
  set progress description to "Resizing NetBoot Image Volume..."
  set progress total steps to 6
  repeat with steps from 1 to 6
    updateProgress(steps)
  end repeat
  set progress additional description to "Completed"
  display dialog "NetBoot Image Volume Resizing Complete" buttons {"OK"} default button 1
end run

on updateProgress(step)
  set progress additional description to "Step " & step
  set progress completed steps to step
  fetchEvents()
  say "Performing step " & step & ", this may take a few seconds"
end updateProgress

on fetchEvents() -- handle user events
  repeat -- forever
    tell current application's NSApp to set theEvent to nextEventMatchingMask_untilDate_inMode_dequeue_(current application's NSUIntegerMax, missing value, current application's NSEventTrackingRunLoopMode, true)
    if theEvent is missing value then -- none left
      exit repeat
    else
      tell current application's NSApp to sendEvent:theEvent -- pass it on
    end if
  end repeat
  return
end fetchEvents

Then, doesn't that make the progress feature relatively pointless?

Pretty much. I thought it was way too late be added, since there were already a few stand alone third party progress applications, and once Cocoa applets became available even more progress libraries showed up.

The new progress works fairly well in the Script Editor, but your typical AppleScript tends to be one big monolithic chunk of code, so the user interface doesn't get much of a chance to update. Putting the typical AppleScript into an Xcode project usually winds up doing the same thing - you need to pay a bit more attention to the way you write your application (regardless of the language used) if you want to keep the UI responsive.

Regular AppleScript is single threaded and not really event driven, so things like repeat loops and shell scripts (unless run in the background) will lock up the UI unless steps are taken. As another example, take a look at your application menu (move the mouse pointer into the menu) while it is running - it is constantly getting beach balls, since the application is not responding to the system.

Sleeping the script would make things worse.

The fetchEvents() handler in my earlier post lets the UI update by getting any events that may be backed up in the queue and passing them on. What I did in my example was to set the various parameters for the progress indicator, then call the handler right before performing the task to update the UI with the new settings.

Unless you run your shell script in the background, AppleScript will wait until it is finished (blocking the UI in the mean time), although running your shell scripts in the background gets interesting figuring out when they are complete so that you can update the progress.

You are correct that AppleScript isn't really designed for this kind of thing, although you can use AppleScriptObjC to leverage Cocoa classes such as NSTask, which does handle background tasks with completion notifications.